工序的缺省输入参数

ABAP RESTful 应用程序编程模型 › 开发 › 开发单个业务对象功能 › 工序的缺省输入参数

上下文

在 Fiori 元素 UI 上触发具有输入参数的操作或函数时,将显示一个弹出窗口,最终用户可以在其中输入这些参数的值。如果要通过在弹出窗口中预设输入参数的缺省值来为最终用户提供输入帮助,则可以使用缺省值函数。缺省值函数计算缺省输入参数,并将其作为结果提供给相应的操作或函数。在 Fiori 元素 UI 上,当最终用户触发相应操作时,计算的缺省值将显示在输入参数的弹出窗口中。

缺省值函数也可用于创建和按关联创建工序的缺省字段。在 Fiori 元素 UI 上,当最终用户触发创建或按关联创建操作时,这些字段将以缺省值显示。

如果不使用 Fiori 元素 UI,请注意使用 OData 应用的要求。

有关缺省值函数的概念信息,请参见操作缺省设置。

过程

开发缺省值函数,包括行为定义及其实施中相关操作的定义。除相关操作外,还需要在投影层公开定义的默认值函数。

示例

此示例的基础是 /DMO/FLIGHT_DRAFT 参考场景包中的操作 deductDiscount,如开发具有专用草稿功能的事务应用中所述。在此示例中,开发了一个缺省值函数,该函数根据执行操作 discount_percent 的实例数据计算参数字段 deductDiscount 的缺省值。

  1. 通过将关键字 GetDefaultsFordeductDiscount 添加到操作定义 { default function GetDefaultsFordeductDiscount ; } 在行为定义中定义缺省值函数 deductDiscount。

    managed;
    strict ( 2 );
    with draft;
    
    define behavior for /DMO/R_Travel_D alias Travel
    ...
    {
      action ( features : instance, authorization : update ) deductDiscount parameter /dmo/a_travel_discount result [1] $self { default function GetDefaultsFordeductDiscount ; }
    ... }
    
  2. 使用为缺省值函数提供的快速修复,在行为实施中生成其方法的声明。

    CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler
    FRIENDS ltc_travel.
    ...
    METHODS GetDefaultsFordeductDiscount FOR READ
      IMPORTING keys FOR FUNCTION Travel~GetDefaultsFordeductDiscount RESULT result.
    ...
    
  3. 实施缺省值功能,如下所示:

    1. 读取导入的实例代码的总价格。将从非现有键值产生的失败条目传递到方法的 failed 响应结构。

    2. 对于每个读取的差旅实例,检查总价格。如果实例的总价格大于或等于 5000,则将包含其主键字段和草稿标识以及值 20 的行作为字段 discount_percen 的输出参数附加到结果表。如果总价格低于 5000,则使用值 10。

    METHOD GetDefaultsFordeductDiscount.
    
        READ ENTITIES OF /DMO/R_TRAVEL_D
          IN LOCAL MODE
          ENTITY Travel
            FIELDS ( TotalPrice )
            WITH CORRESPONDING #( keys )
          RESULT DATA(travels)
          FAILED failed.
    
        LOOP AT travels INTO DATA(travel).
          IF travel-TotalPrice >= 5000.
            APPEND VALUE #( %tky                     = travel-%tky
                            %param-discount_percent  = 20 ) TO result.
          ELSE.
            APPEND VALUE #( %tky                     = travel-%tky
                            %param-discount_percent  = 10 ) TO result.
          ENDIF.
        ENDLOOP.
    
    ENDMETHOD.
    

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 非标准操作的建模参数 · 开发通用功能 →