实施服务回调类
ABAP RESTful 应用程序编程模型 › 重用 › 集成 SAP Workflow Management › 实施服务回调类
服务回调类实施在完成决策工作流后执行的流程。
在此示例中,回调将工作流的接受/拒绝决策应用于相关差旅实例的 acceptTravel / rejectTravel 操作。
创建类
/dmo/cl_wf_callback。实施接口
if_swf_cpwf_callback:CLASS /dmo/cl_wf_callback DEFINITION PUBLIC ... PUBLIC SECTION. INTERFACES if_swf_cpwf_callback . PROTECTED SECTION. PRIVATE SECTION. ENDCLASS. CLASS /dmo/cl_wf_callback IMPLEMENTATION. METHOD if_swf_cpwf_callback~workflow_instance_completed. ... ENDMETHOD. ENDCLASS.
实施
workflow_instance_completed方法。定义参数
wf_travel和wf_timestampl.Wf_travel包含从工作流接收回调所需的所有字段,wf_timestampl包含接收回调的时间点的时戳。METHOD if_swf_cpwf_callback~workflow_instance_completed. DATA: wf_travel TYPE /dmo/bp_trvl_d_w=>ty_wf_travel, wf_timestampl TYPE timestampl. ... ENDMETHOD.
要接收回调数据,需要帮助器类:
cl_swf_cpwf_api_factory_a4c:使用此类,您可以检索允许访问工作流的工作流 API 的实例。有关更多详细信息,请参阅系统文档。
使用方法 get_context_data_from_json,您会收到来自工作流响应的数据:
... TRY. DATA(cpwf_api) = cl_swf_cpwf_api_factory_a4c=>get_api_instance( ). DATA(json) = cpwf_api->get_workflow_context( iv_cpwf_handle = iv_cpwf_handle ). cpwf_api->get_context_data_from_json( EXPORTING iv_context = json IMPORTING ev_data = wf_travel ). CATCH cx_swf_cpwf_api INTO DATA(lx_cpwf). RAISE EXCEPTION TYPE /dmo/cx_wf_callback EXPORTING previous = lx_cpwf. ENDTRY. ...
填写时戳以保存使用
GET TIME STAMP方法接收响应的时间点:... GET TIME STAMP FIELD wf_timestampl. ...
更新与活动差旅实例的工作流相关的差旅字段。其中包括用于保存用户决策的
WFDecisionWFTimestamp用于保存时间信息。... MODIFY ENTITIES OF /dmo/r_trvl_d_w ENTITY Travel UPDATE FIELDS ( WFDecision WFTimestamp WFHandle ) WITH VALUE #( ( TravelUUID = wf_travel-TravelUUID %is_draft = if_abap_behv=>mk-off WFDecision = wf_travel-WFDecision WFTimestamp = wf_timestampl WFHandle = '' ) ) FAILED DATA(failed) REPORTED DATA(reported).
如果修改失败,请根据失败原因处理异常处理。
有关故障原因的详细信息,请参阅响应参数。
... IF failed-travel IS NOT INITIAL. CASE failed-travel[ 1 ]-%fail-cause. WHEN if_abap_behv=>cause-not_found. RAISE EXCEPTION TYPE /dmo/cx_wf_callback EXPORTING textid = /dmo/cx_wf_callback=>travel_not_found travel_id = wf_travel-travelid. WHEN if_abap_behv=>cause-locked. RAISE EXCEPTION TYPE /dmo/cx_wf_callback EXPORTING textid = /dmo/cx_wf_callback=>travel_locked travel_id = wf_travel-travelid. WHEN OTHERS. RAISE EXCEPTION TYPE /dmo/cx_wf_callback. ENDCASE. ENDIF. ...
根据参数 acceptTravel 中保存的用户决策调用 rejectTravel 或 WFDecision 操作。如果 WFDecision 包含 WF-accepted,则调用 acceptTravel 以更新状态。如果其包含 WF-rejected,则调用操作 rejectTravel。如果 rejectTravel 失败,则会引发异常。使用 COMMIT ENTITIES 将最终决策提交到数据库。
... " Call accept/reject Action based on WF outcome IF wf_travel-WFDecision EQ 'WF-accepted'. MODIFY ENTITIES OF /dmo/r_trvl_d_w ENTITY Travel EXECUTE acceptTravel FROM VALUE #( ( TravelUUID = wf_travel-TravelUUID %is_draft = if_abap_behv=>mk-off ) ) FAILED DATA(failed_accept) REPORTED DATA(reported_accept). IF failed_accept-travel IS NOT INITIAL. RAISE EXCEPTION TYPE /dmo/cx_wf_callback EXPORTING textid = /dmo/cx_wf_callback=>travel_set_status_failed travel_id = wf_travel-travelid. ENDIF. ELSEIF wf_travel-WFDecision EQ 'WF-rejected'. MODIFY ENTITIES OF /dmo/r_trvl_d_w ENTITY Travel EXECUTE rejectTravel FROM VALUE #( ( TravelUUID = wf_travel-TravelUUID %is_draft = if_abap_behv=>mk-off ) ) FAILED DATA(failed_reject) REPORTED DATA(reported_reject). IF failed_reject-travel IS NOT INITIAL. RAISE EXCEPTION TYPE /dmo/cx_wf_callback EXPORTING textid = /dmo/cx_wf_callback=>travel_set_status_failed travel_id = wf_travel-travelid. ENDIF. ENDIF. COMMIT ENTITIES. ...
如果回调失败,则引发异常。
... IF sy-subrc NE 0. RAISE EXCEPTION TYPE /dmo/cx_wf_callback. ENDIF. ...
结果
您已实施回调类 以保留通过工作流接收的接受或拒绝差旅信息。
展开以下代码示例以查看源代码
示例代码
CLASS /dmo/cl_wf_callback DEFINITION
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
INTERFACES if_swf_cpwf_callback .
PROTECTED SECTION.
PRIVATE SECTION.
ENDCLASS.
CLASS /dmo/cl_wf_callback IMPLEMENTATION.
METHOD if_swf_cpwf_callback~workflow_instance_completed.
DATA: wf_travel TYPE /dmo/bp_trvl_d_w=>ty_wf_travel,
wf_timestampl TYPE timestampl.
TRY.
DATA(cpwf_api) = cl_swf_cpwf_api_factory_a4c=>get_api_instance( ).
DATA(json) = cpwf_api->get_workflow_context( iv_cpwf_handle = iv_cpwf_handle ).
cpwf_api->get_context_data_from_json(
EXPORTING
iv_context = json
IMPORTING
ev_data = wf_travel
).
CATCH cx_swf_cpwf_api INTO DATA(lx_cpwf).
RAISE EXCEPTION TYPE /dmo/cx_wf_callback
EXPORTING
previous = lx_cpwf.
ENDTRY.
GET TIME STAMP FIELD wf_timestampl.
MODIFY ENTITIES OF /dmo/r_trvl_d_w
ENTITY Travel
UPDATE FIELDS ( WFDecision WFTimestamp WFHandle )
WITH VALUE #( ( TravelUUID = wf_travel-TravelUUID
%is_draft = if_abap_behv=>mk-off
WFDecision = wf_travel-WFDecision
WFTimestamp = wf_timestampl
WFHandle = '' ) )
FAILED DATA(failed)
REPORTED DATA(reported).
IF failed-travel IS NOT INITIAL.
CASE failed-travel[ 1 ]-%fail-cause.
WHEN if_abap_behv=>cause-not_found.
RAISE EXCEPTION TYPE /dmo/cx_wf_callback
EXPORTING
textid = /dmo/cx_wf_callback=>travel_not_found
travel_id = wf_travel-travelid.
WHEN if_abap_behv=>cause-locked.
RAISE EXCEPTION TYPE /dmo/cx_wf_callback
EXPORTING
textid = /dmo/cx_wf_callback=>travel_locked
travel_id = wf_travel-travelid.
WHEN OTHERS.
RAISE EXCEPTION TYPE /dmo/cx_wf_callback.
ENDCASE.
ENDIF.
" Call accept/reject Action based on WF outcome
IF wf_travel-WFDecision EQ 'WF-accepted'.
MODIFY ENTITIES OF /dmo/r_trvl_d_w
ENTITY Travel
EXECUTE acceptTravel
FROM VALUE #( ( TravelUUID = wf_travel-TravelUUID
%is_draft = if_abap_behv=>mk-off ) )
FAILED DATA(failed_accept)
REPORTED DATA(reported_accept).
IF failed_accept-travel IS NOT INITIAL.
RAISE EXCEPTION TYPE /dmo/cx_wf_callback
EXPORTING
textid = /dmo/cx_wf_callback=>travel_set_status_failed
travel_id = wf_travel-travelid.
ENDIF.
ELSEIF wf_travel-WFDecision EQ 'WF-rejected'.
MODIFY ENTITIES OF /dmo/r_trvl_d_w
ENTITY Travel
EXECUTE rejectTravel
FROM VALUE #( ( TravelUUID = wf_travel-TravelUUID
%is_draft = if_abap_behv=>mk-off ) )
FAILED DATA(failed_reject)
REPORTED DATA(reported_reject).
IF failed_reject-travel IS NOT INITIAL.
RAISE EXCEPTION TYPE /dmo/cx_wf_callback
EXPORTING
textid = /dmo/cx_wf_callback=>travel_set_status_failed
travel_id = wf_travel-travelid.
ENDIF.
ENDIF.
COMMIT ENTITIES.
IF sy-subrc NE 0.
RAISE EXCEPTION TYPE /dmo/cx_wf_callback.
ENDIF.
ENDMETHOD.
ENDCLASS.