在非托管查询中实施聚合
ABAP RESTful 应用程序编程模型 › 开发 › 实施非托管查询 › 在非托管查询中实施聚合
要检索聚合数据,需要根据 OData 请求中请求的聚合实施检索和分组数据的逻辑。接口 IF_RAP_QUERY_REQUEST 提供获取聚合信息的方法。它返回接口实例 IF_RAP_QUERY_AGGREGATION,其中包含两种获取要聚合或分组的元素的方法。
要根据请求的聚合选择请求的元素,您需要将请求的聚合元素转换为 SQL SELECT 的聚合字符串。聚合字符串必须如下所示:
<AGGR_METHOD> ( <aggr_element> ) as <result_element>
有关 SQL 表达式中聚合函数的详细信息,请参阅 ABAP SQL - 聚合表达式 agg_exp(ABAP 关键字文档)。
为避免重复选择结果元素,您需要将其从请求的元素列表中删除,因为聚合字符串在 SQL SELECT 中与其他请求的元素一起使用。
要按请求的分组元素对响应数据进行分组,需要为 SQL GROUP BY 子句创建 SQL 字符串。
IF_RAP_QUERY_RESPONSE 接口提供了一种方法,用于在从数据源检索数据后为查询响应设置聚合数据和分组数据。
前提条件
有关非托管查询实施的常规先决条件,请参阅先决条件非托管查询。
要在 Fiori 元素 UI 中使用 聚合并发送聚合值请求,您需要使用
@Aggregation.default: <aggr_method>注释相关元素。
实施步骤
此过程结合了请求元素和聚合的实现,因为二者都在 SQL SELECT 的选择列表中使用。这些步骤还提供了如何在 SQL SELECT 中使用分组元素的示例。
检查是否请求了数据。
调用接口
get_requested_elements的方法IF_RAP_QUERY_REQUEST,该方法返回包含请求元素的表。调用接口
get_aggregation的方法IF_RAP_QUERY_REQUEST,该方法返回IF_RAP_QUERY_AGGREGATION的接口实例。使用方法get_aggregated_elements,该方法返回要聚合的元素列表、其相应的聚合方法和聚合值的结果元素。从请求的元素中删除结果元素。
使用聚合方法 、要聚合的元素和结果元素为 SQL
SELECT创建聚合字符串。将聚合字符串附加到请求元素的字符串。
调用接口
get_aggregation的方法IF_RAP_QUERY_REQUEST,该方法返回IF_RAP_QUERY_AGGREGATION的接口实例。使用方法get_grouped_elements,该方法返回请求作为组参考的元素列表。用逗号分隔将字符串表的各行拼接到一个字符串变量中。
使用 SQL
SELECT的选择列表中的请求元素。将字符串 与
SELECT语句的GROUP BY子句中的分组元素一起使用。
以下代码块说明了查询实施类中 IF_RAP_QUERY_PROVIDER 的聚合和分组 select 方法的实现。
IF io_request->is_data_requested( ).
DATA(lt_req_elements) = io_request->get_requested_elements( ).
DATA(lt_aggr_element) = io_request->get_aggregation( )->get_aggregated_elements( ).
IF lt_aggr_element IS NOT INITIAL.
LOOP AT lt_aggr_element ASSIGNING FIELD-SYMBOL(<fs_aggr_element>).
DELETE lt_req_elements WHERE table_line = <fs_aggr_element>-result_element.
DATA(lv_aggregation) = |{ <fs_aggr_element>-aggregation_method }( { <fs_aggr_element>-input_element } ) as { <fs_aggr_element>-result_element }|.
APPEND lv_aggregation TO lt_req_elements.
ENDLOOP.
ENDIF.
DATA(lv_req_elements) = concat_lines_of( table = lt_req_elements sep = `, ` ).
DATA(lt_grouped_element) = io_request->get_aggregation( )->get_grouped_elements( ).
DATA(lv_grouping) = concat_lines_of( table = lt_grouped_element sep = `, ` ).
DATA lt_travel_response TYPE STANDARD TABLE OF /dmo/i_travel_uq.
SELECT (lv_req_elements) FROM /dmo/travel
GROUP BY (lv_grouping)
ORDER BY ('primary key')
INTO CORRESPONDING FIELDS OF TABLE @lt_travel_response.
io_response->set_data( lt_travel_response ).
ENDIF.
备注
建议实施默认排序顺序以从数据源返回一致的结果。
备注
有关 API 信息,请参阅方法
get_aggregation。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 在非托管查询中考虑请求的元素 · 扩展 →