OData 测试:细化测试类结构
ABAP RESTful 应用程序编程模型 › 测试 › 集成测试 › OData 集成测试 › OData 测试:细化测试类结构
现在您已创建基本测试类结构,可以通过定义提供所需测试配置的基本测试属性、测试关系、变量和固定设备方法来细化此结构。定义的测试类构成了测试方法的基础,将在下一章中实施这些测试方法。
本主题涵盖 OData 测试的特定集成测试类结构。有关 RAP 测试类结构的常规信息,请参阅基本测试类结构。
测试类定义
测试类的定义部分包含基本元信息、参考变量和所用方法的声明。
分配测试属性
由于测试方法的执行预计持续时间不会超过 5 秒,因此可以使用 DURATION SHORT。根据相应的运行模式和运行时监控器,超过所选执行时间可能会影响测试结果。
由于您不会通过单元测试更改持久数据或系统设置,因此可以使用 RISK LEVEL HARMLESS。如果所选风险级别高于系统中允许的风险级别,则不会执行测试。
CLASS /DMO/TC_BOOKING_ODATA DEFINITION
FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS
指定测试关系
您将为将业务对象公开为 OData V2 服务的服务绑定 /DMO/UI_BOOKING_O2 开发集成测试。通过指定测试关系,您可以通过服务绑定的上下文菜单直接运行集成测试。
"!@testing SRVB:/DMO/UI_BOOKING_O2
CLASS /DMO/TC_BOOKING_ODATA DEFINITION
声明类组件
由于您将使用本地客户端代理、过滤 OData 响应的 API 和 CDS 测试双框架以模拟数据库相关性,因此您需要在 CLASS-DATA 部分中声明相应接口的参考变量。此外,还需要结构类型,稍后将用于识别 OData 请求的实体实例。
OData 响应的过滤条件将使用范围表构建。因此,您需要键入一个范围表,其中包含将应用过滤器的字段。
最后,声明一个表和一个变量,用于准备测试双重的预订实例数据。
PRIVATE SECTION.
CLASS-DATA: go_client_proxy TYPE REF TO /iwbep/if_cp_client_proxy,
lo_filter_factory TYPE REF TO /iwbep/if_cp_filter_factory,
lo_filter_node TYPE REF TO /iwbep/if_cp_filter_node,
cds_test_environment TYPE REF TO if_cds_test_environment,
lt_range_currencycode TYPE RANGE OF /dmo/currency_code,
date TYPE /dmo/begin_date,
booking_mock_data TYPE TABLE OF /dmo/booking,
booksupplement_mock_data TYPE STANDARD TABLE OF /dmo/book_suppl.
TYPES:
BEGIN OF ts_key,
travelid TYPE /dmo/travel_id,
bookingid TYPE /dmo/booking_id,
END OF ts_key.
声明所需方法
声明所需的测试和固定设备方法。固定设备方法用于设置和拆卸测试环境,为每个执行的测试生成唯一的测试行为。方法 create_local_client_proxy 用于在方法 class_setup 中创建本地客户端代理的实例。
CLASS-METHODS :
class_setup RAISING cx_static_check,
class_teardown,
create_local_client_proxy
IMPORTING
service_key TYPE /iwbep/if_cp_client_proxy=>ty_s_service_key_v2
RETURNING
VALUE(client_proxy) TYPE REF TO /iwbep/if_cp_client_proxy .
METHODS:
setup,
teardown,
virtual_element FOR TESTING RAISING cx_static_check,
rba_with_filter FOR TESTING RAISING cx_static_check.
测试类实施
本部分介绍固定设备方法的实施,这些固定设备方法指定测试方法使用的测试配置以及用于创建本地客户端代理实例的方法 create_local_client_proxy。
实施方法 class_setup
使用服务绑定 create_local_client_proxy 和服务标识 /DMO/UI_BOOKING_O2 作为参数调用 mehod 0001,并将结果分配给上面声明的参考变量 go_client_proxy。
为了使 OData 请求访问测试双精度数据而不是实际数据库表,现在需要使用 CDS 测试双精度框架创建测试替身。指定 CDS 视图 /DMO/C_Booking_VE 和 /DMO/C_BOOKINGSUPPLEMENT_U 并为这两个视图启用参数 i_select_base_dependencies。由于无法通过指定的 CDS 视图直接访问要双倍的数据库表,因此需要此参数才能启用层次结构测试。它确保为基础结构的所有叶节点创建测试替身。
接下来,使用未来日期使用方法 date 填充变量 get_system_date。此方法还用于测试的虚拟元素实施,以计算航班日期与相应当前日期之间的差异。
最后,使用要插入到测试倍数的实例数据填充表 booking_mock_data 和 booksupplement_mock_data。将变量 date 的内容用于字段 flight_date。
METHOD class_setup.
go_client_proxy = create_local_client_proxy( VALUE #(
service_id = '/DMO/UI_BOOKING_O2'
service_version = '0001' ) ).
CDS_TEST_ENVIRONMENT = cl_cds_test_environment=>create_for_multiple_cds( i_for_entities = VALUE #(
( i_for_entity = '/DMO/C_Booking_VE' i_select_base_dependencies = abap_true )
( i_for_entity = '/DMO/C_BOOKINGSUPPLEMENT_U' i_select_base_dependencies = abap_true )
) ) .
date = cl_abap_context_info=>get_system_date( ) + 10.
booking_mock_data = VALUE #( ( travel_id = '1' booking_id ='1' flight_date = date )
( travel_id = '1' booking_id ='2' flight_date = date )
( travel_id = '2' booking_id ='3' flight_date = date )
( travel_id = '1' booking_id ='4' flight_date = date )
( travel_id = '3' booking_id ='5' flight_date = date )
) .
booksupplement_mock_data = VALUE #( ( travel_id = '1' booking_id = '1' booking_supplement_id = '1' currency_code = 'EUR' price = '5' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '2' currency_code = 'USD' price = '7' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '3' currency_code = 'EUR' price = '8' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '4' currency_code = 'USD' price = '7' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '5' currency_code = 'EUR' price = '5' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '6' currency_code = 'USD' price = '7' )
).
ENDMETHOD.
实施方法 setup
为确保您的测试方法不受其他测试方法数据的影响,请在每次测试方法执行之前清除 CDS 测试两倍的内容。
METHOD setup.
cds_test_environment->clear_doubles( ).
ENDMETHOD.
实施方法 teardown
为确保每次测试方法执行后为相关的 CDS 实体重置事务缓冲区,请在拆卸方法中使用 EML 语句 ROLLBACK ENTITIES。
METHOD teardown.
ROLLBACK ENTITIES.
ENDMETHOD.
实施方法 class_teardown
测试结束时,清除测试环境和创建的测试两倍。
METHOD class_teardown.
cds_test_environment->destroy( ).
ENDMETHOD.
实施方法 create_local_client_proxy
此方法创建用于在 OData 服务上执行 OData V2 调用的 V2 本地客户端代理实例。根据相应的系统,该方法返回云版本或本地客户端代理实例的企业预置版本。
由于两个类在系统中可能不可用,因此请使用动态调用以避免语法错误。
如果两种调用的方法均未返回本地客户端代理实例,则停止测试执行并显示断言错误。
METHOD create_local_client_proxy.
TRY.
" the Cloud version
DATA(class1) = 'CL_WEB_ODATA_CLIENT_FACTORY'.
CALL METHOD (class1)=>create_v2_local_proxy
EXPORTING
is_service_key = service_key
RECEIVING
ro_client_proxy = client_proxy.
CATCH cx_root.
ENDTRY.
IF client_proxy IS NOT BOUND.
TRY.
" the onPrem version
DATA(class2) = '/IWBEP/CL_CP_CLIENT_PROXY_FACT'.
CALL METHOD (class2)=>create_v2_local_proxy
EXPORTING
is_service_key = service_key
RECEIVING
ro_client_proxy = client_proxy.
CATCH cx_root.
ENDTRY.
ENDIF.
cl_abap_unit_assert=>assert_bound( msg = 'cannot get client proxy factory or service binding not active' act = client_proxy ).
ENDMETHOD.
结果测试类
遵循上述步骤后,您的测试类应如下所示,并准备好实施测试方法:
展开以下代码示例以查看测试类 /DMO/TC_BOOKING_ODATA 的源代码。
示例代码
"!@testing SRVB:/DMO/UI_BOOKING_O2
CLASS /DMO/TC_BOOKING_ODATA DEFINITION
FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
PROTECTED SECTION.
PRIVATE SECTION.
CLASS-DATA: go_client_proxy TYPE REF TO /iwbep/if_cp_client_proxy,
lo_filter_factory TYPE REF TO /iwbep/if_cp_filter_factory,
lo_filter_node TYPE REF TO /iwbep/if_cp_filter_node,
cds_test_environment TYPE REF TO if_cds_test_environment,
lt_range_currencycode TYPE RANGE OF /dmo/currency_code,
date TYPE /dmo/begin_date,
booking_mock_data TYPE TABLE OF /dmo/booking,
booksupplement_mock_data TYPE STANDARD TABLE OF /dmo/book_suppl.
TYPES:
BEGIN OF ts_key,
travelid TYPE /dmo/travel_id,
bookingid TYPE /dmo/booking_id,
END OF ts_key.
CLASS-METHODS :
class_setup RAISING cx_static_check,
class_teardown,
create_local_client_proxy
IMPORTING
service_key TYPE /iwbep/if_cp_client_proxy=>ty_s_service_key_v2
RETURNING
VALUE(client_proxy) TYPE REF TO /iwbep/if_cp_client_proxy .
METHODS:
setup,
teardown,
virtual_element FOR TESTING RAISING cx_static_check,
rba_with_filter FOR TESTING RAISING cx_static_check.
ENDCLASS.
CLASS /DMO/TC_BOOKING_ODATA IMPLEMENTATION.
METHOD class_setup.
go_client_proxy = create_local_client_proxy( VALUE #(
service_id = '/DMO/UI_BOOKING_O2'
service_version = '0001' ) ).
CDS_TEST_ENVIRONMENT = cl_cds_test_environment=>create_for_multiple_cds( i_for_entities = VALUE #(
( i_for_entity = '/DMO/C_Booking_VE' i_select_base_dependencies = abap_true )
( i_for_entity = '/DMO/C_BOOKINGSUPPLEMENT_U' i_select_base_dependencies = abap_true )
) ) .
date = cl_abap_context_info=>get_system_date( ) + 10.
booking_mock_data = VALUE #( ( travel_id = '1' booking_id ='1' flight_date = date )
( travel_id = '1' booking_id ='2' flight_date = date )
( travel_id = '2' booking_id ='3' flight_date = date )
( travel_id = '1' booking_id ='4' flight_date = date )
( travel_id = '3' booking_id ='5' flight_date = date )
) .
booksupplement_mock_data = VALUE #( ( travel_id = '1' booking_id = '1' booking_supplement_id = '1' currency_code = 'EUR' price = '5' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '2' currency_code = 'USD' price = '7' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '3' currency_code = 'EUR' price = '8' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '4' currency_code = 'USD' price = '7' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '5' currency_code = 'EUR' price = '5' )
( travel_id = '1' booking_id = '1' booking_supplement_id = '6' currency_code = 'USD' price = '7' )
).
ENDMETHOD.
METHOD setup.
cds_test_environment->clear_doubles( ).
ENDMETHOD.
METHOD teardown.
ROLLBACK ENTITIES.
ENDMETHOD.
METHOD class_teardown.
cds_test_environment->destroy( ).
ENDMETHOD.
METHOD create_local_client_proxy.
TRY.
" the Cloud version
DATA(class1) = 'CL_WEB_ODATA_CLIENT_FACTORY'.
CALL METHOD (class1)=>create_v2_local_proxy
EXPORTING
is_service_key = service_key
RECEIVING
ro_client_proxy = client_proxy.
CATCH cx_root.
ENDTRY.
IF client_proxy IS NOT BOUND.
TRY.
" the onPrem version
DATA(class2) = '/IWBEP/CL_CP_CLIENT_PROXY_FACT'.
CALL METHOD (class2)=>create_v2_local_proxy
EXPORTING
is_service_key = service_key
RECEIVING
ro_client_proxy = client_proxy.
CATCH cx_root.
ENDTRY.
ENDIF.
cl_abap_unit_assert=>assert_bound( msg = 'cannot get client proxy factory or service binding not active' act = client_proxy ).
ENDMETHOD.
METHOD virtual_element.
ENDMETHOD.
METHOD rba_with_filter.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译