实施动态功能控制

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 添加静态和动态功能控制 › 实施动态功能控制

动态功能控制的实施基于作为行为池一部分的本地处理器类 (lhc_handler) 中的 ABAP 语言。有关实例动态功能控制的详细信息,请参阅实例功能控制。

差旅实体的功能控制

接下来,我们将专门将功能控制应用于演示场景。

UI 预览

下图显示了使用已切换到编辑模式的差旅对象页面示例,实现静态和动态字段控制。所有必填字段均标有红色星号。

字段级别的静态和动态功能控制

下图显示了动态控制对两个操作按钮“接受差旅”和“拒绝差旅”的影响:由于所选差旅实例的状态为已接受,因此禁用操作按钮接受差旅。

操作的动态功能控制

定义

在行为定义中,差旅实体的功能控制定义如下:

define behavior for /DMO/I_Travel_M alias travel
implementation in class /DMO/BP_TRAVEL_M unique
...
{
  // administrative fields: read only
  field ( readonly ) last_changed_at, last_changed_by, created_at, created_by;

  // mandatory fields that are required to create a travel
  field ( mandatory ) agency_id, customer_id, begin_date, end_date, overall_status, booking_fee, currency_code;

  // Semantic Key field, which is readonly for the consumer, value is assigned in early numbering
  field ( readonly ) travel_id;

  // instance action and dynamic action control
  action  ( features: instance ) acceptTravel result [1] $self;
  action  ( features: instance ) rejectTravel result [1] $self;

  association _Booking { create (features:instance); }
...
}

实施差旅实体的动态功能控制

方法实施首先读取为动态字段控制指定的 travel_id 和 overall_status 字段。此读取操作的结果存储在 travels 中。

由于在任何其他修改请求之前调用功能控制实施,因此如果导入的 keys 参数包含无效键值,此 EML 读取请求可能会失败。因此,将检索更改参数 failed 并将其内容直接写入方法的 failed 参数。

根据 overall_status 字段的值,将启用或禁用 rejectTravel 和 acceptTravel 操作,并且是否可以通过关联创建。

展开以下代码示例以在 /DMO/I_Travel_M 中查看 功能控制 的源代码。

示例代码

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.

PRIVATE SECTION.
   ...

    METHODS get_features FOR INSTANCE FEATURES
      IMPORTING keys REQUEST requested_features FOR travel RESULT result.

ENDCLASS.

CLASS lhc_travel IMPLEMENTATION.
   ...

 METHOD get_features.

    READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
      ENTITY travel
         FIELDS (  travel_id overall_status )
         WITH CORRESPONDING #( keys )
       RESULT DATA(travels)
       FAILED failed.

    result = VALUE #( FOR travel IN travels
                       ( %tky                           = travel-%tky
                         %features-%action-rejecttravel = COND #( WHEN travel-overall_status = 'X'
                                                                  THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled  )
                         %features-%action-accepttravel = COND #( WHEN travel-overall_status = 'A'
                                                                  THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled   )
                         %assoc-_booking                = COND #( WHEN travel-overall_status = 'X'
                                                                  THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled   )
                      ) ).

  ENDMETHOD.

ENDCLASS.

登记实体的动态功能控制

UI 预览

下图显示了在编辑模式下切换预订的 Fiori UI 对象页面后静态和动态字段控制的影响。

字段级别的静态和动态功能控制

定义

define behavior for /DMO/I_Booking_M alias booking
implementation in class /DMO/BP_BOOKING_M unique
...
{
  // administrative fields: read only
  field ( readonly ) last_changed_at;

  // static field control
  field ( mandatory ) carrier_id, connection_id, flight_date, booking_status;
  field ( readonly ) travel_id, booking_id;

  // Fields that are mandatory for create but should be read-only afterwards
  field ( mandatory : create, readonly : update) booking_date, customer_id;

  // dynamic feature control create booking supplement by association
  association _BookSupplement { create (features:instance); }
  ...
}

实施登记实体的动态功能控制

get_features 方法通过关联实施创建预订补充的动态字段控制。与差旅实体的功能控制一样,必须读取受影响的预订实例以检索与功能控制相关的字段值。然后必须分配功能控制值。

展开以下代码示例以查看预订实体中功能控制的源代码。

示例代码

CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...

       IMPORTING keys FOR booking~validatestatus.
    METHODS get_features FOR INSTANCE FEATURES

ENDCLASS.

CLASS lhc_travel IMPLEMENTATION.
   ...

    READ ENTITIES OF /dmo/i_travel_m IN LOCAL MODE
      ENTITY booking
         FIELDS ( booking_id booking_status )
         WITH CORRESPONDING #( keys )
      RESULT DATA(bookings)
      FAILED failed.

    result = VALUE #( FOR booking IN bookings
                       ( %tky                   = booking-%tky
                         %assoc-_booksupplement = COND #( WHEN booking-booking_status = 'B'
                                                          THEN if_abap_behv=>fc-o-disabled ELSE if_abap_behv=>fc-o-enabled  ) ) ).

  ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 建模静态和动态功能控制 · 开发验证 →