实施验证
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 开发验证 › 实施验证
验证差旅实体
UI 预览
如果用户输入无效的客户标识(客户数据库表中不可用的标识 /DMO/Customer),则会在保存时启动验证。因此,将拒绝保存实例数据,并将相应消息返回给用户。

定义
在行为定义中,差旅实体的验证定义如下:
define behavior for /DMO/I_Travel_M alias travel
...
{
...
validation validateCustomer on save { create; field customer_id; }
validation validateAgency on save { create; field agency_id; }
validation validateDates on save { create; field begin_date, end_date; }
validation validateStatus on save { create; field overall_status; }
validation validateCurrencyCode on save { create; field currency_code; }
validation validateBookingFee on save { create; field booking_fee; }
}
实施 validateCustomer
毫无疑问,实施验证的所有方法的签名都很相似。
在以下代码块中,您可以查看有关 validate_customer 方法实施的详细信息:首先,EML 读取操作 READ ENTITY 使用 键值提供对所选差旅实例的读取访问权限。
FIELDS ( ) 附加项已使用。作为读取操作的 要访问相关实体字段的数据 的输入(更改)值,将所选差旅实例的 customer_id 字段写入表 travels以访问相关数据。只有此值与验证相关。
在以下代码行中,我们准备对以下数据库选择进行优化。通过使用排序表 customers,我们可以确保数据库访问仅考虑具有非初始客户标识的数据记录。
通过访问数据库表 /dmo/customer 的内容,我们可以检查数据库中是否存在输入的客户标识。
如果验证检测到不一致(客户标识无效或为初始值),则必须提供所有不一致实例的键值作为失败键值并将错误消息返回给使用者。对于所有失败的实例,还会创建使用 NEW 语句完成的相应消息。要访问合适的消息文本,请使用 /dmo/cm_flight_messages 包中的消息类 /DMO/FLIGHT。有关在 RAP 上下文中引发消息的详细信息,请参阅消息。
展开以下代码示例以查看验证 validateCustomer** 的源代码**。
示例代码
CLASS ltc_managed DEFINITION DEFERRED FOR TESTING.
PRIVATE SECTION.
METHODS validate_customer FOR VALIDATE ON SAVE
IMPORTING keys FOR travel~validatecustomer.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD validate_customer.
" Read relevant travel instance data
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
FIELDS ( customer_id )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DATA customers TYPE SORTED TABLE OF /dmo/customer WITH UNIQUE KEY customer_id.
" Optimization of DB select: extract distinct non-initial customer IDs
customers = CORRESPONDING #( travels DISCARDING DUPLICATES MAPPING customer_id = customer_id EXCEPT * ).
DELETE customers WHERE customer_id IS INITIAL.
IF customers IS NOT INITIAL.
" Check if customer ID exists
SELECT FROM /dmo/customer FIELDS customer_id
FOR ALL ENTRIES IN @customers
WHERE customer_id = @customers-customer_id
INTO TABLE @DATA(customers_db).
ENDIF.
" Raise msg for non existing and initial customer id
LOOP AT travels INTO DATA(travel).
IF travel-customer_id IS INITIAL
OR NOT line_exists( customers_db[ customer_id = travel-customer_id ] ).
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
customer_id = travel-customer_id
textid = /dmo/cm_flight_messages=>customer_unkown
severity = if_abap_behv_message=>severity-error )
%element-customer_id = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
实施 validateAgency
用于检查代理标识是否有效的验证具有与 validate_customer 完全相同的结构。该代码可从 /DMO/BP_TRAVEL_M 中的 ABAP 航班参考场景下载。
实施 validateDates
在以下代码块中,您会看到有关 validate_dates 方法实施的详细信息:
EML 读取操作 READ ENTITIES 提供对触发器字段 begin_date 和 end_date 中数据的读取访问。作为读取操作的结果,将所选差旅实例的 begin_date 和 end_date 字段的输入(更改)值写入表行 travels。
如果 end_date 的日期值早于 begin_date 的日期值,或者 begin_date 的日期值位于过去,则验证会检测不一致。每次验证都会产生失败的键和消息。任何失败的键都存储在 FAILED 表中,而 REPORTED 表包含特定于实例的所有消息。
展开以下代码示例以查看验证 validateDates** 的源代码**。
示例代码
CLASS ltc_managed DEFINITION DEFERRED FOR TESTING.
PRIVATE SECTION.
METHODS validate_dates FOR VALIDATE ON SAVE
IMPORTING keys FOR travel~validatedates.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD validate_dates.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
FIELDS ( begin_date end_date )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
LOOP AT travels INTO DATA(travel).
IF travel-end_date < travel-begin_date. "end_date before begin_date
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>begin_date_bef_end_date
severity = if_abap_behv_message=>severity-error
begin_date = travel-begin_date
end_date = travel-end_date
travel_id = travel-travel_id )
%element-begin_date = if_abap_behv=>mk-on
%element-end_date = if_abap_behv=>mk-on
) TO reported-travel.
ELSEIF travel-begin_date < cl_abap_context_info=>get_system_date( ). "begin_date must be in the future
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>begin_date_on_or_bef_sysdate
severity = if_abap_behv_message=>severity-error )
%element-begin_date = if_abap_behv=>mk-on
%element-end_date = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
实施 validateStatus
在以下代码块中,您会看到有关 validateStatus 方法实施的详细信息:
检查 overall_status 值的有效性在 case 循环内执行。有效值 O 、 X 和 A 直接在源代码中指定。
validateStatus。
示例代码
CLASS ltc_managed DEFINITION DEFERRED FOR TESTING.
PRIVATE SECTION.
METHODS validate_customer FOR VALIDATE ON SAVE
IMPORTING keys FOR travel~validatecustomer.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD validate_travel_status.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
FIELDS ( overall_status )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
LOOP AT travels INTO DATA(travel).
CASE travel-overall_status.
WHEN 'O'. " Open
WHEN 'X'. " Cancelled
WHEN 'A'. " Accepted
WHEN OTHERS.
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>status_invalid
severity = if_abap_behv_message=>severity-error
status = travel-overall_status )
%element-overall_status = if_abap_behv=>mk-on
) TO reported-travel.
ENDCASE.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
实施 validateCurrencyCode
在以下代码块中,您会看到有关 validate_currencycode 方法实施的详细信息:
首先,EML 读取操作 READ ENTITY 通过使用 键值提供对所选差旅实例的读取访问权限。
要访问相关实体字段的数据,请使用 FIELDS ( ) 附加项。作为读取操作的结果,将所选差旅实例的 currency_code 字段的输入(更改)值写入表 travels。只有此值与验证相关。
在以下代码行中,我们准备对以下数据库选择进行优化。通过使用排序表 currencies,我们确保数据库访问仅考虑具有非初始货币代码的数据记录。
通过访问标准 CDS 视图 I_currency 的内容,我们可以检查数据库中是否存在输入的货币代码。
如果验证检测到不一致(货币代码无效或为初始值),则必须提供所有不一致实例的键值作为失败键值并将错误消息返回给使用者。对于所有失败的实例,还会创建使用 NEW 语句完成的相应消息。要访问合适的消息文本,请使用 /dmo/cm_flight_messages 包中的消息类 /DMO/FLIGHT。有关在 RAP 上下文中引发消息的详细信息,请参阅消息。
展开以下代码示例以查看验证 validateCurrencyCode 的源代码。
示例代码
CLASS ltc_managed DEFINITION DEFERRED FOR TESTING.
PRIVATE SECTION.
METHODS validate_currencycode FOR VALIDATE ON SAVE
IMPORTING keys FOR travel~validatecurrencycode.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD validate_currencycode.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
FIELDS ( currency_code )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DATA: currencies TYPE SORTED TABLE OF I_Currency WITH UNIQUE KEY currency.
currencies = CORRESPONDING #( travels DISCARDING DUPLICATES MAPPING currency = currency_code EXCEPT * ).
DELETE currencies WHERE currency IS INITIAL.
IF currencies IS NOT INITIAL.
SELECT FROM I_Currency FIELDS currency
FOR ALL ENTRIES IN @currencies
WHERE currency = @currencies-currency
INTO TABLE @DATA(currency_db).
ENDIF.
LOOP AT travels INTO DATA(travel).
IF travel-currency_code IS INITIAL.
" Raise message for empty Currency
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_required
severity = if_abap_behv_message=>severity-error )
%element-currency_code = if_abap_behv=>mk-on
) TO reported-travel.
ELSEIF NOT line_exists( currency_db[ currency = travel-currency_code ] ).
" Raise message for not existing Currency
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_not_existing
severity = if_abap_behv_message=>severity-error
currency_code = travel-currency_code )
%element-currency_code = if_abap_behv=>mk-on
) TO reported-travel.
ENDIF.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
实施 validateBookingFee
在以下代码块中,您会看到有关 validateBookingFee 方法实施的详细信息:
首先,EML 读取操作 READ ENTITY 通过使用键值提供对所选差旅实例的读取访问权限。
要访问相关实体字段的数据,请使用 FIELDS ( ) 附加项。作为读取操作的结果,将所选差旅实例的 booking_fee 字段的输入(更改)值写入表 travels。
循环表 travels。对于预订费小于 0 的每个差旅实例,向报告的响应附加合适的消息。有关在 RAP 上下文中引发消息的详细信息,请参阅消息。
展开以下代码示例以查看验证 validate_BookingFee 的源代码。
示例代码
METHOD validate_BookingFee.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
FIELDS ( booking_fee )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
LOOP AT travels INTO DATA(travel) WHERE booking_fee < 0.
" Raise message for booking fee < 0
APPEND VALUE #( %tky = travel-%tky ) TO failed-travel.
APPEND VALUE #( %tky = travel-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>booking_fee_invalid
severity = if_abap_behv_message=>severity-error )
%element-booking_fee = if_abap_behv=>mk-on
) TO reported-travel.
ENDLOOP.
ENDMETHOD.
预订实体验证
UI 预览
在这种情况下,我们希望验证预订实例的状态值。如果用户根据下图输入错误的值 K,则不会保存实例及其数据,而是显示错误消息。

