使用大对象
ABAP RESTful 应用程序编程模型 › 开发 › 开发单个业务对象功能 › 使用大对象
上下文
您可以启用 RAP 应用程序以维护大对象 (LOB)。通过执行此操作,您可以为最终用户提供在编辑实体实例时合并外部二进制文件或文本文件的选项。
以下视频介绍了最终用户如何使用已为 LOB 维护启用的 RAP 应用程序执行图像上载。

数据模型增强
大对象通过以下字段建模:
附件
MIME 类型
文件名
字段 Attachment 包含 LOB 本身,并且在技术上绑定到字段 Mimetype,表示附件的内容类型。没有 MIME 类型就不存在附件,反之亦然。文件名是可选字段。
通过 Fiori 元素 UI 使用大对象时,框架基于维护的 CDS 注释从字段 Mimetype 和 Filename 派生字段 Attachment 的值,因此 UI 使用者只需与字段 Attachment 交互即可维护大对象。
示例场景
我们使用 ABAP 航班参考场景的示例来展示如何启用业务对象中大对象的维护。在此示例中,我们使用包 /DMO/FLIGHT_REUSE_AGENCY 中的业务对象,可用于管理代理主数据(如代理名称和地址)。本指南显示如何启用现有业务对象以维护文件附件,例如代理传单。
前提条件
为了能够遵循本指南的说明并测试增强结果,您的业务对象应满足以下要求:
您的业务对象已创建且已启用更新。
业务对象包含投影层。
投影层具有用于提供 CDS 注释的元数据扩展。
您的业务对象作为 OData UI 服务公开。
过程
在活动数据库表和草稿数据库表中,为大对象添加以下字段:
attachment: /dmo/attachment; mimetype: /dmo/mime_type; filename: /dmo/filename;
使用
/dmo/域中的相应基本类型对字段进行类型分配。而基本类型/dmo/attachment使用数据类型rawstring,而/dmo/mime_type和/dmo/filename则使用数据类型char128。在 CDS 视图
/DMO/I_Agency中,添加为数据库表定义的字段、定义字段别名并使用 CDS 注释以语义方式将字段相互关联。注释contentDispositionPreference可用于定义文件附件是在浏览器中显示(设置#INLINE)还是在选择时下载(选项#ATTACHMENT),具体取决于浏览器设置。使用 CDS 注释@Semantics.mimeType: true定义字段MimeType。@Semantics.largeObject: { mimeType: 'MimeType', fileName: 'Filename', contentDispositionPreference: #INLINE } Agency.attachment as Attachment, @Semantics.mimeType: true Agency.mime_type as MimeType, Agency.filename as Filename
在基本 CDS 视图
/DMO/R_AGENCYTP中,从 CDS 视图Filename添加字段Attachment、MimeType和/DMO/I_Agency。同时将字段添加到 CDS 映射视图
/DMO/C_AgencyTP和/DMO/I_AgencyTP。在 CDS 映射视图
/DMO/C_AgencyTP的元数据扩展中,可以设置要在对象页面上显示的抬头信息。在此示例场景中,如果文件附件为图像,则Attachment字段的内容在抬头中显示为头像。这是通过在title部分提供 UI 注释imageUrl: 'Attachment'来实现的。@UI: { headerInfo: { typeName: 'Agency', typeNamePlural: 'Agencies', title: { type: #STANDARD, value: 'Name' }, imageUrl: 'Attachment', description: { type: #STANDARD, value: 'AgencyID' } }, presentationVariant: [{ sortOrder: [{ by: 'AgencyID', direction: #ASC }], visualizations: [{type: #AS_LINEITEM}] }] }
此外,将 CDS 注释
@UI.hidden: true用于字段Mimetype和Filename以确保在 Fiori 元素 UI 上仅为大对象显示Attachment字段。如上所述,UI 使用者只需与字段Attachment交互即可维护大对象,框架会处理字段Mimetype和Filename的值处理。@UI: { fieldGroup: [ { position: 100, qualifier: 'General_FG' } ], identification: [ { position: 100, label: 'Attachment' } ] } Attachment; @UI.hidden: true MimeType; @UI.hidden: true Filename;
通过 EML 使用大对象
通过 EML 使用大对象时,需要使用者正确提供与大对象相关的字段。例如,业务对象开发人员需要确保仅保留一致值的验证。对于字段值不一致的大对象,无法与 Fiori 元素进行正确的 OData 编排。
此类验证的示例包含在代理参考场景的行为池 lhc_agency 的本地类 /dmo/bp_r_agencytp 中。相应方法 validatelargeobject 考虑以下条件:
不存在不含 MIME 类型的附件。
现有 MIME 类型的附件不得为初始值。这既包括空附件,也包括不存在的附件,因为 ABAP 中的这两种情况之间没有不同的方法。
MIME 类型必须在支持的 MIME 类型列表中。为简单起见,在类构造函数中提供了此列表。
文件名的文件扩展名必须与支持的 mimetypes 列表中的文件扩展名匹配。
文件名是可选的。但是,如果提供了文件名,则必须有相应的附件和 mime 类型。
METHOD validatelargeobject.
READ ENTITIES OF /dmo/r_agencytp IN LOCAL MODE
ENTITY /dmo/agency
FIELDS ( attachment mimetype filename )
WITH CORRESPONDING #( keys )
RESULT DATA(agencies).
LOOP AT agencies INTO DATA(agency).
APPEND VALUE #( %tky = agency-%tky
%state_area = state_area_validate_lob ) TO reported-/dmo/agency.
" No mimetype for attachment
IF agency-attachment IS NOT INITIAL AND agency-mimetype IS INITIAL.
APPEND VALUE #( %tky = agency-%tky ) TO failed-/dmo/agency.
APPEND VALUE #( %tky = agency-%tky
%state_area = state_area_validate_lob
%msg = NEW /dmo/cx_agency( textid = /dmo/cx_agency=>mimetype_missing
attachment = agency-attachment )
%element-mimetype = if_abap_behv=>mk-on )
TO reported-/dmo/agency.
ENDIF.
IF agency-mimetype IS NOT INITIAL.
" No (empty) attachment for mimetype
IF agency-attachment IS INITIAL.
APPEND VALUE #( %tky = agency-%tky ) TO failed-/dmo/agency.
APPEND VALUE #(
%tky = agency-%tky
%state_area = state_area_validate_lob
%msg = NEW /dmo/cx_agency( textid = /dmo/cx_agency=>attachment_empty_missing
attachment = agency-attachment )
%element-attachment = if_abap_behv=>mk-on )
TO reported-/dmo/agency.
ENDIF.
" Mimetype is not supported
IF NOT line_exists( allowed_mimetypes[ mimetype = agency-mimetype ] ).
APPEND VALUE #( %tky = agency-%tky ) TO failed-/dmo/agency.
APPEND VALUE #( %tky = agency-%tky
%state_area = state_area_validate_lob
%msg = NEW /dmo/cx_agency( textid = /dmo/cx_agency=>mimetype_not_supported
mimetype = agency-mimetype )
%element-mimetype = if_abap_behv=>mk-on )
TO reported-/dmo/agency.
ELSE.
IF agency-filename IS NOT INITIAL.
DATA(file_extension) = substring_from( val = agency-filename pcre = '(.[^.]*)$' ).
" File extension does not match mimetype
IF file_extension <> allowed_mimetypes[ mimetype = agency-mimetype ]-file_extension.
APPEND VALUE #( %tky = agency-%tky ) TO failed-/dmo/agency.
APPEND VALUE #(
%tky = agency-%tky
%state_area = state_area_validate_lob
%msg = NEW /dmo/cx_agency( textid = /dmo/cx_agency=>extension_mimetype_mismatch
mimetype = agency-mimetype )
%element-mimetype = if_abap_behv=>mk-on
%element-filename = if_abap_behv=>mk-on )
TO reported-/dmo/agency.
ENDIF.
ENDIF.
ENDIF.
ELSEIF agency-attachment IS INITIAL AND agency-filename IS NOT INITIAL.
APPEND VALUE #( %tky = agency-%tky ) TO failed-/dmo/agency.
APPEND VALUE #( %tky = agency-%tky
%state_area = state_area_validate_lob
%msg = NEW /dmo/cx_agency( textid = /dmo/cx_agency=>only_filename
filename = agency-filename )
%element-attachment = if_abap_behv=>mk-on
%element-mimetype = if_abap_behv=>mk-on )
TO reported-/dmo/agency.
ENDIF.
ENDLOOP.
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 在业务对象之间映射消息 · 非标准操作的建模参数 →