实施附加保存

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 在被管理业务对象中集成附加保存 › 实施附加保存

相关业务对象实体的附加保存在行为池 (ABAP_CLASS) 中实施,该行为池由关键字 implementation in class ABAP_CLASS [unique] 在行为定义中指定。

此实施作为行为池的一部分在本地保护程序类中进行。如下面的列表所示,每个这样的局部类都继承自基本保护类 CL_ABAP_BEHAVIOR_SAVER。此超类提供需要在本地保护程序类中重新定义的预定义方法 save_modified。

常规实施步骤

以下列表提供了一个模板,其中包含用于在 save_modified 方法中实施附加保存的主要步骤。

此方法的基本元素是预定义的隐式参数:

  • CREATE-EntityName

  • UPDATE-EntityName

  • DELETE-EntityName

这些参数不仅包含待修改实体的表类型,还包含标识已在当前 LUW 中更改的字段的 %control 结构。仅在 %control 结构中用 true 标记的字段包含保存附加保存的正确值。

备注

如果在附加保存实施中使用功能模块,以导入实例的所有字段并将其全部写入数据库,则在功能模块中使用实例之前执行初步读取和读取实例的所有字段。

访问隐式参数类型的元素信息 (F2)

实施附加保存的模板

展开以下代码示例以查看源代码

方法 Save_Modified。

示例代码

CLASS lcl_saver DEFINITION INHERITING FROM cl_abap_behavior_saver.

  PROTECTED SECTION.
    METHODS save_modified REDEFINITION.

ENDCLASS.

CLASS lcl_saver IMPLEMENTATION.

  METHOD save_modified.

    IF CREATE-EntityName IS NOT INITIAL.

      " Provide table of instance data of all instances that have been created during current transaction

      " Use %CONTROL to get information on what entity fields have been set when creating the instance

    ENDIF.

    IF UPDATE-EntityName IS NOT INITIAL.

      " Provide table of instance data of all instances that have been updated during current transaction

      " Use %CONTROL to get information on what entity fields have been updated
    ENDIF.

    IF DELETE-EntityName IS NOT INITIAL.

      " Provide table with keys of all instances that have been deleted during current transaction

      " NOTE: There is no information on fields when deleting instances

    ENDIF.

  ENDMETHOD.

  ...

ENDCLASS.

差旅业务对象中的附加保存实施

以下示例详细介绍了如何根据我们的差旅演示场景实施附加保存。

在此示例中,对差旅业务对象根实例的所有基本更改都记录在日志表中。这样定义的方式可以保存不同的差旅实例数据,并包含以下字段:

日志表字段

描述

change_id

单个更改的标识符

travel_id

差旅实体的关键字段

changing_operation

差旅实例的标准操作:创建、更新和删除

changed_field_name

已创建或已更改的字段的名称。

changed_value

已创建或已更改的实体字段的值

created_at

实例数据创建、更新或删除的日期和时间

以下清单显示表编辑器中相应表 /DMO/LOG_TRAVEL 的定义。

清单:带表定义的源代码

@EndUserText.label : 'flight reference scenario: log changes to travel entity'
@AbapCatalog.enhancementCategory : #NOT_EXTENSIBLE
@AbapCatalog.tableCategory : #TRANSPARENT
@AbapCatalog.deliveryClass : #A
@AbapCatalog.dataMaintenance : #LIMITED

define table /dmo/log_travel {
  key client         : abap.clnt not null;
  key change_id      : abap.raw(16);
  travel_id          : /dmo/travel_id not null;
  changing_operation : abap.char(10);
  changed_field_name : abap.char(32);
  changed_value      : abap.char(32);
  created_at         : timestampl;

}

UI 预览

消费者在 Fiori UI 上修改业务数据

成功保存后,相关条目将记录在日志表中

定义

在行为定义中,根实体的附加保存可以定义如下:

define behavior for /DMO/I_Travel_M alias travel
implementation in class /DMO/BP_TRAVEL_M unique
persistent table /DMO/TRAVEL_M
with additional save
...

{
   ...
}

实施

示例实施的源代码分为三个部分:

每个部分都使用 IF 语句启动,每个语句检查

  • 差旅实例已创建 (IF create-travel IS NOT INITIAL),

  • 其元素已修改 (IF update-travel IS NOT INITIAL),或

  • 已由使用者删除 (IF delete-travel IS NOT INITIAL)。

相关实例数据将写入内部表 travel_log 并传递到数据库持久存储的日志表 (INSERT /dmo/log_travel...)。

创建新的差旅实例并更新实例数据时,%control 结构用于获取使用者提供或更新哪些字段的信息。%control 结构包含每个字段的标志 if_abap_behv=>mk-on,指示字段是否由使用者提供(或更改)。

创建实例 (1) 时,差旅实体相关字段的新值将写入内部表 travel_log_create。在我们的演示代码中,我们选择 booking_fee 和 overall_status 这两个字段作为示例。它们的值通过 APPEND 作为单独的行传输到 travel_log_create,最后使用 INSERT 写入日志表 /dmo/log_travel。

同样,在更新情况 (2) 中,我们还选择两个字段(即 customer_id 和 description)作为记录的相关字段。因此,每当使用者更改现有差旅实例的其中一个字段的值时,都会将新表行(具有相应更改标识)附加到内部表 travel_log_create。

最后一部分 (3) 处理差旅实例的删除。但是,在这种情况下,我们仅对已删除实例的信息感兴趣。因此,删除实例时没有可用的字段信息。

展开以下代码示例以查看方法 Save_Modified 的源代码。

示例代码

