实施确定
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 开发确定 › 实施确定
确定差旅实体
定义
在行为定义中,差旅实体的确定定义如下:
define behavior for /DMO/I_Booking_M alias booking
...
{
...
determination calculateTotalPrice on modify {create; field flight_price, currency_code; }
}
calculateTotalPrice
由于所有三个确定都需要定价计算,并且我们将从不同的处理器类访问它们,因此我们将更通用的代码外包到已在先前步骤之一中开发的 ReCalcTotalPrice 内部操作实施,请参阅开发操作。确定的实施仅包含用于执行操作的 EML 调用。
展开以下代码示例以查看确定的源代码 calculateTotalPrice。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS calculatetotalprice FOR DETERMINE ON MODIFY
IMPORTING keys FOR travel~calculatetotalprice.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD calculatetotalprice.
MODIFY ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY travel
EXECUTE recalctotalprice
FROM CORRESPONDING #( keys ).
ENDMETHOD.
...
ENDCLASS.
预订实体确定
UI 预览
下图参考查看具有初始金额(总价格)和差旅货币 0.00 USD 的新创建差旅实例的起点。

如果用户向差旅添加航班预订,则还会更新差旅的总价格。

如果用户将预订的对象页面切换到编辑模式,然后更改航班价格,则总价也会在根级别更新。

定义
在行为定义中,预订实体的确定定义如下:
define behavior for /DMO/I_Booking_M alias booking
...
{
...
determination calculateTotalPrice on modify {create; field flight_price, currency_code; }
}
在预订实体上实施 calculateTotalPrice
由于所有三个确定都需要定价计算,并且我们将从不同的处理器类访问它们,因此我们将更通用的代码外包到已在先前步骤之一中开发的内部操作 ReCalcTotalPrice,请参阅开发操作。在确定的实施中,我们首先放弃已导入密钥中的重复差旅标识,然后对剩余差旅标识执行操作。
展开以下代码示例以查看确定的源代码 calculateTotalPrice。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS calculateTotalPrice FOR DETERMINE ON MODIFY
IMPORTING keys FOR booking~calculateTotalPrice.
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD calculatetotalprice.
DATA: travel_ids TYPE STANDARD TABLE OF /dmo/i_travel_m WITH UNIQUE HASHED KEY key COMPONENTS travel_id.
travel_ids = CORRESPONDING #( keys DISCARDING DUPLICATES MAPPING travel_id = travel_id ).
MODIFY ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Travel
EXECUTE ReCalcTotalPrice
FROM CORRESPONDING #( travel_ids ).
ENDMETHOD.
...
ENDCLASS.
确定预订补充实体
UI 预览
如果用户向给定航班预订添加补充,则会重新计算差旅金额。

更新的差旅金额在 中显示为总价的新值。

定义
在行为定义中,登记补充实体的确定定义如下:
define behavior for /DMO/I_BookSuppl_M alias booksuppl
implementation in class /DMO/BP_BOOKINGSUPPLEMENT_M unique
...
{
...
determination calculateTotalPrice on modify {create; field price, currency_code; }
}
在预订补充实体上实施 calculateTotalPrice
由于所有三个确定都需要定价计算,并且我们将从不同的处理器类访问它们,因此我们将更通用的代码外包到已在先前步骤之一中开发的内部操作 ReCalcTotalPrice,请参阅开发操作。在确定的实施中,我们首先放弃已导入密钥中的重复差旅标识,然后对剩余差旅标识执行操作。
展开以下代码示例以查看确定的源代码 calculateTotalPrice。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS calculateTotalPrice FOR DETERMINE ON MODIFY
IMPORTING keys FOR booksuppl~calculateTotalPrice.
...
ENDCLASS.
CLASS lhc_travel IMPLEMENTATION.
METHOD calculateTotalPrice.
DATA: travel_ids TYPE STANDARD TABLE OF /dmo/i_travel_m WITH UNIQUE HASHED KEY key COMPONENTS travel_id.
travel_ids = CORRESPONDING #( keys DISCARDING DUPLICATES MAPPING travel_id = travel_id ).
MODIFY ENTITIES OF /DMO/I_Travel_M IN LOCAL MODE
ENTITY Travel
EXECUTE ReCalcTotalPrice
FROM CORRESPONDING #( travel_ids ).
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 定义确定 · 在被管理业务对象中集成附加保存 →