实施非托管查询
ABAP RESTful 应用程序编程模型 › 开发 › 实施非托管查询
非托管查询使用 ABAP 接口对持久或非持久数据实施只读访问。与查询框架使用 SQL 下推从数据库表中检索数据相比,它支持更灵活的数据检索。
上下文
只要查询框架的标准 SQL 下推不足或根本不可用,或者根本没有持久数据源,就会实施非托管查询,以便对数据源进行只读访问。
非托管查询的用例是
OData 请求的数据源不是数据库表,而是 OData 客户端代理访问的另一个 OData 服务,
通过应用程序特定处理优化性能,
将 AMDP 与 SQL 脚本实施中的某些查询下推参数结合使用,
将呼叫转接到分析引擎,或
增强属性或行级别的查询结果数据,例如,拆分中间总和的行或压缩过滤结果时。
在这些情况下,数据模型在 CDS 视图(例如,参考查询实施类的自定义实体)中定义,其中使用查询提供者接口实施查询。非托管查询的运行时如下图所示。
有关非托管查询和自定义实体的更多背景信息,请参阅非托管查询。
示例场景
以下部分提供查询提供者接口实施的示例。旨在了解如何使用接口 IF_RAP_QUERY_PROVIDER。查询实现示例从数据库表中检索数据,这不是典型用例。
备注
不要在从数据库表检索数据的直接情况下使用自定义查询。该示例仅用于演示目的,因为了解示例不需要有关其他技术(例如,在 AMDP 实施中)的背景信息。此类场景的建议实施是使用 CDS 视图以及由 RAP 运行时引擎选择的 SQL 的基础查询实施。
数据模型在自定义实体中定义。展开以下代码块以查看示例场景的数据模型。出于简化原因,使用与数据源中相同的元素名称。(如果使用不同的名称,则必须将自定义实体的元素映射到查询实施中的相应表字段。确保类型兼容。)
有关自定义实体中语法的信息,请参阅 CDS DDL - DEFINE CUSTOM ENTITY(ABAP 关键字文档)。 展开以下代码示例以查看源代码
自定义实体 /DMO/I_TRAVEL_U
@EndUserText.label: 'Custom entity for unmanaged travel query'
@ObjectModel.query.implementedBy:'ABAP:/dmo/cl_travel_uq'
define custom entity /DMO/I_TRAVEL_UQ
{
key Travel_ID : abap.numc( 8 );
Agency_ID : abap.numc( 6 );
Customer_ID : abap.numc( 6 );
Begin_Date : abap.dats;
End_Date : abap.dats;
Booking_Fee : abap.dec( 17, 3 );
Total_Price : abap.dec( 17, 3 );
Currency_Code : abap.cuky;
Status : abap.char( 1 );
LastChangedAt : timestampl;
}
注释 @ObjectModel.query.ImplementedBy 引用查询实施类。在以下部分中了解如何为此示例场景实施非托管查询。
示例场景中的数据源是数据库表 /dmo/travel,请参阅 ABAP 航班参考场景。
实施
IF_RAP_QUERY_PROVIDER 提供的每种方法都在此实施中使用和说明。每个方法的查询实施的完整源代码均显示在实施步骤之后。
备注
对于 CDS 自定义实体上的每个查询请求,都会重新实例化实施类。从不会缓存类实例。
前提条件
自定义实体引用注释
@ObjectModel.query.implementedBy中的查询实施类。查询实施类通过其
IF_RAP_QUERY_PROVIDER方法实施接口select。
注意
在为 Fiori UI 公开自定义实体的场景中,必须至少包括计数和分页的实施,因为 UI 始终请求计数并设置用于分页的查询选项
$top和$skip。要在页面上获得一致的结果,还必须实施排序方法以支持查询选项
$orderby。请求分页时,RAP 查询引擎会将主键添加到查询选项以获取稳定分页结果。如果未实施相应方法且非托管查询未返回相应信息,则在运行时将出现错误。
备注
为避免在不使用
$top的情况下调用 OData 服务时高资源消耗,基于 ABAP RESTful 编程模型使用默认分页。其中包括
如果客户端不提供
$top,则设置缺省分页。如果
$top超出此限制,则减少对缺省限制的响应如果响应表示部分列表(所有可用数据记录的子集),则向响应添加带有
skiptoken的__next链接。请参阅 https://www.odata.org/documentation/odata-version-2-0/json-format/→ 6。表示条目集合。
备注
RAP 运行时引擎只能处理与具有属性绑定(A1 = A2 和 B1 = B2)的自定义实体之间的关联,而不能处理:
OR、NOT
'=' 以外的其他运算符
使用除 CDS 元素之外的其他内容作为操作数(例如,无文字或变量)
实施步骤
检查是否仅在请求的实体集与自定义实体匹配时才执行查询。
有关实施详细信息,请参阅在非托管查询中返回请求的实体。
分离数据检索和计数的实施。
有关实施详细信息,请参阅请求和设置非托管查询中的数据或计数。
实施过滤器条件,根据
请求的过滤器,
有关实施详细信息,请参阅在非托管查询中实施过滤
请求的搜索词,
有关实施详细信息,请参阅在非托管查询中实施搜索
请求的参数。
有关实施详细信息,请参阅在非托管查询中使用参数。
根据请求的页面获取分页信息和检索数据。
有关实施详细信息,请参阅在非托管查询中实施分页。
获取排序信息,并根据排序元素和方向对检索的数据进行排序。
有关实施详细信息,请参阅在非托管查询中实施排序。
获取请求的元素并仅从数据源中选择相关元素。
有关实施详细信息,请参阅在非托管查询中考虑请求的元素。
获取已聚合和已分组的元素,并相应地对记录进行聚合和分组。
有关实施详细信息,请参阅在非托管查询中实施聚合。
展开以下代码示例以查看源代码
查询实施类 /dmo/cl_travel_uq c
CLASS /dmo/cl_travel_uq DEFINITION
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
INTERFACES if_rap_query_provider.
PROTECTED SECTION.
PRIVATE SECTION.
ENDCLASS.
CLASS /dmo/cl_travel_uq IMPLEMENTATION.
METHOD if_rap_query_provider~select.
TRY.
CASE io_request->get_entity_id( ).
WHEN '/DMO/I_TRAVEL_UQ' .
**query implementation for travel entity
**filter
DATA(lv_sql_filter) = io_request->get_filter( )->get_as_sql_string( ).
TRY.
DATA(lt_filter) = io_request->get_filter( )->get_as_ranges( ).
CATCH cx_rap_query_filter_no_range.
"handle exception
ENDTRY.
**parameters
DATA(lt_parameters) = io_request->get_parameters( ).
DATA(lv_next_year) = CONV /dmo/end_date( cl_abap_context_info=>get_system_date( ) + 365 ) .
DATA(lv_par_filter) = | BEGIN_DATE >= '{ cl_abap_dyn_prg=>escape_quotes( VALUE #( lt_parameters[ parameter_name = 'P_START_DATE' ]-value
DEFAULT cl_abap_context_info=>get_system_date( ) ) ) }'| &&
| AND | &&
| END_DATE <= '{ cl_abap_dyn_prg=>escape_quotes( VALUE #( lt_parameters[ parameter_name = 'P_END_DATE' ]-value
DEFAULT lv_next_year ) ) }'| .
IF lv_sql_filter IS INITIAL.
lv_sql_filter = lv_par_filter.
ELSE.
lv_sql_filter = |( { lv_sql_filter } AND { lv_par_filter } )| .
ENDIF.
**search
DATA(lv_search_string) = io_request->get_search_expression( ).
DATA(lv_search_sql) = |DESCRIPTION LIKE '%{ cl_abap_dyn_prg=>escape_quotes( lv_search_string ) }%'|.
IF lv_sql_filter IS INITIAL.
lv_sql_filter = lv_search_sql.
ELSE.
lv_sql_filter = |( { lv_sql_filter } AND { lv_search_sql } )|.
ENDIF.
**request data
IF io_request->is_data_requested( ).
**paging
DATA(lv_offset) = io_request->get_paging( )->get_offset( ).
DATA(lv_page_size) = io_request->get_paging( )->get_page_size( ).
DATA(lv_max_rows) = COND #( WHEN lv_page_size = if_rap_query_paging=>page_size_unlimited
THEN 0 ELSE lv_page_size ).
**sorting
DATA(sort_elements) = io_request->get_sort_elements( ).
DATA(lt_sort_criteria) = VALUE string_table( FOR sort_element IN sort_elements
( sort_element-element_name && COND #( WHEN sort_element-descending = abap_true THEN ` descending`
ELSE ` ascending` ) ) ).
DATA(lv_sort_string) = COND #( WHEN lt_sort_criteria IS INITIAL THEN `primary key`
ELSE concat_lines_of( table = lt_sort_criteria sep = `, ` ) ).
**requested elements
DATA(lt_req_elements) = io_request->get_requested_elements( ).
**aggregate
DATA(lt_aggr_element) = io_request->get_aggregation( )->get_aggregated_elements( ).
IF lt_aggr_element IS NOT INITIAL.
LOOP AT lt_aggr_element ASSIGNING FIELD-SYMBOL(<fs_aggr_element>).
DELETE lt_req_elements WHERE table_line = <fs_aggr_element>-result_element.
DATA(lv_aggregation) = |{ <fs_aggr_element>-aggregation_method }( { <fs_aggr_element>-input_element } ) as { <fs_aggr_element>-result_element }|.
APPEND lv_aggregation TO lt_req_elements.
ENDLOOP.
ENDIF.
DATA(lv_req_elements) = concat_lines_of( table = lt_req_elements sep = `, ` ).
****grouping
DATA(lt_grouped_element) = io_request->get_aggregation( )->get_grouped_elements( ).
DATA(lv_grouping) = concat_lines_of( table = lt_grouped_element sep = `, ` ).
**select data
DATA lt_travel_response TYPE STANDARD TABLE OF /dmo/i_travel_uq.
SELECT (lv_req_elements) FROM /dmo/travel
WHERE (lv_sql_filter)
GROUP BY (lv_grouping)
ORDER BY (lv_sort_string)
INTO CORRESPONDING FIELDS OF TABLE @lt_travel_response
OFFSET @lv_offset UP TO @lv_max_rows ROWS.
**fill response
io_response->set_data( lt_travel_response ).
ENDIF.
**request count
IF io_request->is_total_numb_of_rec_requested( ).
**select count
SELECT COUNT( * ) FROM /dmo/travel
WHERE (lv_sql_filter)
INTO @DATA(lv_travel_count).
**fill response
io_response->set_total_number_of_records( lv_travel_count ).
ENDIF.
WHEN `/DMO/I_BOOKING_UQ`.
**query implementation for booking entity
ENDCASE.
CATCH cx_rap_query_provider.
ENDTRY.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 接口 IF_SADL_EXIT_SORT_TRANSFORM · 在非托管查询中返回请求的实体 →
