在非托管查询中使用参数

ABAP RESTful 应用程序编程模型 › 开发 › 实施非托管查询 › 在非托管查询中使用参数

要检索与自定义实体中设置的实体参数相关的数据,您需要在查询实施类中对参数实施处理。接口 IF_RAP_QUERY_REQUEST 提供获取参数的方法。它返回带有参数名称和值的字符串表。

由应用程序开发人员决定如何实施参数逻辑。一个选项是实施参数作为过滤条件。要将参数值用作 SQL SELECT 语句的 WHERE 子句中的过滤器,需要根据参数值创建过滤器字符串。

在从数据源检索数据后,接口 IF_RAP_QUERY_RESPONSE 提供了一种为查询响应设置过滤数据或过滤的记录总数的方法。

前提条件

  • 自定义实体具有一个或多个实体参数。

    示例

    define custom entity /DMO/I_Travel_UQ
    with parameters p_start_date : /dmo/begin_date,
                    p_end_date   : /dmo/end_date
    
  • 有关非托管查询实施的常规先决条件,请参阅先决条件非托管查询。

实施步骤

以下步骤描述了使用参数作为附加筛选条件的过程。参数 p_start_date 和 p_end_date 用作元素 Begin_Date 和 End_Date 上的过滤器。

  1. 调用接口 get_parameters 的方法 IF_RAP_QUERY_REQUEST,该方法返回参数及其值的字符串表。

  2. 如果请求中未提供参数,则定义缺省参数值。实施示例使用系统日期 Begin_Date 和下一年的系统日期 End_Date。

  3. 为过滤器字符串定义变量,并使用元素 Begin_Date 和 End_Date 上 SQL WHERE 子句的过滤条件填充该变量并集成缺省值。

    备注

    要通过 SQL 字符串注入避免安全风险,请使用公共类 escape_quotes 的方法 CL_ABAP_DYN_PRG。

  4. 如果存在其他过滤条件(来自过滤器请求或参数),请使用 AND 连接过滤器字符串。

  5. 检查是否请求了数据。

  6. 使用 SQL 语句的 WHERE 子句中的过滤条件从数据源中检索过滤后的数据。

  7. 调用接口 set_data 的方法 IF_RAP_QUERY_RESPONSE 以响应具有过滤数据的 OData 请求。过滤的结果随即返回到 OData 客户端,例如 SAP Fiori 元素 UI。

  8. 检查是否请求了计数。

  9. 使用 SQL 语句的 WHERE 子句中的过滤条件检索与请求匹配的数据记录计数。

  10. 调用接口 set_total_number_of_records 的方法 IF_RAP_QUERY_RESPONSE 以响应具有过滤计数的 OData 请求。过滤的结果随即返回到 OData 客户端,例如 SAP Fiori 元素 UI。

以下代码块说明了查询实现类中 IF_RAP_QUERY_PROVIDER select 方法内的参数实现。 展开以下代码示例以查看源代码

示例代码

    DATA(lt_parameters) = io_request->get_parameters( ).
    DATA(lv_next_year) =  CONV /dmo/end_date( cl_abap_context_info=>get_system_date( ) + 365 )  .
    DATA(lv_par_filter) = |( BEGIN_DATE >= '{ cl_abap_dyn_prg=>escape_quotes( VALUE #( lt_parameters[ parameter_name = 'P_START_DATE' ]-value
                                                                                      DEFAULT cl_abap_context_info=>get_system_date( ) ) ) }'| &&
                          |  AND | &&
                          | END_DATE <= '{ cl_abap_dyn_prg=>escape_quotes( VALUE #( lt_parameters[ parameter_name = 'P_END_DATE' ]-value
                                                                                    DEFAULT lv_next_year ) ) }' )| .

    IF lv_sql_filter IS INITIAL.
      lv_sql_filter = lv_par_filter.
    ELSE.
      lv_sql_filter = |( { lv_sql_filter } AND { lv_par_filter } )| .
    ENDIF.

    IF io_request->is_data_requested( ).
      DATA lt_travel_response TYPE STANDARD TABLE OF /dmo/i_travel_uq.
      SELECT * FROM /dmo/travel
               WHERE (lv_sql_filter)
               ORDER BY ('primary key')
               INTO CORRESPONDING FIELDS OF TABLE @lt_travel_response
      io_response->set_data( lt_travel_response ).
    ENDIF.

    IF io_request->is_total_numb_of_rec_requested( ).
      SELECT COUNT( * ) FROM /dmo/travel
                        WHERE (lv_sql_filter)
                        INTO @DATA(lv_travel_count).
      io_response->set_total_number_of_records( lv_travel_count ).
    ENDIF.

备注

建议实施默认排序顺序以从数据源返回一致的结果。

有关 API 信息,请参阅方法 get_parameters。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 在非托管查询中实施过滤 · 在非托管查询中实施搜索 →