实施工作流
ABAP RESTful 应用程序编程模型 › 重用 › 集成 SAP Workflow Management › 实施工作流
在 RAP BO 中触发工作流时,通过 Workflow Service 触发预定义决策工作流。该示例通过操作触发,并使用 determination on save 执行。
前提条件
定义 的行为定义 /DMO/R_Travel_W
基于
/DMO/R_Travel_W创建行为定义。行为定义需要以下行为元素来触发工作流:
字段(只读)WFRecipient::对此字段的更改会触发
determination on save。此字段定义为readonly,因为该值通过操作triggerDecisionWorkflow填充。action triggerDecisionWorkflow:设置字段
WFRecipient并在保存时触发确定。determination triggerWorkflow:执行工作流注册并定义工作流服务的有效负载。
编号场景是决定如何在 RAP BO 中集成工作流的决定性因素。更多信息,请参见 工作流和编号 。在这种情况下,在
determination on save中实施它是唯一的选项。展开以下代码示例以查看源代码
示例代码
managed implementation in class /dmo/bp_trvl_w unique; strict(2); with draft; define behavior for /DMO/R_TRVL_W alias Travel implementation in class /dmo/bp_trvl_w unique persistent table /dmo/a_travel_w draft table /dmo/d_travel_w ... { ... field ( readonly ) WFRecipient; ... action ( features : instance ) triggerDecisionWorkflow parameter /dmo/a_trvl_triggerwf_w result [1] $self; determination triggerWorkflow on save { field WFRecipient; } ... mapping for /dmo/a_travel_w corresponding {... } }
实施操作 triggerDecisionWorkflow
实施
triggerDecisionWorkflow操作
此操作将更新 EML MODIFY 语句中的工作流相关字段。WFRecipient 的更新会在保存时触发确定中的工作流注册。结果将返回具有所有字段的所有差旅实例。
示例代码
METHOD TriggerDecisionWorkflow.
MODIFY ENTITIES OF /dmo/r_trvl_d_w IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( WFRecipient WFDecision WFTimestamp WFHandle )
WITH VALUE #( FOR key IN keys ( %tky = key-%tky
WFRecipient = key-%param-WFRecipient
WFDecision = ''
WFTimestamp = 0
WFHandle = '' ) ).
READ ENTITIES OF /dmo/r_trvl_d_w IN LOCAL MODE
ENTITY Travel
ALL FIELDS WITH
CORRESPONDING #( keys )
RESULT DATA(travels).
result = VALUE #( FOR travel IN travels ( %tky = travel-%tky
%param = travel ) ).
ENDMETHOD.
实施确定 triggerWorkflow
触发确定时,它会注册工作流并定义其有效负载。实施确定的以下步骤。
在此,您可以找到完整的代码片段:
展开以下代码示例以查看源代码
示例代码
METHOD triggerWorkflow.
READ ENTITIES OF /dmo/r_trvl_d_w IN LOCAL MODE
ENTITY Travel
ALL FIELDS WITH VALUE #( FOR key IN keys ( %tky = key-%tky ) )
RESULT DATA(travels).
" Skip all Travels that have no recipient or for which a workflow has already been triggered
DELETE travels WHERE WFRecipient IS INITIAL OR WFHandle IS NOT INITIAL.
CHECK travels[] IS NOT INITIAL.
" We need to specify our own WFHandle, as otherwise the mass-registration via the RAP facade would not work
LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
TRY.
<travel>-WFHandle = cl_system_uuid=>create_uuid_c32_static( ).
CATCH cx_uuid_error.
ASSERT 1 = 2.
ENDTRY.
ENDLOOP.
MODIFY ENTITIES OF i_cpwf_inst
ENTITY CPWFInstance
EXECUTE registerWorkflow
FROM VALUE #( FOR travel IN travels
( %key-CpWfHandle = travel-WFHandle
%param-RetentionTime = '2'
%param-CpWfDefId = 'z123.myworkflow'
%param-CallbackClass = '/DMO/CL_WF_CALLBACK'
%param-Consumer = 'DEFAULT' ) )
MAPPED DATA(mapped)
FAILED DATA(failed).
" Check that n Travels have resulted in n workflow instances (both are not yet linked)
ASSERT lines( travels ) = lines( mapped-cpwfinstance ).
ASSERT failed-cpwfinstance IS INITIAL.
" Persist the Workflow Handle in the Travel - to indicate that a workitem has been triggered
MODIFY ENTITIES OF /dmo/r_trvl_d_w IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( WFHandle )
WITH VALUE #( FOR travel IN travels ( %tky = travel-%tky
WFHandle = travel-WFHandle ) ).
" Set the workflow context for the new workflow instances
DATA: wf_travel TYPE /dmo/bp_trvl_d_w=>ty_wf_travel,
wf_json TYPE STANDARD TABLE OF /dmo/bp_trvl_d_w=>ty_wf_json.
TRY.
DATA(cpwf_api) = cl_swf_cpwf_api_factory_a4c=>get_api_instance( ).
DATA(cpwf_json) = cpwf_api->get_json_converter( ).
CATCH cx_swf_cpwf_api INTO DATA(lx_cpwf).
ASSERT 1 = 2.
ENDTRY.
LOOP AT travels ASSIGNING <travel>.
wf_travel = CORRESPONDING #( <travel>-%data ).
cpwf_json->serialize(
EXPORTING
data = wf_travel
RECEIVING
result = DATA(json) ).
APPEND VALUE #( wfhandle = <travel>-WFHandle
json = json ) TO wf_json.
ENDLOOP.
MODIFY ENTITIES OF i_cpwf_inst
ENTITY CPWFInstance
EXECUTE setPayload
FROM VALUE #( FOR wf_item IN wf_json
( %key-CpWfHandle = wf_item-wfhandle
%param-context = wf_item-json
) )
MAPPED DATA(mapped2)
FAILED DATA(failed2).
ASSERT lines( travels ) = lines( mapped2-cpwfinstance ).
ASSERT failed2-cpwfinstance IS INITIAL.
ENDMETHOD.
1. 读取所需差旅
READ 语句读取差旅实例的所有字段。然后 WFRecipient 字段中所有没有接收方的实例都将从 travels 中删除,以及之前已触发工作流的所有实例。
READ ENTITIES OF /dmo/r_trvl_d_w IN LOCAL MODE
ENTITY Travel
ALL FIELDS WITH VALUE #( FOR key IN keys ( %tky = key-%tky ) )
RESULT DATA(travels).
" Skip all travels that have no recipient or for which a workflow has already been triggered
DELETE travels WHERE WFRecipient IS INITIAL OR WFHandle IS NOT INITIAL.
CHECK travels[] IS NOT INITIAL.
...
2.在业务对象接口中定义主键的 WFHandle
调用方法为 create_uuid_c32_static( ) 的WFHandle 类 cl_system_uuid,为每个差旅实例定义唯一的 UUID 作为接口 i_cpwf_inst 的主键。
...
" Specify WFHandle, as otherwise the mass-registration via the RAP BO interface would not work
LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
TRY.
<travel>-WFHandle = cl_system_uuid=>create_uuid_c32_static( ).
CATCH cx_uuid_error.
ASSERT 1 = 2.
ENDTRY.
ENDLOOP.
...
3. 注册工作流
执行 BO 接口 CPWFInstance 的操作 registerWorkflow 以使用以下输入参数注册工作流:
%key-CpWfHandle:用于唯一标识每个差旅实例的 UUID。UUID 已在上一步中生成。
%param-CpWfDefId:设计工作流的工作流标识。
%param-CallbackClass:指定实施接口
if_swf_cpwf_callback的回调类。
根据您的用例,可以使用其他输入参数。有关详细信息,请参阅工作流功能的 API 或参阅相应的 KTD 文档。
断言操作期间所有差旅实例均已传输到工作流实例。
...
MODIFY ENTITIES OF i_cpwf_inst
ENTITY CPWFInstance
EXECUTE registerWorkflow
FROM VALUE #( FOR travel IN travels
( %key-CpWfHandle = travel-WFHandle
%param-RetentionTime = '2'
%param-CpWfDefId = 'myworkflow'
%param-CallbackClass = '/DMO/CL_WF_CALLBACK'
%param-Consumer = 'DEFAULT' ) )
MAPPED DATA(mapped)
FAILED DATA(failed).
" Check that n Travels have resulted in n workflow instances (both are not yet linked)
ASSERT lines( travels ) = lines( mapped-cpwfinstance ).
ASSERT failed-cpwfinstance IS INITIAL.
...
4.为 JSON 转换调用帮助程序类
根据结构 ty_wf_travel 和 ty_wf_json 创建两个变量。有关结构的详细信息,请参阅结构 ty_wf_travel 和 ty_wf_json。cl_swf_cpwf_api_factory_a4c 类用作帮助程序类,以获取下一步所需的 json 转换器的访问权限。
代码语法
...
" Set the workflow context for the new workflow instances
DATA: wf_travel TYPE /dmo/bp_trvl_d_w=>ty_wf_travel,
wf_json TYPE STANDARD TABLE OF /dmo/bp_trvl_d_w=>ty_wf_json.
TRY.
DATA(cpwf_api) = cl_swf_cpwf_api_factory_a4c=>get_api_instance( ).
DATA(cpwf_json) = cpwf_api->get_json_converter( ).
CATCH cx_swf_cpwf_api INTO DATA(lx_cpwf).
ASSERT 1 = 2.
ENDTRY.
...
5. 更新已启动工作流的状态
更新字段 WFHandle 以指示已为特定差旅实例触发工作流程。
代码语法
...
" Persist the Workflow Handle in the Travel - to indicate that a workitem has been triggered
MODIFY ENTITIES OF /dmo/r_trvl_d_w IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( WFHandle )
WITH VALUE #( FOR travel IN travels ( %tky = travel-%tky
WFHandle = travel-WFHandle ) ).
...
6. 设置有效负载
wf_travel 包含差旅结构的子集。结构转换为 json 格式。与 UUID WFHandle 一起附加到类型 TYPE STANDARD TABLE OF /dmo/bp_trvl_d_w=>ty_wf_json 的 wf_json 表中。
然后 setPayload 操作会以 JSON 格式传输有效负载以及相应的 UUID。
...
LOOP AT travels ASSIGNING <travel>.
wf_travel = CORRESPONDING #( <travel>-%data ).
cpwf_json->serialize(
EXPORTING
data = wf_travel
RECEIVING
result = DATA(json) ).
APPEND VALUE #( wfhandle = <travel>-WFHandle
json = json ) TO wf_json.
ENDLOOP.
MODIFY ENTITIES OF i_cpwf_inst
ENTITY CPWFInstance
EXECUTE setPayload
FROM VALUE #( FOR wf_item IN wf_json
( %key-CpWfHandle = wf_item-wfhandle
%param-context = wf_item-json
) )
MAPPED DATA(mapped2)
FAILED DATA(failed2).
ASSERT lines( travels ) = lines( mapped2-cpwfinstance ).
ASSERT failed2-cpwfinstance IS INITIAL.