将另一层添加到事务数据模型
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 开发非托管事务应用 › 将另一层添加到事务数据模型
在此部分中,您将获得有关向航班演示场景添加更多层时如何继续操作的简要概览。具体来说,预订补充实体现在将添加到差旅业务对象的上一双层层。
事务数据的实体
如下图所示,在我们的场景中用于管理事务数据的 3 层实体层次结构由以下可编辑实体组成,每个级别具有 1: n 基数:
差旅
预订
预订补充
即,每个差旅实例都有 0..n 个预订,每个预订都有 0..n 预订补充。
主数据的附加实体
要使用业务数据填充预订补充实例,还需要通过以下实体扩展主数据的数据模型:
补充
补充文本

备注
通过到目前为止的知识,您可以轻松重现此扩展的具体步骤。因此,在本主题中,我们将仅简要概述实施步骤并参考完整实施,因为它在演示 ABAP 包
/DMO/FLIGHT_UNMANAGED中可用。
1. 添加新业务对象节点
添加 CDS 实体以扩展数据模型
实体 |
描述 |
可编辑 |
|---|---|---|
|
此实体用于将附加产品添加到差旅预订。登记补充数据存储在数据库表 |
是 |
|
|
否 |
|
此实体主要为目标实体 |
NO |
BookingSupplement 实体是差旅业务对象构成层次结构的一部分。此构成关系需要与其组成父实体关联。此关系由关键字 ASSOCIATION TO PARENT 表示。使用此语法,将 CDS 实体 BookingSupplement 定义为差旅业务对象结构构成层次结构中的子节点。对于 etag 和锁主数据处理,实体 包含与根实体的关联 _Travel。要访问其他实体中的主数据,请在 CDS 源代码中定义附加关联 _Product 和 _SupplementText。相关视图主要用作检索文本信息的文本视图,并用作特定产品字段的值帮助提供者。
展开以下代码示例以查看 CDS 视图 /DMO/I_BookingSupplement_U 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Booking Supplement view - CDS data model'
define view entity /DMO/I_BookingSupplement_U
as select from /dmo/book_suppl as BookingSupplement
association to parent /DMO/I_Booking_U as _Booking on $projection.TravelID = _Booking.TravelID
and $projection.BookingID = _Booking.BookingID
association [1..1] to /DMO/I_Travel_U as _Travel on $projection.TravelID = _Travel.TravelID
association [1..1] to /DMO/I_Supplement as _Product on $projection.SupplementID = _Product.SupplementID
association [1..*] to /DMO/I_SupplementText as _SupplementText on $projection.SupplementID = _SupplementText.SupplementID
{
key BookingSupplement.travel_id as TravelID,
key BookingSupplement.booking_id as BookingID,
key BookingSupplement.booking_supplement_id as BookingSupplementID,
BookingSupplement.supplement_id as SupplementID,
@Semantics.amount.currencyCode: 'CurrencyCode'
BookingSupplement.price as Price,
BookingSupplement.currency_code as CurrencyCode,
// _Booking.LastChangedAt as LastChangedAt,
/* Associations */
_Booking,
_Travel,
_Product,
_SupplementText
}
由于 BookingSupplement 实体是业务对象构成层次结构的一部分,因此将其投影到投影视图中。在投影视图中,通过 CDS 注释定义文本关系、搜索和值帮助。此外,必须分别重定向到父项和根关联。
展开以下代码示例以查看源代码 CDS 映射视图 /DMO/C_BookingSupplement_U。
示例代码
@EndUserText.label: 'Booking Supplement Projection View'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.allowExtensions: true
@Search.searchable: true
define view entity /DMO/C_BookingSupplement_U
as projection on /DMO/I_BookingSupplement_U
{ ///DMO/I_BookingSupplement_U
@Search.defaultSearchElement: true
key TravelID,
@Search.defaultSearchElement: true
key BookingID,
key BookingSupplementID,
@Consumption.valueHelpDefinition: [ {entity: { name: '/DMO/I_SUPPLEMENT',
element: 'SupplementID' },
additionalBinding: [ { localElement: 'Price', element: 'Price'},
{ localElement: 'CurrencyCode', element: 'CurrencyCode' } ] } ]
@ObjectModel.text.element: ['SupplementText']
SupplementID,
_SupplementText.Description as SupplementText : localized,
Price,
@Consumption.valueHelpDefinition: [ { entity: { name: 'I_Currency',
element: 'Currency' } } ]
CurrencyCode,
// LastChangedAt,
/* Associations */
///DMO/I_BookingSupplement_U
_Booking : redirected to parent /DMO/C_Booking_U,
_Travel : redirected to /DMO/C_Travel_U ,
_Product,
_SupplementText
}
BookingSupplement 实体在 UI 中也具有 表示。因此,它必须配备用户界面注释,这些注释会像与其他业务对象实体一样外包给元数据扩展。
展开以下代码示例以查看**元数据扩展 /DMO/C_BookingSupplement_U 的源代码。
示例代码
@Metadata.layer: #CORE
@UI: { headerInfo: { typeName: 'Booking Supplement',
typeNamePlural: 'Booking Supplements',
title: { type: #STANDARD, label: 'Booking Supplement', value: 'BookingSupplementID' } } }
annotate view /DMO/C_BookingSupplement_U with
{
@UI.facet: [ { id: 'BookingSupplement',
purpose: #STANDARD,
type: #IDENTIFICATION_REFERENCE,
label: 'Booking Supplement',
position: 10 } ,
{ id: 'PriceHeader',
type: #DATAPOINT_REFERENCE,
purpose: #HEADER,
targetQualifier: 'Price',
label: 'Price',
position: 20 } ]
@UI: { lineItem: [ { position: 10, importance: #HIGH } ],
identification: [ { position: 10 } ] }
BookingSupplementID;
@UI: { lineItem: [ { position: 20, importance: #HIGH } ],
identification: [ { position: 20 } ] }
SupplementID;
@UI: { lineItem: [ { position: 30, importance: #HIGH } ],
identification: [ { position: 30 } ],
dataPoint: { title: 'Price' }
}
Price;
}
备注
要完成业务对象的构成层次结构,您需要将构成添加到
Booking实体/DMO/I_Booking_U中的子项以及映射视图/DMO/C_Booking_U中的重定向组合。要在 Fiori UI 上显示和更改预订补充数据,必须在预订元数据扩展
/DMO/C_Booking_U中添加相应的 UI 构面。
添加补充的 CDS 视图
以下源代码为您提供附加产品的数据定义,客户可以与航班预订一起预订。
展开以下代码示例以查看 CDS 视图 /DMO/I_Supplement 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'supplement view - cds data model'
@Search.searchable: true
define root view entity /DMO/I_Supplement
as select from /dmo/supplement as supplement
composition [0..*] of /DMO/I_SupplementText as _SupplementText
association [0..1] to I_Currency as _Currency on $projection.CurrencyCode = _Currency.Currency
association [0..1] to /DMO/I_SupplementCategory_VH as _SupplementCategory on $projection.SupplementCategory = _SupplementCategory.SupplementCategory
{
@Search.defaultSearchElement: true
key supplement.supplement_id as SupplementID,
supplement.supplement_category as SupplementCategory,
@Search.defaultSearchElement: true
@Semantics.amount.currencyCode: 'currencycode'
supplement.price as Price,
supplement.currency_code as CurrencyCode,
@Semantics.user.createdBy: true
supplement.local_created_by as LocalCreatedBy,
@Semantics.systemDateTime.createdAt: true
supplement.local_created_at as LocalCreatedAt,
@Semantics.user.localInstanceLastChangedBy: true
supplement.local_last_changed_by as LocalLastChangedBy,
//local etag field --> odata etag
@Semantics.systemDateTime.localInstanceLastChangedAt: true
supplement.local_last_changed_at as LocalLastChangedAt,
//total etag field
@Semantics.systemDateTime.lastChangedAt: true
supplement.last_changed_at as LastChangedAt,
/* associations */
@Search.defaultSearchElement: true
_SupplementText,
_SupplementCategory,
_Currency
}
添加补充的文本提供者视图
以下源代码为您提供了用作文本提供者的数据定义。它通过预订补充视图中定义的文本关联提供文本数据。
展开以下代码示例以查看 CDS 视图 /DMO/I_Supplement 的源代码。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Supplement View - CDS Data Model'
@Search.searchable: true
define view entity /DMO/I_Supplement
as select from /dmo/supplement as Supplement
association [0..*] to /DMO/I_SupplementText as _SupplText on $projection.SupplementID = _SupplText.SupplementID
association [0..1] to I_Currency as _Currency on $projection.CurrencyCode = _Currency.Currency
{
@ObjectModel.text.association: '_SupplText'
key Supplement.supplement_id as SupplementID,
@Semantics.amount.currencyCode: 'CurrencyCode'
Supplement.price as Price,
Supplement.currency_code as CurrencyCode,
/* Associations */
@Search.defaultSearchElement: true
_SupplText,
_Currency
}
2.扩展 BookingSupplement 实体的行为定义
在我们的场景中,添加 _BookSupplement 关联时会考虑为特定差旅和预订实例创建新的预订补充实体实例。关键字 {create;} 声明此关联已启用创建,确切意味着相关预订补充的实例可由单个预订实例创建。
差旅业务对象的子节点是指由 /DMO/I_BookingSupplement_U 的子实体表示的预订补充的相应数据模型。预订补充子节点的事务行为由标准操作 create、update 和 delete 确定。此外,由于我们使用的 CDS 视图字段名称与数据库表中的不同,因此我们需要从 CDS 名称到数据库字段名称的 mapping 规范。
展开以下代码示例以查看**扩展行为定义的源代码 /DMO/I_TRAVEL_U。
示例代码
...
define behavior for /DMO/I_Travel_U alias travel
{...
}
define behavior for /DMO/I_Booking_U alias booking
{
...
association _BookSupplement { create; }
}
define behavior for /DMO/I_BOOKINGSUPPLEMENT_U alias bookingsupplement
implementation in class /DMO/BP_BOOKINGSUPPLEMENT_U unique
etag dependent by _Travel
lock dependent by _Travel
{
field (read only) TravelID, BookingID, BookingSupplementID;
field (mandatory) SupplementID, Price;
create;
update;
delete;
association _Travel;
mapping for /dmo/book_suppl control /dmo/s_booking_supplement_intx
{
BookingID = booking_id;
BookingSupplementID = booking_supplement_id;
CurrencyCode = currency_code;
Price = price;
SupplementID = supplement_id;
TravelID = travel_id;
}
}
3.创建并实施用于预订补充的行为池
为 BookingSupplement 实体创建行为池
BookingSupplement 子实体的行为池
CLASS /dmo/bp_bookingsupplement_u DEFINITION
PUBLIC
ABSTRACT
FINAL
FOR BEHAVIOR OF /dmo/i_travel_u.
PUBLIC SECTION.
PROTECTED SECTION.
PRIVATE SECTION.
ENDCLASS.
CLASS /dmo/bp_bookingsupplement_u IMPLEMENTATION.
ENDCLASS.
实施 UPDATE、DELETE、READ 和 READ BY ASSOCIATION 的处理程序
实施用于更新和删除的处理器方法时,您将找到相同的基本结构:
要更新或删除的预订补充实例的循环。
调用业务逻辑功能模块。
失败时用于处理消息的错误处理。
在 lhc_supplement 中更新预订补充数据
CLASS lhc_supplement DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
TYPES:
tt_bookingsupplement_update TYPE TABLE FOR UPDATE /dmo/i_bookingsupplement_u.
update FOR MODIFY
IMPORTING entities FOR UPDATE bookingsupplement,
...
ENDCLASS.
CLASS lhc_supplement IMPLEMENTATION.
METHOD update.
...
ENDMETHOD.
ENDCLASS.
在 lhc_supplement 中删除预订补充
CLASS lhc_supplement DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
delete FOR MODIFY
IMPORTING entities FOR DELETE bookingsupplement,
ENDCLASS.
CLASS lhc_supplement IMPLEMENTATION.
...
METHOD delete.
...
ENDMETHOD.
ENDCLASS.
在 lhc_supplement 中读取预订补充
CLASS lhc_supplement DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS:
read FOR READ
IMPORTING keys FOR READ bookingsupplement
RESULT result,
ENDCLASS.
CLASS lhc_supplement IMPLEMENTATION.
...
METHOD read.
...
ENDMETHOD.
ENDCLASS.
在 lhc_supplement 中通过协会阅读旅行
CLASS lhc_supplement DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
...
METHODS:
rba_travel FOR READ
IMPORTING keys_rba FOR READ bookingsupplement\_travel FULL result_requested
RESULT result LINK association_links.
ENDCLASS.
CLASS lhc_supplement IMPLEMENTATION.
...
METHOD rba_travel.
...
ENDMETHOD.
ENDCLASS.
实施相关预订补充的 CREATE 处理程序
在我们的演示场景中,我们假设无法单独创建新的预订补充,而只能与属于单个差旅实例的给定预订结合使用。
要识别相关预订补充,将根据行为定义中指定的别名使用父实体和子实体的别名。该关联以预订行为池 /DMO/BP_BOOKING_U 实施方法 cba_supplement 的签名表示,格式为:… FOR CREATE parent\_child_entity.
在 cba_supplement 方法中创建预订补充
CLASS lhc_booking DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
cba_booksupplement FOR MODIFY
IMPORTING entities FOR CREATE booking\_booksupplement,
...
ENDCLASS.
CLASS lhc_booking IMPLEMENTATION.
...
METHOD cba_booksupplement
...
ENDMETHOD.
ENDCLASS.


实施相关预订补充的 READ
要完成业务对象,必须为相关预订实施 READ 操作。READ by association 在预订行为的行为定义中由 CREATE by association 定义隐式定义:
define behavior for /DMO/I_Booking_U alias booking
{
...
association _BookSupplement { create; }
}
通过关联读取预订补充方法的声明和实施在预订 /DMO/BP_BOOKING_U 的处理器类中完成,方法与为相关预订实施 READ 操作相同:
按差旅 ID 对导入的预订密钥进行分组
调用功能模块
/DMO/FLIGHT_TRAVEL_READ筛选请求的登记代码
使用相应的源键值和目标键值填充链接表。
如果设置了完整参数,则填充结果参数
处理错误
在 read_supplement_ba 方法中读取预订补充
CLASS lhc_booking DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS:
rba_booksupplement FOR READ
IMPORTING keys_rba FOR READ booking\_booksupplement FULL result_requested
RESULT result LINK association_links.
...
ENDCLASS.
CLASS lhc_booking IMPLEMENTATION.
...
METHOD rba_booksupplement
...
ENDMETHOD.
ENDCLASS.
可以使用 EML 测试 READ by association。
4.预测预订补充实体的行为
如投影行为中所述,必须在映射行为定义 /DMO/C_Travel_U 中投影行程业务对象的行为。
与登记补充实体相关的行为是:
行为节点
/DMO/C_BookingSupplement_U上的标准操作update和delete,以及行为节点上预订补充的按关联创建操作
/DMO/C_Booking_U。
展开以下代码示例以查看**投影行为定义的源代码 /DMO/C_Travel_U。
示例代码
...
define behavior for /DMO/C_Travel_U alias travel
use etag
{
use create;
use update;
use delete;
use action set_status_booked;
use association _BOOKING { create; }
}
define behavior for /DMO/C_Booking_U alias booking
use etag
{
use update;
use delete;
use association _BOOKSUPPLEMENT { create; }
}
define behavior for /DMO/C_BookingSupplement_U alias bookingsupplement
use etag
{
use update;
use delete;
}
5.在服务定义中公开新实体
根据以下列表,将通过 UI 服务公开以下 CDS 实体:
清单 12:已在服务定义中添加实体
@EndUserText.label: 'Service definition for managing travels'
define service /DMO/TRAVEL_U {
...
expose /DMO/C_BookingSupplement_U as BookingSupplement;
expose /DMO/I_Supplement as Supplement;
expose /DMO/I_SupplementText as SupplementText;
...
}
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 创建服务绑定 · 使用独占草稿功能开发事务应用 →