实施保存处理器方法
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发业务逻辑 › 在被管理业务对象中集成非托管保存 › 实施保存处理器方法
相关业务对象实体的非托管保存在行为池 (ABAP_ClASS) 中实施,该行为池由关键字 implementation in class ABAP_ClASS [unique] 在行为定义中指定。
此实施作为行为池的一部分在本地保护程序类中进行。如下面的列表所示,每个这样的局部类都继承自基本保护类 CL_ABAP_BEHAVIOR_SAVER。此超类提供需要在本地保护程序类 save_modified 中重新定义的预定义方法 lhc_saver。
记住
约定:实现
save_modified方法的局部保护程序类是单独的全局类或根实施的一部分(根实体的行为池)。
常规实施步骤
以下列表提供了一个模板,其中包含用于在 save_modified 方法中实施非托管保存的主要步骤。
此方法的基本元素是预定义的隐式参数:
CREATE-EntityNameUPDATE-EntityNameDELETE-EntityName
这些参数不仅包含要修改的实体的表类型,还包含可用于识别在当前事务期间更改了哪些元素的 %control 结构。

save_modified 方法的实际实施步骤显示在以下模板中:
实施非托管保存的模板
CLASS lcl_saver DEFINITION INHERITING FROM cl_abap_behavior_saver.
PROTECTED SECTION.
METHODS save_modified REDEFINITION.
ENDCLASS.
CLASS lcl_saver IMPLEMENTATION.
METHOD save_modified.
IF CREATE-EntityName IS NOT INITIAL.
" Provide table of instance data of all instances that have been created during current transaction
" Use %CONTROL to get information on what entity fields have been set or updated during the current transaction
ENDIF.
IF UPDATE-EntityName IS NOT INITIAL.
" Provide table of instance data of all instances that have been updated during current transaction
" Use %CONTROL to get information on what entity fields have been updated
ENDIF.
IF DELETE-EntityName IS NOT INITIAL.
" Provide table with keys of all instances that have been deleted during current transaction
" NOTE: There is no information on fields when deleting instances
ENDIF.
ENDMETHOD.
...
ENDCLASS.
在差旅业务对象中实施非管理保存
以下示例详细介绍了如何根据我们的差旅演示场景专门实施非托管 save。特别是,必须扩展之前的实施,以便可用功能模块用于保存预订补充子实体业务数据的更改。
函数模块
在我们的示例中,用于创建、更改和删除预订补充实体实例的相应功能模块已在演示包 /DMO/FLIGHT_MANAGED 的相应功能组中提供。

功能模块 /DMO/FLIGHT_BOOKSUPPL_C
FUNCTION /dmo/flight_booksuppl_c
IMPORTING
VALUE(values) TYPE /dmo/tt_booksuppl_m.
INSERT /dmo/booksuppl_m FROM TABLE @values.
ENDFUNCTION.
备注
要使用此源代码,
/dmo/tt_booksuppl_m导入参数还需要表类型values。

