为处理人创建投影 CDS 视图
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发托管事务应用 › 开发灵活服务使用的预测层 › 提供用于投影的数据模型 › 处理器业务对象预测的映射视图 › 为处理人创建投影 CDS 视图
要为定义处理器应用程序范围的业务对象映射定义数据模型,需要执行以下任务:
为处理人创建投影 CDS 视图
数据处理人需要能够创建、更新和删除差旅实体、预订实体和预订补充实体的条目。这意味着,必须投影构成结构的所有三个节点。
对于以下 CDS 视图,通过在数据定义的创建向导中选择映射视图模板创建相应的映射视图。
|
业务对象结构的 CDS 视图 |
/DMO/I_TRAVEL_M |
/DMO/I_BOOKING_M |
/DMO/I_BOOKSUPPL_M |
|
业务对象映射的 CDS 视图 |
/DMO/C_TRAVEL_PROCESSOR_M |
/DMO/C_BOOKING_PROCESSOR_M |
/DMO/C_BOOKSUPPL_PROCESSOR_M |
备注
名称根据映射视图的命名规则进行分配:开发对象的命名规则。
有关映射视图中语法的信息,请参阅将视图实体定义为映射(ABAP 关键字文档)。
定义处理器映射视图的数据模型
以下主题为您提供有关如何为处理人的业务对象映射中使用的 CDS 映射视图定义数据模型的详细描述。
差旅预测视图 /DMO/C_TRAVEL_PROCESSOR_M
对于服务特定投影,需要定义元素以及所有 UI 细节。
数据模型定义为 UI 服务公开的元素。此外,在映射视图的数据定义中,您可以定义所有 UI 规范。
可通过为处理人实施 CDS 差旅预测视图中的相应功能来实现以下 UI。
预览:处理器的 UI 应用程序


