实施操作

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 开发操作 › 实施操作

在本主题中,我们将演示如何实施两个操作 copyTravel 和 acceptTravel。

操作 copyTravel

此操作复制差旅实例及其相关预订和预订补充实例,并根据复制的数据创建新实例。通过早期非托管编号将新差旅标识分配到新差旅实例。

UI 预览

运行最终应用时,UI 屏幕会为操作提供复制差旅按钮,如下图所示。

访问 Fiori UI 上的操作

用户选择差旅并选择此按钮后,将创建差旅实例及其相关预订和补充实例的副本并将其保存在相应的数据库表中。

按模板创建差旅实例

定义

在行为定义中,操作 copyTravel 定义如下:

define behavior for /DMO/I_Travel_M alias travel
  ...
{ ...
  factory action copyTravel [1];
  ...
}

在处理器类中实施 copyTravel 操作

copyTravel 操作在作为行为池/DMO/BP_TRAVEL_M 一部分的处理器类 lhc_travel 内的 copyTravel 方法中实施。

本地处理器类 lhc_travel 继承自类 cl_abap_behavior_handler 并由框架自动实例化。

copyTravel 方法的签名包括导入参数 keys 用于引用包含要复制数据的 travel(根)实例。要标识根实体,根据行为定义中指定的别名使用别名 travel。然后通过 FOR ACTION travel~copyTravel 处理该操作。

如下列表所示,copyTravel 方法的基本结构包括:

  • 确保仅针对已填充导入参数 %cid 的操作执行调用代码的断言,这对于工厂操作是必需的。如果使用者未填充 %cid 则对于具有子实例的所有源差旅实例,后续按关联创建将失败。由于初始 %cid 是编程错误,因此会进行断言。

  • EML READ 语句,读取所选差旅实例的所有字段,如果成功,还会读取其相关联预订和预订补充实例的所有字段。所选差旅实例由导入参数 keys 标识。

  • LOOP 语句,其中根据 %cid 填充后续创建和按关联创建操作的结构和表,以标识要创建的实例。对于差旅实例,使用导入参数 %cid。预订和预订补充的其他内容标识符必须手动连接。在此实施中,使用导入的 %cid 并连接源实例的相应标识。然后,父实例的内容标识符将用作相应子实体的 %cid_ref 值。目标实例的某些字段将单独处理以满足新差旅的要求,例如,通过验证检查的差旅日期 validateDates。

  • 当未找到从 复制的实例的键值时,复制操作可能会失败。这些失败键将附加到方法输出失败参数。

  • 基于上面填充的内部表创建差旅、预订和预订补充实例的 EML MODIFY 语句。通过早期非托管编号将新差旅标识分配到新差旅实例。实例的内容标识和创建操作提供的相应键值存储在 MODIFY 语句的 mapped_create 结构中,并映射到确定的键值。本地模式下 的修改操作不应失败。因此,在这种情况下,不需要 failed 数据容器。

  • 对于方法更改参数 mapped-travel,分配先前确定的相应工序结构。实例工厂操作的 RAP 合同仅允许在 mapped 中返回一个实例。因此,方法仅返回新差旅实例的映射条件,但不返回子实体的映射。

展开以下代码示例以查看 Action CopyTravel 的源代码。

示例代码

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

  PRIVATE SECTION.

    METHODS copyTravel FOR MODIFY IMPORTING keys FOR ACTION travel~copyTravel RESULT result.
    ...

ENDCLASS.

CLASS lhc_travel IMPLEMENTATION.
  ...

  METHOD copyTravel.

    DATA:
      travels       TYPE TABLE FOR CREATE /DMO/I_Travel_M\\travel,
      bookings_cba  TYPE TABLE FOR CREATE /DMO/I_Travel_M\\travel\_booking,
      booksuppl_cba TYPE TABLE FOR CREATE /DMO/I_Travel_M\\booking\_booksupplement.

    READ TABLE keys WITH KEY %cid = '' INTO DATA(key_with_inital_cid).
    ASSERT key_with_inital_cid IS INITIAL.

    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
