基本测试类结构

ABAP RESTful 应用程序编程模型 › 测试 › 基本测试类结构

存在可应用于任何 RAP 测试类的基本测试类元素。这些元素构成了本章介绍的基本测试类结构。解释的测试类结构可以用作 RAP 测试类的模板。

测试类定义

测试类的定义部分包含基本的元信息、参考变量以及固定设备和测试方法的声明。

分配测试属性

根据测试的复杂性,选择测试类的合适持续时间。较小的测试类的执行时间通常小于 5 秒。在这种情况下,您可以使用 DURATION SHORT。根据相应的运行模式和运行时监控器,超过所选执行时间可能会影响测试结果。

通过使用测试替身,可以防止在测试期间更改持久数据。如果未更改持久数据或系统设置,则可以使用 RISK LEVEL HARMLESS。如果所选风险级别高于系统中允许的风险级别,则不会执行测试。

CLASS ltc_class_name DEFINITION FINAL FOR TESTING
  DURATION SHORT
  RISK LEVEL HARMLESS.

指定测试关系

测试关系将测试类链接到要测试的对象。为行为实施、CDS 视图或服务指定测试关系后,可以直接从 ADT 项目浏览器中的上下文菜单执行其所有相关测试。测试关系在类定义语句上方指定。对于行为实施,相应行为定义的名称紧跟在关键字 BDEF: 之后。对于服务绑定,使用前缀 SRVB。

"! @testing [BDEF:BDEF_name] | [CDS_view_name] | [SRVB:SRVB_name]
CLASS ltc_class_name DEFINITION FINAL FOR TESTING

声明参考变量

对于行为实施的单元测试,请实例化相应的类。为此,请在专用节中声明此类的参考变量。在下面的示例中,测试的行为实施类的名称为 lhc_name。

CDS 和 SQL 测试双重框架可用于创建将在测试中使用的测试双精度值。为了使用这些框架之一,还需要声明其接口的参考变量。

对于使用本地客户端代理的 OData 测试,请声明其接口的参考变量。

PRIVATE SECTION.
CLASS-DATA: class_under_test     TYPE REF TO lhc_name,
            cds_test_environment TYPE REF TO if_cds_test_environment,
            sql_test_environment TYPE REF TO if_osql_test_environment,
            go_client_proxy      TYPE REF TO /iwbep/if_cp_client_proxy.

声明固定设备和测试方法

除了声明测试方法外,还声明固定设备方法。固定设备方法用于设置和拆卸测试环境,为每个执行的测试生成唯一的测试行为。声明的测试方法可能与要测试的方法具有相同的名称。

CLASS-METHODS:
      class_setup,
      class_teardown.

    METHODS:
      setup,
      teardown,
      method_name FOR TESTING.

测试类实施

本节包含上述固定设备和测试方法的实现。

实施方法 class_setup

对于行为实施的单元测试,请使用上面声明的参考变量创建相应类的对象。附加项 FOR TESTING 支持实例化行为实施的处理器类。

对于 OData 测试,创建本地客户端代理的实例并将其分配到将在测试方法中使用以创建所需 OData 请求的参考变量。有关使用本地客户端代理接口为不同系统创建代理实例的具体示例类,请参阅 OData 测试:细化测试类结构。

现在,使用 CDS 测试双重框架或 SQL 测试双重框架为所需的数据库表创建测试双精度。如果通过被测代码中的 CDS 实体执行数据访问,请选择 CDS 测试双重框架。如果您的测试涉及使用 OpenSQL 进行直接数据库访问,请选择 SQL 测试双框架。

