业务事件

ABAP RESTful 应用程序编程模型 › 开发 › 开发业务事件 › 业务事件

示例

以下示例基于数据建模和行为中所述的可扩展性数据模型。在这种情况下,事件在原始 Agency RAP BO 的行为扩展中引发。

您想要定义每次创建新审核时引发的事件,以通知相应的代理。一旦无退货点已过且业务流程已完成,则必须触发事件,这就是在延迟保存阶段引发事件并额外保存的原因。这可确保数据保存到数据库,并且业务对象的状态更改是最终的。事件本身在行为定义中使用关键字 event 定义,可以使用或不使用参数进行定义。对于此用例,使用抽象实体定义参数,该抽象实体传输电子邮件地址和文本,以通过电子邮件通知代理。在附加保存中的行为池中实施事件的引发。

  1. 创建抽象实体 /DMO/ZZ_D_AgencyReviewCreated 并定义所需的数据类型。变量 EMailAddress 定义为 strg(256),包含相应 Agency 的电子邮件地址。ReviewID 包含有关触发事件的审核的信息。

    @EndUserText.label: 'Agency Review Infos for create event'
    define abstract entity /DMO/ZZ_D_AgencyReviewCreated
    {
      ReviewID        : /dmo/zz_review_id;
      Rating          : /dmo/zz_rating;
      FreeTextComment : /dmo/zz_free_text_comment;
      EMailAddress    : /dmo/email_address;
    }
    

    有关在 RAP 中建模参数的详细信息,请参阅非标准操作的建模参数。

  2. 在行为定义扩展中使用关键字 event 定义事件。此示例中的事件名为 /DMO/AgencyReviewCreated。抽象实体 /DMO/ZZ_D_AgencyReviewCreated 的字段构成了事件的有效负载。

    extend behavior for /DMO/Agency
    {
      event /DMO/AgencyReviewCreated parameter /DMO/ZZ_D_AgencyReviewCreated;
    }
    
  3. 为要引发事件的业务对象实体定义附加保存。在此示例中,扩展节点 /DMO/ZZ_R_Agency_ReviewTP 引发事件 ,因此 with additional save 将添加到实体定义的标头:

    define behavior for /DMO/ZZ_R_AGENCY_REVIEWTP alias /DMO/ZZ_Review using /DMO/ZZ_I_AGENCY_REVIEWTP
    with additional save
    persistent table /DMO/ZZ_AGN_REVA
    draft table /DMO/ZZ_AGN_REVD
    etag master LocalLastChangedAt
    lock dependent
    authorization dependent
    late numbering
    {
    ...
    }
    
  4. 在行为池的 save_modified 方法中实施事件的引发。

    此方法检查是否通过检查 create-/dmo/zz_review 不为空而实际创建了检查。READ 返回为其创建审核的根节点代理实例。emailaddress 信息是在触发事件后电子邮件将发送到的电子邮件地址。然后,使用通过事件 RAISE EVENT 扩展的 RAP BO 接口 /DMO/I_AgencyTP /DMO/AgencyReviewCreated 引发该事件。在最后一步中,填充事件的实例代码和参数值。

    有关附加保存的一般信息,请参阅 保存 。

    METHOD save_modified.
        IF create-/dmo/zz_review IS NOT INITIAL.
          READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
            ENTITY /dmo/agency
              FIELDS ( emailaddress ) WITH CORRESPONDING #( create-/dmo/zz_review )
            RESULT DATA(agencies).
    
          RAISE ENTITY EVENT /dmo/i_agencytp~/dmo/agencyreviewcreated
            FROM VALUE #(
              FOR review IN create-/dmo/zz_review (
                  agencyid        = review-agencyid
                  reviewid        = review-reviewid
                  rating          = review-rating
                  freetextcomment = review-freetextcomment
                  emailaddress    = agencies[ KEY entity  agencyid = review-agencyid ]-emailaddress
                )
              ).
        ENDIF.
      ENDMETHOD.
    

备注

在使用事件之前,需要使用语法 use event 在 RAP BO 接口中公开这些事件。请注意,上述示例中不需要此操作,因为事件是通过扩展添加的。对于公开事件的本地使用,需要发布 RAP BO 接口 C1。

备注

如果事件使用者与事件提供者(远程使用)不在同一系统中,则需要创建事件绑定并将具有公开事件的 RAP BO 接口包括在此事件绑定中。事件绑定表示事件的设计时定义,并将 RAP BO 中定义的事件映射到命名空间、业务对象和业务对象操作(如修改)。