ALL FIELDS WITH CORRESPONDING #( keys )
RESULT DATA(travel_read_result).

    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
    ENTITY travel BY {color}_booking
    ALL FIELDS WITH CORRESPONDING #( travel_read_result )
    RESULT DATA(book_read_result).

    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
    ENTITY booking BY {color}_booksupplement
    ALL FIELDS WITH CORRESPONDING #( book_read_result )
    RESULT DATA(booksuppl_read_result).

    LOOP AT keys INTO DATA(key).
      READ TABLE travel_read_result ASSIGNING FIELD-SYMBOL(<travel>) WITH KEY id COMPONENTS %tky = key-%tky.
      IF sy-subrc EQ 0.
        "Fill travel container for creating new travel instance
        APPEND VALUE #( %cid = key-%cid
        %data = CORRESPONDING #( <travel> EXCEPT travel_id ) )
        TO travels ASSIGNING FIELD-SYMBOL(<new_travel>).

        "Fill %cid_ref of travel as instance identifier for cba booking
        APPEND VALUE #( %cid_ref = key-%cid )
        TO bookings_cba ASSIGNING FIELD-SYMBOL(<bookings_cba>).

        <new_travel>-begin_date = cl_abap_context_info=>get_system_date( ).
        <new_travel>-end_date = cl_abap_context_info=>get_system_date( ) + 30.
        <new_travel>-overall_status = 'O'. "Set to open to allow an editable instance

        LOOP AT book_read_result ASSIGNING FIELD-SYMBOL(<booking>) USING KEY entity WHERE travel_id EQ <travel>-travel_id.
          "Fill booking container for creating booking with cba
          APPEND VALUE #( %cid = key-%cid && <booking>-booking_id
          %data = CORRESPONDING #( book_read_result[ KEY entity %tky = <booking>-%tky ] EXCEPT travel_id ) )
          TO <bookings_cba>-%target ASSIGNING FIELD-SYMBOL(<new_booking>).

          "Fill %cid_ref of booking as instance identifier for cba booksuppl
          APPEND VALUE #( %cid_ref = key-%cid && <booking>-booking_id )
          TO booksuppl_cba ASSIGNING FIELD-SYMBOL(<booksuppl_cba>).

          <new_booking>-booking_status = 'N'.

          LOOP AT booksuppl_read_result ASSIGNING FIELD-SYMBOL(<booksuppl>) USING KEY entity WHERE travel_id EQ <travel>-travel_id
          AND booking_id EQ <booking>-booking_id.
            "Fill booksuppl container for creating supplement with cba
            APPEND VALUE #( %cid = key-%cid && <booking>-booking_id && <booksuppl>-booking_supplement_id
            %data = CORRESPONDING #( <booksuppl> EXCEPT travel_id booking_id ) )
            TO <booksuppl_cba>-%target.
          ENDLOOP.
        ENDLOOP.

      ELSE.
        APPEND CORRESPONDING #( key MAPPING %fail = DEFAULT VALUE #( cause = if_abap_behv=>cause-not_found ) ) TO failed-travel.
      ENDIF.
    ENDLOOP.

    "create new BO instance
    MODIFY ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
      ENTITY travel
        CREATE FIELDS ( agency_id customer_id begin_date end_date booking_fee total_price currency_code overall_status description )
          WITH travels
        CREATE BY \_Booking FIELDS ( booking_id booking_date customer_id carrier_id connection_id flight_date flight_price currency_code booking_status )
          WITH bookings_cba
      ENTITY booking
        CREATE BY \_BookSupplement FIELDS ( booking_supplement_id supplement_id price currency_code )
          WITH booksuppl_cba
      MAPPED DATA(mapped_create).

    mapped-travel   =  mapped_create-travel .

  ENDMETHOD.

操作接受差旅

此操作为最终用户提供接受单个差旅的选项,而无需切换到“编辑”模式。

UI 预览

如果运行应用,生成的 UI 屏幕会为您提供新操作的标签接受差旅 - 如下图所示。动作配备了功能控制。仅当实例的状态不是 Accepted 时才能执行操作。有关实施详细信息,请参阅添加静态和动态功能控制。

Fiori UI 上已启用操作的按钮

Fiori UI 上已禁用操作的按钮

定义

请记住,在行为定义中,操作 acceptTravel 定义如下:

define behavior for /DMO/I_Travel_M alias travel
  ...
{

  ...
  action acceptTravel result [1] $self;
  ...
}

在处理器类中实施 acceptTravel 操作

acceptTravel 操作在处理器类 lhc_travel 内的 set_status_accepted 方法中实施,该处理器类属于行为池的本地类型组件 /DMO/BP_TRAVEL_M。

要更新所选差旅实例的 overall_status 数据,请在 EML UPDATE 语句中指定操作 MODIFY。请注意,修改操作在 LOCAL MODE 中进行。因此,更新操作将从权限检查中排除(稍后可实施)。本地模式下托管业务对象提供者的 EML 修改请求不应失败。因此,无需检索 failed 参数。

后续 EML READ 语句为操作结果提供实例数据。

展开以下代码示例以查看 Action AcceptTravel 的源代码。

示例代码

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

PRIVATE SECTION.

  METHODS set_status_accepted FOR MODIFY IMPORTING keys FOR ACTION travel~acceptTravel RESULT result.
  ...

ENDCLASS.

CLASS lhc_travel IMPLEMENTATION.
   ...

  METHOD set_status_accepted.

    " Modify in local mode: BO-related updates that are not relevant for authorization checks
    MODIFY ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
           ENTITY travel
              UPDATE FIELDS ( overall_status )
                 WITH VALUE #( FOR key IN keys ( %tky      = key-%tky
                                                 overall_status = 'A' ) ). " Accepted

    " Read changed data for action result
    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
      ENTITY travel
         ALL FIELDS WITH
         CORRESPONDING #( keys )
       RESULT DATA(travels).

    result = VALUE #( FOR travel IN travels ( %tky      = travel-%tky
                                              %param    = travel ) ).

  ENDMETHOD.

ENDCLASS.

提示