定义
define behavior for /DMO/I_Booking_M alias booking
...
{
...
validation validateStatus on save { create; field booking_status; }
validation validateCustomer on save { create; field customer_id; }
validation validateConnection on save { create; field carrier_id, connection_id, flight_date; }
validation validateCurrencyCode on save { create; field currency_code; }
validation validateFlightPrice on save { create; field flight_price; }
}
预订实体 validateStatus 的实施
validate_booking_status 方法的实施类似于检查差旅状态时的先前情况。
展开以下代码示例以查看验证 validateStatus** 的源代码**。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS validateStatus FOR VALIDATE ON SAVE
importing keys FOR booking~validateStatus.
...
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD validateStatus.
READ ENTITIES OF /dmo/i_travel_m IN LOCAL MODE
ENTITY booking
FIELDS ( booking_status )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
LOOP AT bookings INTO DATA(booking).
CASE booking-booking_status.
WHEN 'N'. " New
WHEN 'X'. " Canceled
WHEN 'B'. " Booked
WHEN OTHERS.
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>status_invalid
status = booking-booking_status
severity = if_abap_behv_message=>severity-error )
%element-booking_status = if_abap_behv=>mk-on
%path = VALUE #( travel-travel_id = booking-travel_id )
) TO reported-booking.
ENDCASE.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
预订实体 validateCurrencyCode 的实施
validate_currencycode 方法的实施类似于差旅实体上的方法。
展开以下代码示例以查看验证 validateCurrencyCode** 的源代码**。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS validate_currencycode FOR VALIDATE ON SAVE
IMPORTING keys FOR booking~validatecurrencycode.
...
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD validate_currencycode.
READ ENTITIES OF /dmo/i_travel_m IN LOCAL MODE
ENTITY booking
FIELDS ( currency_code )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
DATA: currencies TYPE SORTED TABLE OF i_currency WITH UNIQUE KEY currency.
currencies = CORRESPONDING #( bookings DISCARDING DUPLICATES MAPPING currency = currency_code EXCEPT * ).
DELETE currencies WHERE currency IS INITIAL.
IF currencies IS NOT INITIAL.
SELECT FROM i_currency FIELDS currency
FOR ALL ENTRIES IN @currencies
WHERE currency = @currencies-currency
INTO TABLE @DATA(currency_db).
ENDIF.
LOOP AT bookings INTO DATA(booking).
IF booking-currency_code IS INITIAL.
" Raise message for empty Currency
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_required
severity = if_abap_behv_message=>severity-error )
%element-currency_code = if_abap_behv=>mk-on
%path = VALUE #( travel-travel_id = booking-travel_id )
) TO reported-booking.
ELSEIF NOT line_exists( currency_db[ currency = booking-currency_code ] ).
" Raise message for not existing Currency
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_not_existing
severity = if_abap_behv_message=>severity-error
currency_code = booking-currency_code )
%path = VALUE #( travel-travel_id = booking-travel_id )
%element-currency_code = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
ENDLOOP.
ENDMETHOD.
ENDCLASS.
预订实体 validateCustomer 的实施
validateCustomer 方法的实施类似于差旅实体的相应方法。此外,还会在报告的响应中为每个预订实例提供相应的差旅实例。
展开以下代码示例以查看验证 validateCustomer** 的源代码**。
示例代码
METHOD validate_customer.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Booking
FIELDS ( customer_id )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
DATA customers TYPE SORTED TABLE OF /dmo/customer WITH UNIQUE KEY customer_id.
" Optimization of DB select: extract distinct non-initial customer IDs
customers = CORRESPONDING #( bookings DISCARDING DUPLICATES MAPPING customer_id = customer_id EXCEPT * ).
DELETE customers WHERE customer_id IS INITIAL.
IF customers IS NOT INITIAL.
" Check if customer ID exists
SELECT FROM /dmo/customer FIELDS customer_id
FOR ALL ENTRIES IN @customers
WHERE customer_id = @customers-customer_id
INTO TABLE @DATA(valid_customers).
ENDIF.
" Raise message for non existing and initial customer id
LOOP AT bookings INTO DATA(booking).
IF booking-customer_id IS INITIAL.
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_customer_id
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
%element-customer_id = if_abap_behv=>mk-on
) TO reported-booking.
ELSEIF booking-customer_id IS NOT INITIAL AND NOT line_exists( valid_customers[ customer_id = booking-customer_id ] ).
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>customer_unkown
customer_id = booking-customer_id
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
%element-customer_id = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
ENDLOOP.
ENDMETHOD.
预订实体 validateConnection 的实施
validateConnection 方法首先使用关联 _Travel 读取相关字段以及每个预订实例的相应差旅实例的键值。
方法随后检查字段 carrier_id、connection_id 和 flight_date 是否为初始值。如果是,该方法将返回失败键值并报告相应消息。
如果没有初始字段,则方法检查其值是否与表 /dmo/flight 中的航班匹配。如果不是,该方法将返回失败键值并报告相应的消息。
展开以下代码示例以查看验证 validate_connection** 的源代码**。
示例代码
METHOD validate_connection.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Booking
FIELDS ( booking_id carrier_id connection_id flight_date )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
LOOP AT bookings ASSIGNING FIELD-SYMBOL(<booking>).
" Raise message for non existing airline ID
IF <booking>-carrier_id IS INITIAL.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_airline_id
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-carrier_id = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
" Raise message for non existing connection ID
IF <booking>-connection_id IS INITIAL.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_connection_id
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-connection_id = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
" Raise message for non existing flight date
IF <booking>-flight_date IS INITIAL.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_flight_date
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-flight_date = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
" check if flight connection exists
IF <booking>-carrier_id IS NOT INITIAL AND
<booking>-connection_id IS NOT INITIAL AND
<booking>-flight_date IS NOT INITIAL.
SELECT SINGLE Carrier_ID, Connection_ID, Flight_Date FROM /dmo/flight WHERE carrier_id = @<booking>-carrier_id
AND connection_id = @<booking>-connection_id
AND flight_date = @<booking>-flight_date
INTO @DATA(flight).
IF sy-subrc <> 0.
APPEND VALUE #( %tky = <booking>-%tky ) TO failed-booking.
APPEND VALUE #( %tky = <booking>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>no_flight_exists
carrier_id = <booking>-carrier_id
flight_date = <booking>-flight_date
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = <booking>-%tky ]-target-%tky )
%element-flight_date = if_abap_behv=>mk-on
%element-carrier_id = if_abap_behv=>mk-on
%element-connection_id = if_abap_behv=>mk-on
) TO reported-booking.
ENDIF.
ENDIF.
ENDLOOP.
ENDMETHOD.
实施 validateFlightPrice
在以下代码块中,您会看到有关 validate_flight_price 方法实施的详细信息:
使用关联 _Travel 读取相关字段以及每个预订实例的相应差旅实例的键值。
循环表 bookings。对于航班价格低于 0 的每个预订实例,将合适的消息附加到报告的响应。使用链接表 travel_booking_links 为报告的响应中的每个预订实例提供相应差旅实例的路径。有关在 RAP 上下文中引发消息的详细信息,请参阅消息。
展开以下代码示例以查看验证 validate_flight_price 的源代码。
示例代码
METHOD validate_flight_price.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booking
FIELDS ( flight_price )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Booking BY \_Travel
FROM CORRESPONDING #( bookings )
LINK DATA(travel_booking_links).
LOOP AT bookings INTO DATA(booking) WHERE flight_price < 0.
" Raise message for flight price < 0
APPEND VALUE #( %tky = booking-%tky ) TO failed-booking.
APPEND VALUE #( %tky = booking-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>flight_price_invalid
severity = if_abap_behv_message=>severity-error )
%element-flight_price = if_abap_behv=>mk-on
%path = VALUE #( travel-%tky = travel_booking_links[ KEY id source-%tky = booking-%tky ]-target-%tky )
) TO reported-booking.
ENDLOOP.
ENDMETHOD.
验证补充实体
实施 validate_supplement
读取已导入键值的补充标识并将结果写入内部表 bookingsupplements。将失败的读取键值写入报告的验证响应。
使用关联 _Booking 和 _Travel 读取每个补充实例的相应预订和差旅实例键值。
将读取结果表 bookingsupplements 中的不同补充标识写入通过数据库表 /dmo/supplement 键入的内部表。如果生成的内部表不是初始值,则将此内部表中与数据库表 /dmo/supplement 中的补充标识相匹配的所有补充标识写入另一个内部表 valid_supplements。
读取结果表 bookingsupplements 的循环。对于具有初始补充标识的每个条目,将实例键值附加到失败响应中的补充表,并将合适的消息附加到报告的响应。如果表 valid_supplements 中不包含补充标识,则执行类似操作。在这两种情况下,在报告响应的 %path 组件中,为每个补充实例提供预订和差旅实例键值。
展开以下代码示例以查看验证 validate_supplement 的源代码。
示例代码
METHOD validate_supplement.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl
FIELDS ( supplement_id )
WITH CORRESPONDING #( keys )
RESULT DATA(bookingsupplements)
FAILED DATA(read_failed).
failed = CORRESPONDING #( DEEP read_failed ).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl BY \_Booking
FROM CORRESPONDING #( bookingsupplements )
LINK DATA(booksuppl_booking_links).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl BY \_Travel
FROM CORRESPONDING #( bookingsupplements )
LINK DATA(booksuppl_travel_links).
DATA supplements TYPE SORTED TABLE OF /dmo/supplement WITH UNIQUE KEY supplement_id.
supplements = CORRESPONDING #( bookingsupplements DISCARDING DUPLICATES MAPPING supplement_id = supplement_id EXCEPT * ).
DELETE supplements WHERE supplement_id IS INITIAL.
IF supplements IS NOT INITIAL.
" Check if supplement ID exists
SELECT FROM /dmo/supplement FIELDS supplement_id
FOR ALL ENTRIES IN @supplements
WHERE supplement_id = @supplements-supplement_id
INTO TABLE @DATA(valid_supplements).
ENDIF.
LOOP AT bookingsupplements ASSIGNING FIELD-SYMBOL(<bookingsupplement>).
IF <bookingsupplement>-supplement_id IS INITIAL.
APPEND VALUE #( %tky = <bookingsupplement>-%tky ) TO failed-booksuppl.
APPEND VALUE #( %tky = <bookingsupplement>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>enter_supplement_id
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id source-%tky = <bookingsupplement>-%tky ]-target-%tky
travel-%tky = booksuppl_travel_links[ KEY id source-%tky = <bookingsupplement>-%tky ]-target-%tky )
%element-supplement_id = if_abap_behv=>mk-on
) TO reported-booksuppl.
ELSEIF <bookingsupplement>-supplement_id IS NOT INITIAL AND NOT line_exists( valid_supplements[ supplement_id = <bookingsupplement>-supplement_id ] ).
APPEND VALUE #( %tky = <bookingsupplement>-%tky ) TO failed-booksuppl.
APPEND VALUE #( %tky = <bookingsupplement>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>supplement_unknown
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id source-%tky = <bookingsupplement>-%tky ]-target-%tky
travel-%tky = booksuppl_travel_links[ KEY id source-%tky = <bookingsupplement>-%tky ]-target-%tky )
%element-supplement_id = if_abap_behv=>mk-on
) TO reported-booksuppl.
ENDIF.
ENDLOOP.
ENDMETHOD.
补充实体的 validateCurrencyCode 实施
validateCurrencyCode 方法的实施类似于差旅和预订实体的相应方法。
展开以下代码示例以查看验证 validateCurrencyCode** 的源代码**。
示例代码
METHOD validate_currencycode.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl
FIELDS ( currency_code )
WITH CORRESPONDING #( keys )
RESULT DATA(booking_supplements).
DATA: currencies TYPE SORTED TABLE OF I_Currency WITH UNIQUE KEY currency.
currencies = CORRESPONDING #( booking_supplements DISCARDING DUPLICATES MAPPING currency = currency_code EXCEPT * ).
DELETE currencies WHERE currency IS INITIAL.
IF currencies IS NOT INITIAL.
SELECT FROM I_Currency FIELDS currency
FOR ALL ENTRIES IN @currencies
WHERE currency = @currencies-currency
INTO TABLE @DATA(currency_db).
ENDIF.
LOOP AT booking_supplements INTO DATA(booking_supplement).
IF booking_supplement-currency_code IS INITIAL.
" Raise message for empty Currency
APPEND VALUE #( %tky = booking_supplement-%tky ) TO failed-booksuppl.
APPEND VALUE #( %tky = booking_supplement-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_required
severity = if_abap_behv_message=>severity-error )
%element-currency_code = if_abap_behv=>mk-on
%path = VALUE #( travel-travel_id = booking_supplement-travel_id
booking-booking_id = booking_supplement-booking_id )
) TO reported-booksuppl.
ELSEIF NOT line_exists( currency_db[ currency = booking_supplement-currency_code ] ).
" Raise message for not existing Currency
APPEND VALUE #( %tky = booking_supplement-%tky ) TO failed-booksuppl.
APPEND VALUE #( %tky = booking_supplement-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>currency_not_existing
severity = if_abap_behv_message=>severity-error
currency_code = booking_supplement-currency_code )
%element-currency_code = if_abap_behv=>mk-on
) TO reported-booksuppl.
ENDIF.
ENDLOOP.
ENDMETHOD.
补充实体的 validate_price 实施
使用关联 _Booking 和 _Travel 读取相关字段以及每个补充实例的相应预订和差旅实例的键值。
读取补充实例的循环。如果补充实例的价格小于 0,则将其键值写入失败的响应并将合适的消息附加到报告的响应。在报告响应的 %path 组件中,为每个补充实例提供相应的预订和差旅实例代码。
展开以下代码示例以查看验证 validate_price** 的源代码**。
示例代码
METHOD validate_price.
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl
FIELDS ( price )
WITH CORRESPONDING #( keys )
RESULT DATA(booking_supplements).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl BY \_Booking
FROM CORRESPONDING #( booking_supplements )
LINK DATA(booksuppl_booking_links).
READ ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY booksuppl BY \_Travel
FROM CORRESPONDING #( booking_supplements )
LINK DATA(booksuppl_travel_links).
LOOP AT booking_supplements INTO DATA(book_suppl) WHERE price < 0.
" Raise message for supplement price < 0
APPEND VALUE #( %tky = book_suppl-%tky ) TO failed-booksuppl.
APPEND VALUE #( %tky = book_suppl-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>suppl_price_invalid
severity = if_abap_behv_message=>severity-error )
%path = VALUE #( booking-%tky = booksuppl_booking_links[ KEY id source-%tky = book_suppl-%tky ]-target-%tky
travel-%tky = booksuppl_travel_links[ KEY id source-%tky = book_suppl-%tky ]-target-%tky )
%element-price = if_abap_behv=>mk-on
) TO reported-booksuppl.
ENDLOOP.
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译