在非托管查询中实施搜索

ABAP RESTful 应用程序编程模型 › 开发 › 实施非托管查询 › 在非托管查询中实施搜索

要根据 OData 请求中的搜索词检索数据,需要在查询实施类中实施搜索逻辑。接口 IF_RAP_QUERY_REQUEST 提供了从请求中获取搜索表达式的方法。

搜索逻辑由应用程序开发人员决定。一个选项是使用搜索表达式作为一个或多个元素的(附加)过滤条件。要将搜索表达式用作 SQL SELECT 语句的 WHERE 子句中的过滤器,您需要从搜索表达式中创建过滤器字符串,并将其与其他可能的过滤器字符串组合。

接口 IF_RAP_QUERY_RESPONSE 提供了一种方法,用于在从数据源检索数据后为查询响应设置过滤的数据。

前提条件

  • 有关非托管查询实施的常规先决条件,请参阅先决条件非托管查询。

  • 要从 Fiori 元素 UI 发送包含搜索条件的查询请求,您需要使用 @Search.seachable:true 注释自定义实体。

    备注

    注释 @Search.searchable: true 需要对自定义实体中的至少一个元素使用注释 @Search.defaultSearchElement: true。此元素注释对搜索没有任何影响,因为它由实施搜索逻辑元素的应用程序开发人员决定。

实施步骤

以下步骤提供了如何将搜索实施为元素 Description 的过滤器的示例。如果还请求了过滤器,则需要确保 SQL 过滤器字符串具有 SQL SELECT 语句的正确语法。

  1. 检查是否请求了数据。

  2. 调用接口 get_search_expression 的方法 IF_RAP_QUERY_REQUEST,该方法返回请求的搜索表达式的字符串。

  3. 使用元素 WHERE 的过滤器为 SQL SELECT 语句的 Description 子句创建过滤器字符串。

    备注

    要通过 SQL 字符串注入避免安全风险,请使用公共类 escape_quotes 的方法 CL_ABAP_DYN_PRG。

  4. 如果存在其他过滤条件(来自过滤器请求或参数),请使用 AND 连接过滤器字符串。

  5. 检查是否请求了数据。

  6. 使用 SQL 语句的 WHERE 子句中的过滤条件从数据源中检索过滤后的数据。

  7. 调用接口 set_data 的方法 IF_RAP_QUERY_RESPONSE 以响应具有过滤数据的 OData 请求。过滤的结果随即返回到 OData 客户端,例如 SAP Fiori 元素 UI。

  8. 检查是否请求了计数。

  9. 使用 SQL 语句的 WHERE 子句中的过滤条件检索与请求匹配的数据记录计数。

  10. 调用接口 set_total_number_of_records 的方法 IF_RAP_QUERY_RESPONSE 以响应具有过滤计数的 OData 请求。过滤的结果随即返回到 OData 客户端,例如 SAP Fiori 元素 UI。

以下代码块说明了查询实现类中 select IF_RAP_QUERY_PROVIDER 方法内的搜索实现。

    DATA(lv_search_string) = io_request->get_search_expression( ).
    DATA(lv_search_sql) = |DESCRIPTION LIKE '%{ cl_abap_dyn_prg=>escape_quotes( lv_search_string ) }%'|.

    IF lv_sql_filter IS INITIAL.
      lv_sql_filter = lv_search_sql.
    ELSE.
      lv_sql_filter = |( { lv_sql_filter } AND { lv_search_sql } )|.
    ENDIF.

    IF io_request->is_data_requested( ).
      DATA lt_travel_response TYPE STANDARD TABLE OF /dmo/i_travel_uq.
      SELECT * FROM /dmo/travel
               WHERE (lv_sql_filter)
               ORDER BY ('primary key')
               INTO CORRESPONDING FIELDS OF TABLE @lt_travel_response.
      io_response->set_data( lt_travel_response ).
    ENDIF.

    IF io_request->is_total_numb_of_rec_requested( ).
      SELECT COUNT( * ) FROM /dmo/travel
                        WHERE (lv_sql_filter)
                        INTO @DATA(lv_travel_count).
      io_response->set_total_number_of_records( lv_travel_count ).
    ENDIF.

备注

建议实施默认排序顺序以从数据源返回一致的结果。

有关 API 信息,请参阅方法 get_search_expression。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 在非托管查询中使用参数 · 在非托管查询中实施分页 →