要使用 CDS 测试双重框架创建测试双精度,可以使用 create 方法并提供选择要双倍的数据库表的 CDS 视图的名称。因此,在测试期间调用测试双精度值以进行数据访问,而不是实际数据库表。将创建的测试环境对象的引用分配给上面声明的接口参考变量。为了创建多个测试替身,CDS 测试双重框架提供了方法 create_for_multiple_cds。如果测试双精度不仅要通过 CDS 视图访问,还要通过开放式 SQL 调用访问,则另外使用方法 enable_double_redirection。在这种情况下,不需要额外使用 SQL 测试双框架。如果使用 create_for_multiple_cds 方法,则会自动启用双重定向。

要使用 SQL 测试双重框架创建测试副本,可以使用 create 方法并提供要双倍的数据库表的名称。因此,在测试期间而不是实际数据库表期间会调用测试替身进行数据访问。将创建的测试环境对象的引用分配给上面声明的接口参考变量。

如果测试加倍的数据不取决于测试方法的特定测试用例,则可以在类设置方法中将测试数据插入到测试双精度中。为此,请声明一个表,用创建的测试 double 键入该表,然后将所需的测试数据插入表中。接下来,通过填充的表将测试数据插入到双精度中。

METHOD class_setup.
  CREATE OBJECT class_under_test FOR TESTING. "For unit tests of behavior implementations
  go_client_proxy = [Call of creation methods for Local Client Proxy]
  cds_test_environment = cl_cds_test_environment=>create( i_for_entity = 'CDS_view1' ).
  cds_test_environment = cl_cds_test_environment=>create_for_multiple_cds(
                               VALUE #(
                                   ( i_for_entity = 'CDS_view1'            )
                                   ( i_for_entity = 'CDS_view2'           )
                                   ( i_for_entity = 'CDS_view3' )
                                 )
                             ). "For multiple test doubles
  cds_test_environment->enable_double_redirection(  ). "For Open SQL access to the test double
      sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #(
        ( 'database1' )
        ( 'database2' )
        ( 'database3' )
      ) ) .

  " Insert test data into CDS test double
  DATA cds_mock_data TYPE STANDARD TABLE OF test_double.
  cds_mock_data = VALUE #( ( instance_data ) ).
  cds_test_environment->insert_test_data( cds_mock_data ).

  " Insert test data into SQL test double
  DATA sql_mock_data TYPE STANDARD TABLE OF test_double.
  sql_mock_data = VALUE #( ( instance_data ) ).
  sql_test_environment->insert_test_data( sql_mock_data ).
ENDMETHOD.

实施方法 setup

为确保测试方法不受其他测试方法数据的影响,请在每次执行测试方法之前根据需要清除测试两倍的内容。

METHOD setup.
  cds_test_environment->clear_doubles( ).
  sql_test_environment->clear_doubles( ).
ENDMETHOD.

实施方法 teardown

为确保每次测试方法执行后为相关实体重置事务缓冲区,请在拆卸方法中使用 EML 语句 ROLLBACK ENTITIES。

METHOD teardown.
  ROLLBACK ENTITIES.
ENDMETHOD.

实施方法 class_teardown

测试结束时,清除测试环境和创建的测试两倍。

METHOD class_teardown.
  cds_test_environment->destroy( ).
  sql_test_environment->destroy( ).
ENDMETHOD.

实施单元测试的测试方法

无论要测试的对象如何,为单元测试实施测试方法通常涉及许多基本步骤。

首先,使用相应的测试双重框架将测试数据插入到测试双精度中。为此,请声明一个表,用创建的测试 double 键入该表,然后将所需的测试数据插入表中。接下来,通过填充的表将测试数据插入到双精度中。

接下来,调用正在测试的对象。如果要测试行为实施,请调用要测试的方法并分别提供所需数据,通常是测试双重中实例的键值。如果要测试 CDS 视图,请对 CDS 视图的测试字段执行 SELECT 操作并将结果保存在内部表中。

最后,使用类 cl_abap_unit_assert 的断言方法根据预期值检查返回的值。例如,您可以检查测试方法返回的值是否等于预期值。断言检查通常之前有一些准备任务,例如读取测试期间执行的操作结果或填充用于与结果进行比较的内部表。这些任务中的哪个相关取决于相应的 RAP 部件和要测试的逻辑。

