在非托管查询中实施排序

ABAP RESTful 应用程序编程模型 › 开发 › 实施非托管查询 › 在非托管查询中实施排序

要在非托管查询中检索已排序的数据,需要将排序条件添加到 SQL SELECT 语句。接口 IF_RAP_QUERY_REQUEST 提供了获取请求的排序元素和排序顺序的方法。

该方法返回元素的有序列表及其排序顺序。如果存在多个排序元素,则排序优先级按出现顺序排列。要在 SQL SELECT 子句中使用排序条件,必须将排序条件转换为具有逗号分隔的排序元素和排序顺序对的字符串。

abap.bool 表示从查询请求中获取的排序表中元素 descending 的排序顺序,而排序顺序必须使用 SQL 语句的 descending 子句中的字符串 ascending 或 ORDER BY 表示。

示例

SQL select 语句的字符串必须类似于 element1 ascending , element2 descending, …。

接口 IF_RAP_QUERY_RESPONSE 提供了在从数据源检索数据记录后为查询响应设置已排序数据的方法。

前提条件

有关非托管查询实施的常规先决条件,请参阅先决条件非托管查询。

实施步骤

以下步骤提供了如何实施排序条件的示例。

  1. 调用接口 get_sort_elements 的方法 IF_RAP_QUERY_REQUEST,该方法返回排序元素的排序列表以及相应的排序方向。

  2. 将返回值的元素写入字符串表,并将 abap.bool 分别映射到 ' ascending' 或 ' descending'。

  3. 用逗号分隔将字符串表的各行拼接到一个字符串变量中。

  4. 如果存在具有初始排序顺序的查询请求,要实现一致的结果,请提供缺省排序顺序,例如 'primary key'。

  5. 在 SQL select 的 ORDER BY 子句中使用排序条件。

  6. 调用接口 set_data 的方法 IF_RAP_QUERY_RESPONSE 以响应具有已排序数据的 OData 请求。排序的结果随即返回到 OData 客户端,例如 SAP Fiori 元素 UI。

以下代码块说明了查询实现类中 select 方法IF_RAP_QUERY_PROVIDER 内的排序实现。

    IF io_request->is_data_requested( ).

      DATA(sort_elements) = io_request->get_sort_elements( ).
      DATA(lt_sort_criteria) = VALUE string_table( FOR sort_element IN sort_elements
                                                 ( sort_element-element_name && COND #( WHEN sort_element-descending = abap_true
                                                                                        THEN ` descending`
                                                                                        ELSE ` ascending` ) ) ).
      DATA(lv_sort_string)  = COND #( WHEN lt_sort_criteria IS INITIAL THEN `primary key`
                                                                       ELSE concat_lines_of( table = lt_sort_criteria sep = `, ` ) ).

      DATA lt_travel_response TYPE STANDARD TABLE OF /dmo/i_travel_uq.
      SELECT * FROM /dmo/travel
               ORDER BY (lv_sort_string)
               INTO CORRESPONDING FIELDS OF TABLE @lt_travel_response.
      io_response->set_data( lt_travel_response ).
    ENDIF.

有关 API 信息,请参阅方法 get_sort_elements。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 在非托管查询中实施分页 · 在非托管查询中考虑请求的元素 →