添加元数据扩展

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发只读列表报表应用 › 定义只读场景的数据模型 › 添加元数据扩展

元数据扩展(简称 MDE)是 CDS 对象,允许用户向其数据定义之外的 CDS 实体添加注释。

上下文

要将 UI 元数据与数据模型紧密集成,请使用基于 RAP 应用的 UI 注释直接将 UI 特定元数据添加到数据模型。

SAP Fiori 元素相应地使用元数据,并根据应用的最新楼层计划和设计创建开箱即用的标准化 UI。这使您能够实施全栈 UI 服务,而无需实施任何附加前端代码,除非用例需要。如果需要,您可以使用 SAP Business Application Studio 和 SAP Fiori 工具等工具实施自定义 UI 附加项。

UI 信息始终在 CDS 视图堆栈的消耗层上指定。

要在 UI 上显示数据模型中的数据,必须为使用和相应的 UI 注释添加元数据扩展。

过程

  1. 将 @Metadata.allowExtensions: true 添加到 /DMO/C_Flight_R 和 /DMO/C_Flight_R 的标头。

    此注释允许您为相关 CDS 视图创建元数据扩展

  2. 按创建元数据扩展中所述创建元数据扩展 /DMO/C_Flight_R 和 /DMO/C_Connection_R。

  3. 将以下 UI 注释添加到 /DMO/C_Connection_R:

    连接信息在 SAP Fiori 中显示为列表页面。UI.header 注释定义页面或应用程序的最顶层区域。它为用户提供关键信息、过滤器选项或搜索选项。页眉通常包括页面标题或应用程序徽标等元素。对于连接,注释 UI.headerInfo 定义显示的名称,presentationVariant 注释定义 SAP Fiori 应用中导航源和导航目标之间的布局和显示相关信息,在本例中为每次航班的详细信息。

    UI.facets 定义对象页面布局(导航目标)的详细信息。UI.lineItem 注释定义列表报表中所显示字段的详细信息,如显示顺序。有关详细信息,请参阅[使用构面更改 UI 上的对象页面布局](../../../06-Develop-UI-Specifics/03-Defining-CDS-Annotations-for-Metadata-Driven-UIs/04-Object-Page/02-Using-Facets-to-change-the-Object-Page-Layout.md)和字段。

    代码语法

    @Metadata.layer: #CORE
    
    @UI: { headerInfo: { typeName: 'Connection',
                         typeNamePlural: 'Connections',
                         title: { type: #STANDARD, value: 'ConnectionTitle' }},
           presentationVariant: [{ visualizations: [{type: #AS_LINEITEM}] }]}
    
    annotate entity /DMO/C_Connection_R with
    {
      @UI.facet: [
          {
            id:              'Connection',
            purpose:         #STANDARD,
            type:            #COLLECTION,
            label:           'Connection',
            position:        10
          },
          {
            id:              'General',
            targetQualifier: 'General_FG',
            parentId:        'Connection',
            purpose:         #STANDARD,
            type:            #FIELDGROUP_REFERENCE,
            label:           'General',
            position:        10
          },
          {
            id:              'Departure',
            targetQualifier: 'Departure_FG',
            parentId:        'Connection',
            purpose:         #STANDARD,
            type:            #FIELDGROUP_REFERENCE,
            label:           'Departure',
            position:        20
          },
          {
            id:              'Destination',
            targetQualifier: 'Destination_FG',
            parentId:        'Connection',
            purpose:         #STANDARD,
            type:            #FIELDGROUP_REFERENCE,
            label:           'Destination',
            position:        30
          },
          { id:            'Flight',
            type:          #LINEITEM_REFERENCE,
            label:         'Flight',
            position:      20,
            targetElement: '_Flight'
          }
        ]
    
      @UI: { lineItem: [{ position: 10 }],
             selectionField: [{ position: 10 }],
             fieldGroup:[{ position: 10, qualifier: 'General_FG' }]}
      @EndUserText.quickInfo: 'Airline that operates the flight'
      AirlineID;
    
      @UI: { lineItem: [{ position: 20 }],
             selectionField: [{ position: 20 }],
             fieldGroup:[{ position: 20, qualifier: 'General_FG' }]}
      ConnectionID;
    
      @UI.fieldGroup: [{ position: 30, qualifier: 'General_FG' }]
      Distance;
    
      @UI.fieldGroup: [{ position: 40, qualifier: 'General_FG', label: 'Distance Unit' }]
      DistanceUnit;
    
      @UI: { lineItem: [{ position: 30 }],
             selectionField: [{ position: 30 }],
             fieldGroup:[{ position: 10, qualifier: 'Departure_FG' }]}
      @EndUserText.label: 'Departure Airport'
      DepartureAirport;
    
      @UI.lineItem: [{ position: 50 }]
      @UI.fieldGroup: [{ position: 20, qualifier: 'Departure_FG' }]
      DepartureTime;
    
      @UI: { lineItem: [{ position: 40 }],
             selectionField: [{ position: 40 }],
             fieldGroup: [{ position: 10, qualifier: 'Destination_FG' }]}
      @EndUserText.label: 'Destination Airport'
      DestinationAirport;
    
      @UI.lineItem: [{ position: 60 }]
      @UI.fieldGroup: [{ position: 20, qualifier: 'Destination_FG' }]
      ArrivalTime;
    }
    
  4. 将以下 UI 注释添加到 /DMO/C_FLIGHT_R:

    除 UI.header 和 UI.facet 外,此元数据扩展还定义一个图表,将占用的座位显示为径向图。有关详细信息,请参阅数据点

    代码语法

    @Metadata.layer: #CORE
    
    @UI: { headerInfo: { typeName: 'Flight',
                         typeNamePlural: 'Flights',
                         title: { type: #STANDARD, value: 'FlightDate' }},
           presentationVariant: [{ visualizations: [{type: #AS_LINEITEM}] }]}
    
    @UI.chart: [
      {
        qualifier: 'radialChart',
        title: 'Occupation Rate',
        description: 'Occupied seats in relation to maximum number of seats',
        chartType: #DONUT,
        measures: ['OccupiedSeatsForChart'],
        measureAttributes: [
          {
            measure: 'OccupiedSeatsForChart',
            role: #AXIS_1,
            asDataPoint: true
          }
        ]
      }
    ]
    
    annotate entity /DMO/C_Flight_R with
    {
      @UI.facet: [
          {
            id:              'Flight',
            purpose:         #STANDARD,
            type:            #COLLECTION,
            label:           'Flight',
            position:        10
          },
          {
            id:              'General',
            targetQualifier: 'General_FG',
            parentId:        'Flight',
            purpose:         #STANDARD,
            type:            #FIELDGROUP_REFERENCE,
            label:           'General',
            position:        10
          },
          {
            id:              'Seats',
            targetQualifier: 'Seats_FG',
            parentId:        'Flight',
            purpose:         #STANDARD,
            type:            #FIELDGROUP_REFERENCE,
            label:           'Seats',
            position:        20
          },
          {
            purpose: #HEADER,
            type: #COLLECTION,
            id: 'CollectionFacet'
          },
          {
            parentId   : 'CollectionFacet',
            type       : #CHART_REFERENCE,
            targetQualifier: 'radialChart'
          }
        ]
    
      @UI.fieldGroup: [{ position: 10, qualifier: 'General_FG' }]
      AirlineID;
    
      @UI.fieldGroup: [{ position: 20, qualifier: 'General_FG' }]
      ConnectionID;
    
      @UI.lineItem: [{ position: 10 }]
      @UI.fieldGroup: [{ position: 30, qualifier: 'General_FG' }]
      FlightDate;
    
      @UI.lineItem: [{ position: 20 }]
      @UI.fieldGroup: [{ position: 40, qualifier: 'General_FG' }]
      Price;
    
      @UI.lineItem: [{ position: 30 }]
      @UI.fieldGroup: [{ position: 50, qualifier: 'General_FG' }]
      PlaneType;
    
      @UI.lineItem: [{ position: 40 }]
      @UI.fieldGroup: [{ position: 10, qualifier: 'Seats_FG' }]
      MaximumSeats;
    
      @UI.lineItem: [{ position: 50 }]
      @UI.fieldGroup: [{ position: 20, qualifier: 'Seats_FG' }]
      OccupiedSeats;
    
      @UI: {
        dataPoint: {
          qualifier: 'OccupiedSeatsForChart',
          targetValueElement: 'MaximumSeats'
        },
        lineItem: [
          {
            type: #AS_CHART,
            label: 'Occupation Rate',
            valueQualifier: 'radialChart',
            position: 60
          }
        ]
      }
      OccupiedSeatsForChart;
    }