展开以下代码示例以查看方法 method_name 的源代码。

示例代码

METHOD method_name.

  " Insert test data into CDS test double
  DATA cds_mock_data TYPE STANDARD TABLE OF test_double.
  cds_mock_data = VALUE #( ( instance_data ) ).
  cds_test_environment->insert_test_data( cds_mock_data ).

  " Insert test data into SQL test double
  DATA sql_mock_data TYPE STANDARD TABLE OF test_double.
  sql_mock_data = VALUE #( ( instance_data ) ).
  sql_test_environment->insert_test_data( sql_mock_data ).

  " Run test for behavior implementation method
  class_under_test->method_under_test(
      keys = CORRESPONDING #( mock_data ) ).

  " Run test for CDS view
  SELECT * FROM cds_view INTO TABLE @DATA(act_results).

  " Preparatory tasks for assert checks
  ...

  " Perform assert checks
  cl_abap_unit_assert=>assert_equals( msg = 'message when assert fails' act = returned_value exp = expected_value ).

ENDMETHOD.

实施 EML 集成测试的测试方法

每个 EML 集成测试涉及许多基本步骤。首先,执行所需的 EML 调用并将响应参数保存在相应的变量中。然后,您可以使用这些变量来检查 EML 调用是否已按预期执行。

如果需要读取实例数据以验证测试结果,现在可以对业务对象执行 EML READ 调用。将结果保存在相应的变量中。

最后,使用类 cl_abap_unit_assert 的断言方法根据预期值检查实际值。例如,您可以检查读取结果中返回的值是否等于预期值。

以下代码块中使用的 EML 语句只是示例,需要根据给定测试用例进行选择。

展开以下代码示例以查看方法 method_name 的源代码。

示例代码

METHOD method_name.

  " Create a Travel
    MODIFY ENTITIES OF /dmo/i_travel_m
      ENTITY travel
        CREATE FIELDS (  ) WITH
        VALUE #( (  ) )
     MAPPED DATA(mapped_create)
     FAILED DATA(failed_create)
     REPORTED DATA(reported_create).

" Perform assert checks to validate intermediate result
  cl_abap_unit_assert=>assert_equals( msg = 'message when assert fails' act = returned_value exp = expected_value ).

" Read result
    READ ENTITIES OF /dmo/i_travel_m
     ENTITY travel
       FIELDS ( )
       WITH VALUE #( (  ) )
       RESULT DATA(result)
       FAILED DATA(failed_read).

" Perform assert checks to validate test result
  cl_abap_unit_assert=>assert_equals( msg = 'message when assert fails' act = returned_value exp = expected_value ).
ENDMETHOD.

实施 OData 集成测试的测试方法

每个 OData 集成测试都涉及许多基本步骤。首先,创建所需的 OData 请求并将其引用分配到变量。

执行创建的请求,并将其响应参考分配到其他变量。

检查是否存在对已执行请求的响应。

获取响应的业务数据并对其执行所需的断言检查。

展开以下代码示例以查看方法 method_name 的源代码。

示例代码

METHOD method_name.

"Create OData request
DATA(lo_request) = go_client_proxy->create_resource_for_entity_set( 'Booking' )->create_request_for_read(  ).

"Execute OData request
DATA(lo_response) = lo_request->execute( ).

"Check request response
cl_abap_unit_assert=>assert_not_initial( lo_response ).

"Get the business data from the response
DATA ls_response_data TYPE STANDARD TABLE OF [CDS entitiy].
lo_response->get_business_data( IMPORTING et_business_data = ls_response_data ).

"Compare the business data to the expected result
cl_abap_unit_assert=>assert_equals( exp =  [expected values] act = ls_response_data ).
ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 测试概念 · 单元测试 →