投影草稿业务对象数据模型
ABAP RESTful 应用程序编程模型 › 开发 › 开发 API › 投影草稿业务对象数据模型
对于使用草稿的托管场景,为草稿业务对象实体创建和实施 CDS 映射视图。
上下文和过程
为所有三个业务对象实体“差旅”、“预订”和“预订补充”创建映射视图的数据定义。在 ADT 中,使用基础 CDS 视图实体上的上下文菜单 /DMO/R_Travel_D、/DMO/R_Booking_D 和 /DMO/R_BookingSupplement_D 打开用于创建 CDS 数据定义的向导。
选择模板定义映射视图。
有关映射视图中语法的详细信息,请参阅将视图实体定义为映射(ABAP 关键字文档)。
投影视图 /DMO/I_Travel_D
在抬头部分使用注释 @Metadata.ignorePropagatedAnnotations: true。这样可以防止基础基础数据模型中的注释通过 CDS 视图堆栈进一步传播,因此可能会影响基于 RAP BO 接口构建的投影。
映射视图是 /DMO/R_Travel_D 上的投影。在投影视图中包含关键字 root。
使用供方合同 transactional_interface。这会将映射视图定义为 RAP BO 接口的一部分。
使用基础业务对象差旅实体的所有元素。您不需要在投影视图中使用管理数据,表示 ETag 主数据的元素除外。
由于投影视图不会用于 OData 服务使用,因此不需要 UI 特定注释。标识元素的长文本也不需要非规范化。
定义语义注释,以建立 BookingFee 和 TotalPrice 字段与其货币代码字段之间的关系。此外,还可以定义字段 LocalLastChangedAt。定义的语义注释将对在此接口视图之上构建的所有投影视图生效。
业务对象的构成结构的所有映射视图可用后,将子构成重定向到预订实体的映射视图。
展开以下代码示例以查看投影视图 /DMO/I_Travel_D 的源代码。
示例代码
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Travel Interface Projection View'
@AccessControl.authorizationCheck: #NOT_REQUIRED
define root view entity /DMO/I_Travel_D
provider contract transactional_interface
as projection on /DMO/R_Travel_D
{
key TravelUUID,
TravelID,
AgencyID,
CustomerID,
BeginDate,
EndDate,
@Semantics.amount.currencyCode: 'CurrencyCode'
BookingFee,
@Semantics.amount.currencyCode: 'CurrencyCode'
TotalPrice,
CurrencyCode,
Description,
OverallStatus,
@Semantics.systemDateTime.localInstanceLastChangedAt: true
LocalLastChangedAt,
/* Associations */
_Agency,
_Booking: redirected to composition child /DMO/I_Booking_D,
_Currency,
_Customer,
_OverallStatus
}
投影视图 /DMO/I_Booking_D
在抬头部分使用注释 @Metadata.ignorePropagatedAnnotations: true。这样可以防止基础基础数据模型中的注释通过 CDS 视图堆栈进一步传播,因此可能会影响基于 RAP BO 接口构建的投影。
映射视图是 /DMO/R_Booking_D 上的投影。
使用基础业务对象差旅实体的所有元素。
由于投影视图不会用于 OData 服务使用,因此不需要 UI 特定注释。标识元素的长文本也不需要非规范化。
定义语义注释,以建立字段 FlightPrice 与其货币代码字段之间的关系。此外,定义字段 LocalLastChangedAt。定义的语义注释将对在此接口视图之上构建的所有投影视图生效。
业务对象构成结构的所有映射视图可用后,将目标子构成重定向到预订补充实体的映射视图,并将与根实体的关联重定向到相应的映射视图。
展开以下代码示例以查看投影视图 /DMO/I_Booking_D 的源代码。
示例代码
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Booking Interface Projection View '
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view entity /DMO/I_Booking_D
as projection on /DMO/R_Booking_D {
key BookingUUID,
TravelUUID,
BookingID,
BookingDate,
CustomerID,
AirlineID,
ConnectionID,
FlightDate,
@Semantics.amount.currencyCode: 'CurrencyCode'
FlightPrice,
CurrencyCode,
BookingStatus,
@Semantics.systemDateTime.localInstanceLastChangedAt: true
LocalLastChangedAt,
/* Associations */
_BookingStatus,
_BookingSupplement: redirected to composition child /DMO/I_BookingSupplement_D,
_Carrier,
_Connection,
_Customer,
_Travel: redirected to parent /DMO/I_Travel_D
}
投影视图 /DMO/I_BookingSupplement_D
在抬头部分使用注释 @Metadata.ignorePropagatedAnnotations: true。这样可以防止基础基础数据模型中的注释通过 CDS 视图堆栈进一步传播,因此可能会影响基于 RAP BO 接口构建的投影。
映射视图是 /DMO/R_BookingSupplement_D 上的投影。
使用基础业务对象差旅实体的所有元素。
由于投影视图不会用于 OData 服务使用,因此不需要 UI 特定注释。标识元素的长文本也不需要非规范化。
定义语义注释,以建立字段 BookSupplPrice 与其货币代码字段之间的关系。此外,定义字段 LocalLastChangedAt。定义的语义注释将对在此接口视图之上构建的所有投影视图生效。
业务对象构成结构的所有映射视图可用后,将至父关联重定向到预订实体的映射视图,并将根实体的关联重定向到相应的映射视图。
展开以下代码示例以查看投影视图 /DMO/I_BookingSupplement_D 的源代码。
示例代码
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'BookSupplement Interface Projection View'
@AccessControl.authorizationCheck: #NOT_REQUIRED
define view entity /DMO/I_BookingSupplement_D
as projection on /DMO/R_BookingSupplement_D {
key BookSupplUUID,
TravelUUID,
BookingUUID,
BookingSupplementID,
SupplementID,
@Semantics.amount.currencyCode: 'CurrencyCode'
BookSupplPrice,
CurrencyCode,
@Semantics.systemDateTime.localInstanceLastChangedAt: true
LocalLastChangedAt,
/* Associations */
_Booking: redirected to parent /DMO/I_Booking_D,
_Product,
_SupplementText,
_Travel : redirected to /DMO/I_Travel_D
}
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 开发 API · 预测草稿业务对象行为 →