rejectTravel 操作的实施类似于处理器类 acceptTravel 中的 lhc_travel 操作。

操作 ReCalcTotalPrice

每当更改相关金额字段以基于相关实例中的金额计算总差旅价格时,确定都会调用该操作。

由于此操作是只能从业务对象内部调用的内部操作,因此不会向 UI 公开。

定义

操作在行为定义中定义,如下所示:

define behavior for /DMO/I_Travel_M alias travel
  ...
{  ...
  internal action ReCalcTotalPrice;
  ...
}

实施 ReCalcTotalPrice

ReCalcTotalPrice 操作在处理器类 lhc_travel 中具有相同名称的方法中实施。

分别计算每个差旅实例的总价格。EML READ 声明读取所有申请的差旅实例及其预订费和货币代码、相关预订及其航班价格和货币代码以及价格和货币代码的相关预订补充。结果表 travels 的循环可确保汇总相应差旅实例的金额。在 循环中,如果所有相关预订及其相关预订补充的价格具有相同货币代码,则会将其添加到差旅实例的预订费中。如果货币代码不同,则调用货币转换的公共方法以获取以差旅预订费货币计的所有航班价格。

最后,通过更新差旅实例的 EML 修改语句修改实例的已计算总价格。

记住

托管 BO 中本地模式的 EML 修改语句不应失败。在本地模式下,权限、功能和字段控制不适用于 EML 调用。因此,无需检索 failed 或 reported 参数。

展开以下代码示例以查看 Action ReCalCTotalPrice 的源代码。

示例代码

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

PRIVATE SECTION.

    METHODS recalctotalprice FOR MODIFY
      IMPORTING keys FOR ACTION travel~recalctotalprice.
  ...

ENDCLASS.

CLASS lhc_travel IMPLEMENTATION.
   ...

  METHOD recalctotalprice.
    TYPES: BEGIN OF ty_amount_per_currencycode,
             amount        TYPE /dmo/total_price,
             currency_code TYPE /dmo/currency_code,
           END OF ty_amount_per_currencycode.

    DATA: amounts_per_currencycode TYPE STANDARD TABLE OF ty_amount_per_currencycode.

    " Read all relevant travel instances.
    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
         ENTITY travel
            FIELDS ( booking_fee currency_code )
            WITH CORRESPONDING #( keys )
         RESULT DATA(travels).

    DELETE travels WHERE currency_code IS INITIAL.

    " Read all associated bookings and add them to the total price.
    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
      ENTITY travel BY \_booking
        FIELDS ( flight_price currency_code )
      WITH CORRESPONDING #( travels )
      RESULT DATA(bookings).

    " Read all associated booking supplements and add them to the total price.
    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
      ENTITY booking BY \_booksupplement
        FIELDS ( price currency_code )
      WITH CORRESPONDING #( bookings )
      RESULT DATA(bookingsupplements).

    LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
      " Set the start for the calculation by adding the booking fee.
      amounts_per_currencycode = VALUE #( ( amount        = <travel>-booking_fee
                                           currency_code = <travel>-currency_code ) ).

      LOOP AT bookings INTO DATA(booking) USING KEY id WHERE   travel_id = <travel>-travel_id
                                                       AND     currency_code IS NOT INITIAL.
        COLLECT VALUE ty_amount_per_currencycode( amount        = booking-flight_price
                                                  currency_code = booking-currency_code
                                                ) INTO amounts_per_currencycode.
      ENDLOOP.

      LOOP AT bookingsupplements INTO DATA(bookingsupplement) USING KEY id WHERE   travel_id = <travel>-travel_id
                                                                           AND     currency_code IS NOT INITIAL.
        COLLECT VALUE ty_amount_per_currencycode( amount        = bookingsupplement-price
                                                  currency_code = bookingsupplement-currency_code
                                                ) INTO amounts_per_currencycode.
      ENDLOOP.

      DELETE amounts_per_currencycode WHERE currency_code IS INITIAL.

      CLEAR <travel>-total_price.
      LOOP AT amounts_per_currencycode INTO DATA(amount_per_currencycode).
        " If needed do a Currency Conversion
        IF amount_per_currencycode-currency_code = <travel>-currency_code.
          <travel>-total_price += amount_per_currencycode-amount.
        ELSE.
          /dmo/cl_flight_amdp=>convert_currency(
             EXPORTING
               iv_amount                   =  amount_per_currencycode-amount
               iv_currency_code_source     =  amount_per_currencycode-currency_code
               iv_currency_code_target     =  <travel>-currency_code
               iv_exchange_rate_date       =  cl_abap_context_info=>get_system_date( )
             IMPORTING
               ev_amount                   = DATA(total_booking_price_per_curr)
            ).
          <travel>-total_price += total_booking_price_per_curr.
        ENDIF.
      ENDLOOP.
    ENDLOOP.

    " write back the modified total_price of travels
    MODIFY ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
      ENTITY travel
        UPDATE FIELDS ( total_price )
        WITH CORRESPONDING #( travels ).

  ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 将操作定义为行为定义的一部分 · 为 UI 使用启用操作 →