展开以下代码示例以查看差旅预测视图 /DMO/C_Travel_Processor_M 的源代码。
示例代码
@EndUserText.label: 'Travel projection view'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@UI: {
headerInfo: { typeName: 'Travel', typeNamePlural: 'Travels', title: { type: #STANDARD, value: 'TravelID' } } }
@Search.searchable: true
define root view entity /DMO/C_Travel_Processor_M
provider contract transactional_query
as projection on /DMO/I_Travel_M
{
@UI.facet: [ { id: 'Travel',
purpose: #STANDARD,
type: #IDENTIFICATION_REFERENCE,
label: 'Travel',
position: 10 },
{ id: 'Booking',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Booking',
position: 20,
targetElement: '_Booking'}]
@UI: {
lineItem: [ { position: 10, importance: #HIGH } ,
{ type: #FOR_ACTION, dataAction: 'copyTravel', label: 'Copy Travel' } ],
identification: [ { position: 10, label: 'Travel ID' } ] }
@Search.defaultSearchElement: true
key travel_id as TravelID,
@UI: {
lineItem: [ { position: 20, importance: #HIGH } ],
identification: [ { position: 20 } ],
selectionField: [ { position: 20 } ] }
@Consumption.valueHelpDefinition: [{ entity : {name: '/DMO/I_Agency', element: 'AgencyID' } }]
@ObjectModel.text.element: ['AgencyName']
@Search.defaultSearchElement: true
agency_id as AgencyID,
_Agency.Name as AgencyName,
@UI: {
lineItem: [ { position: 30, importance: #HIGH } ],
identification: [ { position: 30 } ],
selectionField: [ { position: 30 } ] }
@Consumption.valueHelpDefinition: [{ entity : {name: '/DMO/I_Customer', element: 'CustomerID' } }]
@ObjectModel.text.element: ['CustomerName']
@Search.defaultSearchElement: true
customer_id as CustomerID,
_Customer.LastName as CustomerName,
@UI: {
lineItem: [ { position: 40, importance: #MEDIUM } ],
identification: [ { position: 40 } ] }
begin_date as BeginDate,
@UI: {
lineItem: [ { position: 41, importance: #MEDIUM } ],
identification: [ { position: 41 } ] }
end_date as EndDate,
@UI: {
identification: [ { position: 42 } ] }
@Semantics.amount.currencyCode: 'CurrencyCode'
booking_fee as BookingFee,
@UI: {
lineItem: [ { position: 43, importance: #MEDIUM } ],
identification: [ { position: 43, label: 'Total Price' } ] }
@Semantics.amount.currencyCode: 'CurrencyCode'
total_price as TotalPrice,
@Consumption.valueHelpDefinition: [{entity: {name: 'I_Currency', element: 'Currency' }}]
currency_code as CurrencyCode,
@UI: {
lineItem: [ { position: 50, importance: #HIGH } ],
identification: [ { position: 45, label: 'Status' } ],
selectionField: [{ position: 40 }],
textArrangement: #TEXT_ONLY
}
@Consumption.valueHelpDefinition: [{ entity: { name: '/DMO/I_Overall_Status_VH', element: 'OverallStatus' }}]
@ObjectModel.text.element: ['OverallStatusText']
overall_status as OverallStatus,
@UI.hidden: true
_OverallStatus._Text.Text as OverallStatusText : localized,
@UI: {
identification:[ { position: 46 } ] }
description as Description,
@UI.hidden: true
last_changed_at as LastChangedAt,
/* Associations */
_Booking : redirected to composition child /DMO/C_Booking_Processor_M,
_Agency,
_Customer,
_OverallStatus
}
解释
对于我们的场景中差旅映射视图的数据模型,您可以采用预计视图的所有元素,created_by、created_at 和 last_changed_by 除外。我们的服务用例不需要这些元素。但是,存储 eTag 需要 last_changed_at 元素,但场景中不需要其他管理元素。差旅信息的其他元素用于处理差旅数据。
记住
需要此 eTag 才能进行乐观并发检查。在差旅业务对象中,所有节点都使用自己的主 eTag。
可通过服务框架完成的自动映射,为投影的所有元素指定别名。
差旅映射视图使用在投影视图中定义的关联子集。文本配置需要 _Agency、_Customer 和 _OverallStatus。这些关联只能在投影视图中采用。另一方面,由于投影层中的目标实体更改,必须将构成重定向到子实体预订。映射视图中不需要关联 _Currency。它仅在基础业务对象数据模型中定义,以表示完整的数据模型结构。
备注
在激活处理人的差旅预测根视图之前,需要在预订预测子视图中创建预订映射视图,并将成分重定向到父项。成分必须始终从父项到子项一致,反之亦然。
UI 细节
UI 标头信息在实体注释中提供,以标记列表报告页面。
差旅处理器投影视图是业务对象投影的根节点。打开差旅处理应用时,差旅条目显示为列表项目,并导航到其对象页面和相应预订。在此对象页面中,可以导航到预订补充。在后端中,导航按成分实施。对于要启用导航的 UI,需要在差旅映射视图中定义 UI 构面,以便在对象页面上为差旅实体的标识参考以及预订实体的行项目参考。
此外,列表项目的元素和对象页面的标识参考需要在投影视图中使用相应的 UI 注释进行注释,以定义位置、重要性和可能的标签。
有关 UI 导航和元素定位的详细信息,请参阅设计 Fiori 元素应用或 CDS 注释的用户界面。
投影实体中使用的注释将传播到投影视图。无需使用与投影实体中相同的注释重新注释元素。但是,如果注释绘制对特定元素的引用,并且该特定元素的名称在投影视图中更改为别名,则传播的注释将保留投影实体中给定的引用。然后,两个元素之间的语义关系可能会丢失。在这种情况下,您必须重用相同的注释,并在注释的元素引用中使用别名。
在我们的示例场景中,CurrencyCode 和 BookingFee 或 TotalPrice 之间的语义关系就是这种情况。在投影视图中,您无需使用 @Semantics.currencyCode: true 注释 CurrencyCode ,因为此注释继承自投影实体。注释 @Semantics.amount.currencyCode: 'currency_code' 也会继承,但投影视图中的字段名称已更改。因此,您需要使用新别名重新注释元素:@Semantics.amount.currencyCode: 'CurrencyCode'。
提示
检查活动 AnnotationsView 以找出当前 CDS 视图处于活动状态的注释以及活动注释的值。
为了能够搜索特定数据集,差旅预测视图必须已启用搜索,并且必须至少分配一个元素作为缺省搜索元素。此外,您可以定义选择字段以为特定元素提供过滤器栏。有关搜索启用的详细信息,请参阅在 SAP Fiori 应用中启用文本和模糊搜索。有关选择字段的详细信息,请参阅清单报表抬头
要访问相应的文本或描述,必须在相关文本提供者视图中建立元素 AgencyID、CustomerID、OverallStatus 及其文本元素之间的关系。文本提供者视图的文本元素必须集成在映射视图中。文本提供者视图必须与投影视图相关联,文本提供者视图中的文本元素必须使用 @Semantics.text: true 进行注释。注释 @ObjectModel.text.element: 在注释元素及其以相应登录语言显示值的描述性文本元素之间建立链接。要指示仅显示文本元素,注释 textArrangement: #TEXT_ONLY 用于元素 OverallStatus。使用注释 OverallStatusText 隐藏非规范化字段 @UI.hidden: true 以防止显示冗余信息。有关文本配置的详细信息,请参阅使用文本元素。
特别是对于数据处理角色,值帮助对于查找元素 AgencyID、CurrencyCode、CustomerID 和 OverallStatus 的必要值尤为重要。值帮助使用注释 @Consumption.valueHelpDefinititon 定义。无需关联值帮助提供者视图即可获取值帮助,因为实体和元素在注释中引用。有关详细信息,请参阅添加值帮助。
在映射视图中,还必须定义已在行为定义中定义的操作执行按钮的位置。在清单报表页面上,定义了操作 copyTravel 的按钮位置。有关操作的详细信息,请参阅开发操作。
预订映射视图 /DMO/C_BOOKING_PROCESSOR_M
对于服务特定映射,必须定义元素以及所有 UI 细节。
数据模型定义为 UI 服务公开的元素。此外,在数据定义中,必须定义所有 UI 规范。
可通过在处理者的 CDS 预订映射视图中实施相应功能来实现以下 UI。
预览:处理器的 UI 应用程序


展开以下代码示例以查看预订映射视图 /DMO/C_Booking_Processor_M 的源代码。
示例代码
@EndUserText.label: 'Booking projection view'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@UI: {
headerInfo: { typeName: 'Booking',
typeNamePlural: 'Bookings',
title: { type: #STANDARD, value: 'BookingID' } } }
@Search.searchable: true
define view entity /DMO/C_Booking_Processor_M
as projection on /DMO/I_Booking_M
{
@UI.facet: [ { id: 'Booking',
purpose: #STANDARD,
type: #IDENTIFICATION_REFERENCE,
label: 'Booking',
position: 10 },
{ id: 'BookingSupplement',
purpose: #STANDARD,
type: #LINEITEM_REFERENCE,
label: 'Booking Supplement',
position: 20,
targetElement: '_BookSupplement'} ]
@Search.defaultSearchElement: true
key travel_id as TravelID,
@UI: { lineItem: [ { position: 20, importance: #HIGH } ],
identification: [ { position: 20 } ] }
@Search.defaultSearchElement: true
key booking_id as BookingID,
@UI: { lineItem: [ { position: 30, importance: #HIGH } ],
identification: [ { position: 30 } ] }
booking_date as BookingDate,
@UI: { lineItem: [ { position: 40, importance: #HIGH } ],
identification: [ { position: 40 } ] }
@Consumption.valueHelpDefinition: [{entity: {name: '/DMO/I_Customer', element: 'CustomerID' }}]
@ObjectModel.text.element: ['CustomerName']
@Search.defaultSearchElement: true
customer_id as CustomerID,
_Customer.LastName as CustomerName,
@UI: { lineItem: [ { position: 50, importance: #HIGH } ],
identification: [ { position: 50 } ] }
@Consumption.valueHelpDefinition: [{entity: {name: '/DMO/I_Carrier', element: 'AirlineID' }}]
@ObjectModel.text.element: ['CarrierName']
carrier_id as CarrierID,
_Carrier.Name as CarrierName,
@UI: { lineItem: [ { position: 60, importance: #HIGH } ],
identification: [ { position: 60 } ] }
@Consumption.valueHelpDefinition: [ {entity: {name: '/DMO/I_Flight', element: 'ConnectionID'},
additionalBinding: [ { localElement: 'FlightDate', element: 'FlightDate'},
{ localElement: 'CarrierID', element: 'AirlineID'},
{ localElement: 'FlightPrice', element: 'Price'},
{ localElement: 'CurrencyCode', element: 'CurrencyCode' } ] } ]
connection_id as ConnectionID,
@UI: { lineItem: [ { position: 70, importance: #HIGH } ],
identification: [ { position: 70 } ] }
@Consumption.valueHelpDefinition: [ {entity: {name: '/DMO/I_Flight', element: 'FlightDate' },
additionalBinding: [ { localElement: 'ConnectionID', element: 'ConnectionID'},
{ localElement: 'CarrierID', element: 'AirlineID'},
{ localElement: 'FlightPrice', element: 'Price' },
{ localElement: 'CurrencyCode', element: 'CurrencyCode' }]}]
flight_date as FlightDate,
@UI: { lineItem: [ { position: 80, importance: #HIGH } ],
identification: [ { position: 80 } ] }
@Semantics.amount.currencyCode: 'CurrencyCode'
flight_price as FlightPrice,
@Consumption.valueHelpDefinition: [{entity: {name: 'I_Currency', element: 'Currency' }}]
currency_code as CurrencyCode,
@UI: { lineItem: [ { position: 90, importance: #HIGH, label: 'Status' } ],
identification: [ { position: 90, label: 'Status' } ],
textArrangement: #TEXT_ONLY }
@Consumption.valueHelpDefinition: [{ entity: { name: '/DMO/I_Booking_Status_VH', element: 'BookingStatus' }}]
@ObjectModel.text.element: ['BookingStatusText']
booking_status as BookingStatus,
@UI.hidden: true
_BookingStatus._Text.Text as BookingStatusText : localized,
@UI.hidden: true
last_changed_at as LastChangedAt,
/* Associations */
_Travel : redirected to parent /DMO/C_Travel_Processor_M,
_BookSupplement : redirected to composition child /DMO/C_BookSuppl_Processor_M,
_Customer,
_Carrier,
_BookingStatus
}
解释
对于预订映射视图的数据模型,可以采用预计视图的所有元素。
可通过服务框架完成的自动映射,为投影的所有元素指定别名。
预订映射视图使用预计视图中定义的关联子集。文本配置需要关联 _Customer、_Carrier 和 _BookingStatus。这些关联只能在投影视图中采用。另一方面,由于映射层中的目标实体更改,必须重定向父实体 _Travel 和子实体 _BookSupplement 的组合。映射视图中不需要关联 _Connection。在基础业务对象数据模型中定义用于完成业务对象数据模型结构。
备注
在激活处理人的预订映射视图之前,您需要创建预订补充投影视图,并将预订补充映射子视图中的成分重定向到父项。成分必须始终从父项到子项一致,反之亦然。
UI 细节
与差旅投影视图一样,预订投影视图的 UI 抬头信息在实体注释中提供。
为了使 UI 能够从预订导航到 BookingSupplement 实体,您需要定义 UI 构面。登记实体必须定义为标识参考,BookingSupplement 定义为行项目参考。
此外,需要在预订投影视图中使用相应的 UI 注释对列表项目的元素和第二个导航的标识参考进行注释,以定义位置、重要性和可能的标签。
有关 UI 导航和元素定位的详细信息,请参阅设计 Fiori 元素应用或 CDS 注释的用户界面。
与差旅投影视图一样,由于注释值因别名而更改,因此需要在投影视图中重复注释 @Semantics.amount.currencyCode: 'CurrencyCode'。
为了能够搜索特定数据集,必须启用预订映射视图,并且必须至少分配一个元素作为缺省搜索元素。有关搜索启用的详细信息,请参阅在 SAP Fiori 应用中启用文本和模糊搜索。
要访问相应的文本或描述,必须在相关文本提供者视图中建立元素 CarrierID、BookingStatus 及其文本元素之间的关系。因此,您需要与文本提供者视图的关联。文本提供者视图的文本元素必须集成在映射视图中。文本提供者视图必须与投影视图相关联,文本提供者视图中的文本元素必须使用 @Semantics.text: true 进行注释。注释 @ObjectModel.text.element: 在注释元素及其以相应登录语言显示值的描述性文本元素之间建立链接。要指示仅显示文本元素,注释 textArrangement: #TEXT_ONLY 用于元素 BookingStatus。使用注释 BookingStatusText 隐藏非规范化字段 @UI.hidden: true 以防止显示冗余信息。有关文本配置的详细信息,请参阅使用文本元素。
特别是对于数据处理角色,值帮助对于查找元素 CustomerID、CarrierID、ConnectionID 的必要值以及查找 FlightDate、CurrencyCode 和 BookingStatus 的足够值非常重要。值帮助使用注释 @Consumption.valueHelpDefinititon 定义。ConnectionID 和 FlightDate 的值帮助使用附加绑定,以便仅显示与给定本地元素中的条目匹配的值。无需关联值帮助提供者视图即可获取值帮助,因为实体和元素在注释中引用。但是,需要将其包含在服务定义中。有关详细信息,请参阅添加值帮助。
管理字段 last_changed_at 仅用于并发处理,不必显示在 UI 上。注释 @UI.hidden = true 用于此目的。
预订补充映射视图 /DMO/C_BOOKSUPPL_PROCESSOR_M
对于服务特定映射,必须定义元素以及所有 UI 细节。
数据模型定义为 UI 服务公开的元素。此外,在数据定义中,必须定义所有 UI 规范。
可通过为处理人实施 CDS 预订补充映射视图中的相应功能来实现以下 UI。
预览:处理器的 UI 应用程序

展开以下代码示例以查看预订补充映射视图 /DMO/C_BookSuppl_Processor_M 的源代码。
示例代码
@EndUserText.label: 'Booking supplement projection view'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@UI: { headerInfo: { typeName: 'Booking Supplement',
typeNamePlural: 'Booking Supplements',
title: { type: #STANDARD,
label: 'Booking Supplement',
value: 'BookingSupplementID' } } }
@Search.searchable: true
define view entity /DMO/C_BookSuppl_Processor_M as projection on /DMO/I_BookSuppl_M
{
@UI.facet: [ { id: 'BookingSupplement',
purpose: #STANDARD,
type: #IDENTIFICATION_REFERENCE,
label: 'Booking Supplement',
position: 10 } ]
@Search.defaultSearchElement: true
key travel_id as TravelID,
@Search.defaultSearchElement: true
key booking_id as BookingID,
@UI: { lineItem: [ { position: 10, importance: #HIGH } ],
identification: [ { position: 10 } ] }
key booking_supplement_id as BookingSupplementID,
@UI: { lineItem: [ { position: 20, importance: #HIGH } ],
identification: [ { position: 20 } ] }
@Consumption.valueHelpDefinition: [ {entity: {name: '/DMO/I_SUPPLEMENT', element: 'SupplementID' } ,
additionalBinding: [ { localElement: 'Price', element: 'Price' },
{ localElement: 'CurrencyCode', element: 'CurrencyCode' }] }]
@ObjectModel.text.element: ['SupplementDescription']
supplement_id as SupplementID,
_SupplementText.Description as SupplementDescription: localized,
@UI: { lineItem: [ { position: 30, importance: #HIGH } ],
identification: [ { position: 30 } ] }
@Semantics.amount.currencyCode: 'CurrencyCode'
price as Price,
@Consumption.valueHelpDefinition: [{entity: {name: 'I_Currency', element: 'Currency' }}]
currency_code as CurrencyCode,
@UI.hidden: true
last_changed_at as LastChangedAt,
/* Associations */
_Travel : redirected to /DMO/C_Travel_Processor_M,
_Booking : redirected to parent /DMO/C_Booking_Processor_M,
_SupplementText
}
对于预订补充映射视图的数据模型,可以采用预计视图的所有元素。
可通过服务框架完成的自动映射,为投影的所有元素指定别名。
预订补充 投影 视图使用在投影视图中定义的关联子集。文本配置需要关联 _SupplementText。此关联只能在投影视图中采用。另一方面,必须重定向父实体 _Booking 和根实体 _Travel 的组合作为投影层中的目标实体更改。在服务上下文的映射视图中不需要关联 _Supplement。在基础业务对象数据模型中定义用于完成业务对象数据模型结构。
备注
现在,所有成分均已重定向,您可以为处理人激活三个投影视图。
UI 细节
与在差旅和预订投影视图中一样,预订补充投影视图的 UI 标题信息在实体注释中提供。
限制
Fiori 元素预览不支持导航到多个子实体。因此,通过实体集
Travel和关联to_Booking访问预览时,无法导航到 BookingSupplement 实体的对象页面。这意味着,如果您仅使用预览测试应用程序,则某些 UI 注释不相关。例如,通过根节点identification进行测试时,引用Travel的 UI 注释无法在预览中显示。但是,如果要开发实际应用程序或使用 Web IDE 测试服务,则可以配置应用程序以启用到任意数量的子实体的导航。因此,有关
identification的 UI 注释包含在以下描述中。您可以通过实体集
Booking和关联to_BookSupplement访问 Fiori 元素预览来模仿 Web IDE 的行为以进行第二级导航。
要在其对象页面上显示预订补充实体的条目,必须定义 #IDENTIFICATION_REFERENCE 的 UI 构面。
此外,列表项目(显示在预订实体的对象页面上)和标识的元素必须在预订补充投影视图中使用相应的 UI 注释进行注释,以定义位置、重要性和可能的标签。
有关 UI 导航和元素定位的详细信息,请参阅设计 Fiori 元素应用或 CDS 注释的用户界面。
与差旅投影视图一样,由于注释值因别名而更改,因此需要在投影视图中重复注释 @Semantics.amount.currencyCode: 'CurrencyCode'。
为了能够搜索特定数据集,必须启用搜索预订补充映射视图,并且必须至少分配一个元素作为缺省搜索元素。有关搜索启用的详细信息,请参阅在 SAP Fiori 应用中启用文本和模糊搜索。
要访问标识元素的相应文本或描述,必须在相关文本提供者视图中建立元素 SupplementID 及其文本元素之间的关系。因此,您需要与文本提供者视图的关联。文本提供者视图的文本元素必须集成在映射视图中。文本提供者视图必须与投影视图相关联,文本提供者视图中的文本元素必须使用 @Semantics.text: true 进行注释。有关文本配置的详细信息,请参阅使用文本元素。
特别是对于数据处理角色,值帮助对于查找标识元素 SupplementID 以及 CurrencyCode 的必要值非常重要。值帮助使用注释 @Consumption.valueHelpDefinititon 定义。SupplementID 的值帮助使用附加绑定,以便仅显示与字段 CurrencyCode 字段中的条目匹配的值。无需关联值帮助提供者视图即可获取值帮助,因为实体和元素在注释中引用。有关详细信息,请参阅添加值帮助。
管理字段 last_changed_at 仅用于并发处理,不必显示在 UI 上。注释 @UI.hidden = true 用于此目的。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 处理器业务对象预测的映射视图 · 定义处理器映射视图的数据模型 →