以下清单为您提供函数模块的源代码,用于持久存储现有登记补充实例的各个元素。
功能模块 /DMO/FLIGHT_BOOKSUPPL_U
FUNCTION /dmo/flight_booksuppl_u
IMPORTING
VALUE(values) TYPE /dmo/tt_booksuppl_m.
UPDATE /dmo/booksuppl_m FROM TABLE @values.
ENDFUNCTION.
以下清单提供了用于删除登记补充实例的功能模块的源代码。
功能模块 /DMO/FLIGHT_BOOKSUPPL_D
FUNCTION /dmo/flight_booksuppl_d
IMPORTING
VALUE(values) TYPE /dmo/tt_booksuppl_m.
DELETE /dmo/booksuppl_m FROM TABLE @values.
ENDFUNCTION.
定义
在行为定义中,子实体 booksuppl 的未手动保存可能定义如下:
define behavior for /DMO/I_Travel_M alias travel
implementation in class /DMO/BP_TRAVEL_M unique
...
{
...
}
...
define behavior for /DMO/I_BookSuppl_M alias booksuppl
implementation in class /DMO/BP_BOOKINGSUPPLEMENT_M unique
with unmanaged save
...
{
...
}
实施
如下方列表所示,示例实施的源代码分为三个部分:
每个部分都使用 IF 语句启动,每个语句检查预订补充实例是否已创建、其元素是否已由使用者修改或删除。相关实例数据将写入内部表booksuppls_db 并传递到数据库中持久存储的相应功能模块。
如果更新实例数据 (IF update-booksuppl IS NOT INITIAL),%control 结构用于获取使用者已更新哪些字段的信息。%control 结构包含每个字段的标志 if_abap_behv=>mk-on,指示字段是否由使用者提供(更改)。
要消除用缺省值覆盖未更改字段的选项,我们必须确保根据数据库数据保留这些字段。这就是我们使用 语句从数据库中读取当前数据集的原因 SELECT * FROM /dmo/booksuppl_m FOR ALL ENTRIES IN @booksuppls_db...
展开以下代码示例以查看方法 Save_Modified 的源代码。
示例代码
CLASS lcl_save DEFINITION INHERITING FROM cl_abap_behavior_saver.
PROTECTED SECTION.
METHODS save_modified REDEFINITION.
ENDCLASS.
CLASS lcl_save IMPLEMENTATION.
METHOD save_modified.
DATA booksuppls_db TYPE STANDARD TABLE OF /dmo/booksuppl_m.
" (1) Get instance data of all instances that have been created
IF create-booksuppl IS NOT INITIAL.
booksuppls_db = CORRESPONDING #( create-booksuppl ).
CALL FUNCTION '/DMO/FLIGHT_BOOKSUPPL_C' EXPORTING values = booksuppls_db .
ENDIF.
" (2) Get instance data of all instances that have been updated during the transaction
booksuppls_db = CORRESPONDING #( update-booksuppl ).
IF booksuppls_db IS NOT INITIAL.
" Read all field values from database
SELECT * FROM /dmo/booksuppl_m FOR ALL ENTRIES IN @booksuppls_db
WHERE booking_supplement_id = @booksuppls_db-booking_supplement_id
INTO TABLE @booksuppls_db .
" Take over field values that have been changed during the transaction
LOOP AT update-booksuppl ASSIGNING FIELD-SYMBOL(<unmanaged_booksuppl>).
ASSIGN booksuppls_db[ travel_id = <unmanaged_booksuppl>-travel_id
booking_id = <unmanaged_booksuppl>-booking_id
booking_supplement_id = <unmanaged_booksuppl>-booking_supplement_id
] TO FIELD-SYMBOL(<booksuppl_db>).
IF <unmanaged_booksuppl>-%control-supplement_id = if_abap_behv=>mk-on.
<booksuppl_db>-supplement_id = <unmanaged_booksuppl>-supplement_id.
ENDIF.
IF <unmanaged_booksuppl>-%control-price = if_abap_behv=>mk-on.
<booksuppl_db>-price = <unmanaged_booksuppl>-price.
ENDIF.
IF <unmanaged_booksuppl>-%control-currency_code = if_abap_behv=>mk-on.
<booksuppl_db>-currency_code = <unmanaged_booksuppl>-currency_code.
ENDIF.
ENDLOOP.
" Update the complete instance data
CALL FUNCTION '/DMO/FLIGHT_BOOKSUPPL_U' EXPORTING values = booksuppls_db .
ENDIF.
" (3) Get keys of all travel instances that have been deleted during the transaction
IF delete-booksuppl IS NOT INITIAL.
booksuppls_db = CORRESPONDING #( delete-booksuppl ).
CALL FUNCTION '/DMO/FLIGHT_BOOKSUPPL_D' EXPORTING values = booksuppls_db .
ENDIF.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 在行为定义中定义非托管保存 · 开发灵活服务使用的预测层 →