CLASS lcl_save DEFINITION INHERITING FROM cl_abap_behavior_saver.

  PROTECTED SECTION.
    METHODS save_modified REDEFINITION.

ENDCLASS.

CLASS lcl_save IMPLEMENTATION.

  METHOD save_modified.

CLASS lcl_save DEFINITION INHERITING FROM cl_abap_behavior_saver.

  PROTECTED SECTION.
    METHODS save_modified REDEFINITION.

ENDCLASS.

CLASS lcl_save IMPLEMENTATION.

  METHOD save_modified.

    DATA travel_log        TYPE STANDARD TABLE OF /dmo/log_travel.
    DATA travel_log_create TYPE STANDARD TABLE OF /dmo/log_travel.
    DATA travel_log_update TYPE STANDARD TABLE OF /dmo/log_travel.

    " (1) Get instance data of all instances that have been created
    IF create-travel IS NOT INITIAL.
      " Creates internal table with instance data
      travel_log = CORRESPONDING #( create-travel ).

      LOOP AT travel_log ASSIGNING FIELD-SYMBOL(<travel_log>).
        <travel_log>-changing_operation = 'CREATE'.

        " Generate time stamp
        GET TIME STAMP FIELD <travel_log>-created_at.

        " Read travel instance data into ls_travel that includes %control structure
        READ TABLE create-travel WITH TABLE KEY entity COMPONENTS travel_id = <travel_log>-travel_id INTO DATA(travel).
        IF sy-subrc = 0.

          " If new value of the booking_fee field created
          IF travel-%control-booking_fee = cl_abap_behv=>flag_changed.
            " Generate uuid as value of the change_id field
            TRY.
                <travel_log>-change_id = cl_system_uuid=>create_uuid_x16_static( ) .
              CATCH cx_uuid_error.
                "handle exception
            ENDTRY.
            <travel_log>-changed_field_name = 'booking_fee'.
            <travel_log>-changed_value = travel-booking_fee.
            APPEND <travel_log> TO travel_log_create.
          ENDIF.

          " If new value of the overall_status field created
          IF travel-%control-overall_status = cl_abap_behv=>flag_changed.
            " Generate uuid as value of the change_id field
            TRY.
                <travel_log>-change_id = cl_system_uuid=>create_uuid_x16_static( ) .
              CATCH cx_uuid_error.
                "handle exception
            ENDTRY.
            <travel_log>-changed_field_name = 'overall_status'.
            <travel_log>-changed_value = travel-overall_status.
            APPEND <travel_log> TO travel_log_create.
          ENDIF.

          " IF  ls_travel-%control-...

        ENDIF.

      ENDLOOP.

      " Inserts rows specified in lt_travel_log_c into the DB table /dmo/log_travel
      INSERT /dmo/log_travel FROM TABLE @travel_log_create.

    ENDIF.

    " (2) Get instance data of all instances that have been updated during the transaction
    IF update-travel IS NOT INITIAL.
      travel_log = CORRESPONDING #( update-travel ).

      LOOP AT update-travel ASSIGNING FIELD-SYMBOL(<travel_log_update>).

        ASSIGN travel_log[ travel_id = <travel_log_update>-travel_id ] TO FIELD-SYMBOL(<travel_log_db>).

        <travel_log_db>-changing_operation = 'UPDATE'.

        " Generate time stamp
        GET TIME STAMP FIELD <travel_log_db>-created_at.

        IF <travel_log_update>-%control-customer_id = if_abap_behv=>mk-on.
          <travel_log_db>-changed_value = <travel_log_update>-customer_id.
          " Generate uuid as value of the change_id field
          TRY.
              <travel_log_db>-change_id = cl_system_uuid=>create_uuid_x16_static( ) .
            CATCH cx_uuid_error.
              "handle exception
          ENDTRY.

          <travel_log_db>-changed_field_name = 'customer_id'.

          APPEND <travel_log_db> TO travel_log_update.

        ENDIF.

        IF <travel_log_update>-%control-description = if_abap_behv=>mk-on.
          <travel_log_db>-changed_value = <travel_log_update>-description.

          " Generate uuid as value of the change_id field
          TRY.
              <travel_log_db>-change_id = cl_system_uuid=>create_uuid_x16_static( ) .
            CATCH cx_uuid_error.
              "handle exception
          ENDTRY.

          <travel_log_db>-changed_field_name = 'description'.

          APPEND <travel_log_db> TO travel_log_update.

        ENDIF.

        "IF <fs_travel_log_u>-%control-...

      ENDLOOP.

      " Inserts rows specified in lt_travel_log_u into the DB table /dmo/log_travel
      INSERT /dmo/log_travel FROM TABLE @travel_log_update.

    ENDIF.

    " (3) Get keys of all travel instances that have been deleted during the transaction
    IF delete-travel IS NOT INITIAL.
      travel_log = CORRESPONDING #( delete-travel ).
      LOOP AT travel_log ASSIGNING FIELD-SYMBOL(<travel_log_delete>).
        <travel_log_delete>-changing_operation = 'DELETE'.
        " Generate time stamp
        GET TIME STAMP FIELD <travel_log_delete>-created_at.
        " Generate uuid as value of the change_id field
        TRY.
            <travel_log_delete>-change_id = cl_system_uuid=>create_uuid_x16_static( ) .
          CATCH cx_uuid_error.
            "handle exception
        ENDTRY.

      ENDLOOP.

      " Inserts rows specified in lt_travel_log into the DB table /dmo/log_travel
      INSERT /dmo/log_travel FROM TABLE @travel_log.

    ENDIF.

  ENDMETHOD.

ENDCLASS.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 在行为定义中定义附加保存 · 在被管理业务对象中集成非托管保存 →