实施早期非托管编号
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 开发早期非托管编号 › 实施早期非托管编号
在本主题中,我们将介绍如何为业务对象实施早期非托管编号。
差旅
早期非托管编号在行为池 earlynumbering_create 的处理程序类 lhc_travel(局部类型)内的 /DMO/BP_TRAVEL_M 方法中实施。
定义
在行为定义中,差旅实体的早期非管理编号定义如下:
managed implementation in class /DMO/BP_TRAVEL_M unique;
strict(2);
define behavior for /DMO/I_Travel_M alias travel
implementation in class /DMO/BP_TRAVEL_M unique
persistent table /DMO/TRAVEL_M
with additional save
etag master last_changed_at
lock master
early numbering
...
{
field ( readonly ) travel_id;
...
}
实施
根节点级别的早期非托管编号实施必须始终唯一,以确保所有子节点的键值唯一。在此示例中,Number Range Object 用于绘制差旅实体的键值。这保证了即使同时从多个服务调用方法,每个编号也只分配一次。编号范围可以自由定义 - 在此实施中,计数始终增加 1。
(1) 由于 FOR NUMBERING 方法在具有草稿功能的托管场景中调用两次(在 CREATE 期间调用一次,在保存序列期间调用一次),因此实施包括已具有标识的旅行映射,因此在保存序列期间不会覆盖 CREATE 期间分配的标识。这只是后续草稿启用的准备步骤,仅主动管理的业务对象不需要此步骤。
然后从差旅列表中删除已具有标识的差旅。在后续实施中,标识仅分配到之前没有标识的差旅。
(2) 使用编号范围对象 /DMO/TRV_M 实施实际键值分配。方法 number_get 具有以下导入参数:
nr_range_nr:用于分配键值的间隔的标识。
对象:编号范围对象的名称。
数量:所需数量的数量(
entities_wo_travelid中没有标识的旅行数量)
该方法返回要分配的 ID,返回代码指示所抽取的数字以及返回的 ID 的实际数量是否存在问题。您可以根据需要实施错误处理 - 在此示例中,编号范围对象的任何问题都会导致 failed 表中的条目中止 CREATE,并显示错误消息以提供有关所发生错误的更多详细信息。
(3) 然后在 mapped-travel 中分配并映射键值。如果请求了多个编号,则 number 始终返回最大数字,并通过减去请求的数字数来计算分配的起点。然后,每个实例的计数将增加 1。
展开以下代码示例以查看 travel 的早期非托管编号的源代码。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler
PRIVATE SECTION.
METHODS earlynumbering_create FOR NUMBERING
IMPORTING entities FOR CREATE travel.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD earlynumbering_create.
DATA:
entity TYPE STRUCTURE FOR CREATE /DMO/I_Travel_M,
travel_id_max TYPE /dmo/travel_id.
" Ensure Travel ID is not set yet (idempotent)- must be checked when BO is draft-enabled
LOOP AT entities INTO entity WHERE travel_id IS NOT INITIAL.
APPEND CORRESPONDING #( entity ) TO mapped-travel.
ENDLOOP.
DATA(entities_wo_travelid) = entities.
DELETE entities_wo_travelid WHERE travel_id IS NOT INITIAL.
" Get Numbers
TRY.
cl_numberrange_runtime=>number_get(
EXPORTING
nr_range_nr = '01'
object = '/DMO/TRV_M'
quantity = CONV #( lines( entities_wo_travelid ) )
IMPORTING
number = DATA(number_range_key)
returncode = DATA(number_range_return_code)
returned_quantity = DATA(number_range_returned_quantity)
).
CATCH cx_number_ranges INTO DATA(lx_number_ranges).
LOOP AT entities_wo_travelid INTO entity.
APPEND VALUE #( %cid = entity-%cid
%key = entity-%key
%msg = lx_number_ranges
) TO reported-travel.
APPEND VALUE #( %cid = entity-%cid
%key = entity-%key
) TO failed-travel.
ENDLOOP.
EXIT.
ENDTRY.
CASE number_range_return_code.
WHEN '1'.
" 1 - the returned number is in a critical range (specified under "percentage warning" in the object definition)
LOOP AT entities_wo_travelid INTO entity.
APPEND VALUE #( %cid = entity-%cid
%key = entity-%key
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>number_range_depleted
severity = if_abap_behv_message=>severity-warning )
) TO reported-travel.
ENDLOOP.
WHEN '2' OR '3'.
" 2 - the last number of the interval was returned
" 3 - if fewer numbers are available than requested, the return code is 3
LOOP AT entities_wo_travelid INTO entity.
APPEND VALUE #( %cid = entity-%cid
%key = entity-%key
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>not_sufficient_numbers
severity = if_abap_behv_message=>severity-warning )
) TO reported-travel.
APPEND VALUE #( %cid = entity-%cid
%key = entity-%key
%fail-cause = if_abap_behv=>cause-conflict
) TO failed-travel.
ENDLOOP.
EXIT.
ENDCASE.
" At this point ALL entities get a number!
ASSERT number_range_returned_quantity = lines( entities_wo_travelid ).
travel_id_max = number_range_key - number_range_returned_quantity.
" Set Travel ID
LOOP AT entities_wo_travelid INTO entity.
travel_id_max += 1.
entity-travel_id = travel_id_max .
APPEND VALUE #( %cid = entity-%cid
%key = entity-%key
) TO mapped-travel.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
预订
早期非托管编号在行为池 earlynumbering_cba_booking 的处理程序类 lhc_travel(局部类型)内的 /DMO/BP_TRAVEL_M 方法中实施。
定义
在行为定义中,预订实体的早期非托管编号定义如下:
managed;
define behavior for /DMO/I_Booking_M alias booking
implementation in class /DMO/BP_BOOKING_M unique
persistent table /DMO/BOOKING_M
etag master last_changed_at
lock dependent by _Travel
early numbering
...
{
field ( readonly ) travel_id, booking_id;
...
}
实施
差旅实体的编号范围对象保证根实体的唯一键值。对于预订实体,每个差旅实体的编号从 0 开始。
(1) 通过关联读取,检索所有预订标识。
(2) 检索当前差旅的最高预订编号。
(3) 已将具有标识的预订分配到 mapped-booking 且未分配新编号。当内部操作随后执行调用早期编号出口的按关联创建时,可能会发生这种情况。在此场景中,使用 copyTravel 操作复制与其父差旅实例一起复制的每个 booking_id 源预订实例。
(4) 对于每个新预订,max_booking_id 增加 10。
展开以下代码示例以查看 booking 的早期非托管编号的源代码。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler
PRIVATE SECTION.
METHODS earlynumbering_cba_booking FOR NUMBERING
IMPORTING entities FOR CREATE travel\_booking.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD earlynumbering_cba_booking.
DATA: max_booking_id TYPE /dmo/booking_id.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel BY \_booking
FROM CORRESPONDING #( entities )
LINK DATA(bookings).
" Loop over all unique TravelIDs
LOOP AT entities ASSIGNING FIELD-SYMBOL(<travel>) GROUP BY <travel>-travel_id.
" Get highest booking_id from existing bookings belonging to travel
max_booking_id = REDUCE #( INIT max = CONV /dmo/booking_id( '0' )
FOR booking IN bookings USING KEY entity WHERE ( source-travel_id = <travel>-travel_id )
NEXT max = COND /dmo/booking_id( WHEN booking-target-booking_id > max
THEN booking-target-booking_id
ELSE max )
).
" Get highest assigned booking_id from incoming entities, eg from internal operations
max_booking_id = REDUCE #( INIT max = max_booking_id
FOR entity IN entities USING KEY entity WHERE ( travel_id = <travel>-travel_id )
FOR target IN entity-%target
NEXT max = COND /dmo/booking_id( WHEN target-booking_id > max
THEN target-booking_id
ELSE max )
).
" Assign new booking-ids if not already assigned
LOOP AT <travel>-%target ASSIGNING FIELD-SYMBOL(<booking_wo_numbers>).
APPEND CORRESPONDING #( <booking_wo_numbers> ) TO mapped-booking ASSIGNING FIELD-SYMBOL(<mapped_booking>).
IF <booking_wo_numbers>-booking_id IS INITIAL.
max_booking_id += 10 .
<mapped_booking>-booking_id = max_booking_id .
ENDIF.
ENDLOOP.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
预订补充
早期非托管编号在行为池 earlynumbering_cba_booksupplem 的处理程序类 lhc_travel(局部类型)内的 /DMO/BP_BOOKING_M 方法中实施。
定义
在行为定义中,bookingsupplement 实体的早期非托管编号定义如下:
managed;
define behavior for /DMO/I_BookSuppl_M alias booksuppl
implementation in class /DMO/BP_BOOKINGSUPPLEMENT_M unique
persistent table /DMO/BOOKSUPPL_M
with unmanaged save
etag master last_changed_at
lock dependent by _Travel
early numbering
...
{
field ( readonly ) travel_id, booking_id, booking_supplement_id;
}
实施
差旅实体的编号范围对象保证根实体的唯一键值。对于预订补充,每个预订补充实例的编号均从 0 开始。
(1) 通过逐个读取关联,检索所有 supplement_id。
(2) 当前预订的最高补充编号与相应 travel_id 一起检索。
(3) 已将具有标识的预订分配到 mapped-booksuppl 且未分配新编号。当内部操作随后执行调用早期编号出口的按关联创建时,可能会发生这种情况。在此场景中,使用 copyTravel 操作复制与其父预订和差旅实例一起复制的每个 booking_supplement_id 源预订补充实例。
(4) 对于每个新预订,max_booking_suppl_id 将增加 1。
展开以下代码示例以查看 bookingSupplement 的早期非托管编号的源代码。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS earlynumbering_cba_booksupplem FOR NUMBERING
IMPORTING entities FOR CREATE booking\_booksupplement.
...
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD earlynumbering_cba_booksupplem.
DATA: max_booking_suppl_id TYPE /dmo/booking_supplement_id .
READ ENTITIES OF /dmo/i_travel_m IN LOCAL MODE
ENTITY booking BY \_booksupplement
FROM CORRESPONDING #( entities )
LINK DATA(booking_supplements).
" Loop over all unique tky (TravelID + BookingID)
LOOP AT entities ASSIGNING FIELD-SYMBOL(<booking>) GROUP BY <booking>-%tky.
" Get highest bookingsupplement_id from bookings belonging to booking
max_booking_suppl_id = REDUCE #( INIT max = CONV /dmo/booking_supplement_id( '0' )
FOR booksuppl IN booking_supplements USING KEY entity
WHERE ( source-travel_id = <booking>-travel_id
AND source-booking_id = <booking>-booking_id )
NEXT max = COND /dmo/booking_supplement_id( WHEN booksuppl-target-booking_supplement_id > max
THEN booksuppl-target-booking_supplement_id
ELSE max )
).
" Get highest assigned bookingsupplement_id from incoming entities
max_booking_suppl_id = REDUCE #( INIT max = max_booking_suppl_id
FOR entity IN entities USING KEY entity
WHERE ( travel_id = <booking>-travel_id
AND booking_id = <booking>-booking_id )
FOR target IN entity-%target
NEXT max = COND /dmo/booking_supplement_id( WHEN target-booking_supplement_id > max
THEN target-booking_supplement_id
ELSE max )
).
" Assign new booking_supplement-ids
LOOP AT <booking>-%target ASSIGNING FIELD-SYMBOL(<booksuppl_wo_numbers>).
APPEND CORRESPONDING #( <booksuppl_wo_numbers> ) TO mapped-booksuppl ASSIGNING FIELD-SYMBOL(<mapped_booksuppl>).
IF <booksuppl_wo_numbers>-booking_supplement_id IS INITIAL.
max_booking_suppl_id += 1 .
<mapped_booksuppl>-booking_supplement_id = max_booking_suppl_id .
ENDIF.
ENDLOOP.
ENDLOOP.
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译