创建持久数据库表

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 数据模型和业务对象结构 › 创建持久数据库表

对于具有草稿的托管场景,为与差旅、预订和预订补充的交易数据结构匹配的业务对象数据模型创建新的数据库表。

上下文和过程

在没有现有历史代码的场景中,第一步是创建存储数据的持久数据库表。

通过使用创建向导在 ADT 中创建数据库表来创建这些表。

备注

ABAP 航班参考场景中的草稿场景使用后缀 _D。对于持久数据库表,我们使用前缀 A_ 指示活动持久性。有关详细信息,请参阅 开发对象的命名规则 。

为具有使用 UUID 键值布局的草稿的被管理业务对象创建数据库表时,需要注意以下事项:

  • RAP 管理的运行时引擎需要管理数据字段来内部处理业务对象实体。特别是,表示上次更改实例的时间戳的字段对每个实体上的 ETag 主数据处理很重要。RAP 框架提供重用数据元素以定义数据库中的管理字段,请参阅 RAP 重用数据元素。如果本地实例上的管理字段在 CDS 中使用注释 @Semantics.systemDateTime.localInstanceLastChangedAt: true 进行注释,则会由 RAP 管理的运行时引擎自动填充。有关更多信息,请参阅乐观并发控制。

  • 在 UUID 场景中,每个实体都需要一个 UUID 键值字段。此外,子实体必须具有其父项 UUID 的字段。否则,无法为构成关系定义关联。此外,任何与锁主实体没有父子关系的子实体都必须具有具有锁主数据的 UUID 的字段。否则,无法定义与锁主实体的关联,这对于锁定和 ETag 处理很重要。

  • 除 UUID 键值外,每个数据库表还具有语义标识字段。这些字段不是技术键值,但用于在语义上区分业务对象中的实体实例。

表 /DMO/A_TRAVEL_D:用于管理差旅数据的持久表

此表定义常规差旅数据、描述差旅基本信息的数据,例如差旅标识、客户和旅行社标识以及日期。由于此场景基于 UUID 键值布局,因此表还需要具有 UUID 数据类型的字段。此外,标准管理数据的字段(如相应用户或创建时间)将添加到表中。在被管理业务对象中,如果将相应的 @Semantics 注释添加到 CDS 视图实体中的字段,则可以由 RAP 管理的运行时框架自动填充这些字段。管理字段,特别是确定何时更改实例数据的字段,对于并发控制很重要。

展开以下代码示例以查看 /DMO/A_TRAVEL_D 的源代码。

示例代码

@EndUserText.label : 'Active Travel Persistence for Draft Reference Scenario'
@AbapCatalog.enhancement.category : #NOT_EXTENSIBLE
@AbapCatalog.tableCategory : #TRANSPARENT
@AbapCatalog.deliveryClass : #A
@AbapCatalog.dataMaintenance : #RESTRICTED
define table /DMO/A_TRAVEL_D{
  key client            : abap.clnt not null;
  key travel_uuid       : sysuuid_x16 not null;
  travel_id             : /dmo/travel_id not null;
  agency_id             : /dmo/agency_id;
  customer_id           : /dmo/customer_id;
  begin_date            : /dmo/begin_date;
  end_date              : /dmo/end_date;
  @Semantics.amount.currencyCode : '/dmo/a_travel_d.currency_code'
  booking_fee           : /dmo/booking_fee;
  @Semantics.amount.currencyCode : '/dmo/a_travel_d.currency_code'
  total_price           : /dmo/total_price;
  currency_code         : /dmo/currency_code;
  description           : /dmo/description;
  overall_status        : /dmo/overall_status;
  @AbapCatalog.anonymizedWhenDelivered : true
  local_created_by      : abp_creation_user;
  local_created_at      : abp_creation_tstmpl;
  @AbapCatalog.anonymizedWhenDelivered : true
  local_last_changed_by : abp_locinst_lastchange_user;
  local_last_changed_at : abp_locinst_lastchange_tstmpl;
  last_changed_at       : abp_lastchange_tstmpl;

}

表 /DMO/A_BOOKING_D:用于管理预订数据的持久表

此表定义特定差旅实例的预订数据。其中包含常规预订数据,例如预订 ID、预订日期和一般航班数据。要唯一标识预订实例,表必须包含预订的 UUID 字段。在 UUID 场景中,父 UUID 充当数据库中子实体的外键字段。对于 ETag 主处理,预订数据库表会收到一个字段,用于存储更新实例时的时间戳。

展开以下代码示例以查看 /DMO/A_BOOKING_D 的源代码。

示例代码

@EndUserText.label : 'Active Booking Persistence for Draft Reference Scenario'
@AbapCatalog.enhancement.category : #NOT_EXTENSIBLE
@AbapCatalog.tableCategory : #TRANSPARENT
@AbapCatalog.deliveryClass : #A
@AbapCatalog.dataMaintenance : #RESTRICTED
define table /DMO/A_BOOKING_D{
  key client            : abap.clnt not null;
  key booking_uuid      : sysuuid_x16 not null;
  parent_uuid           : sysuuid_x16;
  booking_id            : /dmo/booking_id not null;
  booking_date          : /dmo/booking_date;
  customer_id           : /dmo/customer_id;
  carrier_id            : /dmo/carrier_id;
  connection_id         : /dmo/connection_id;
  flight_date           : /dmo/flight_date;
  @Semantics.amount.currencyCode : '/dmo/a_booking_d.currency_code'
  flight_price          : /dmo/flight_price;
  currency_code         : /dmo/currency_code;
  booking_status        : /dmo/booking_status;
  local_last_changed_at : abp_locinst_lastchange_tstmpl;

}

表 /DMO/A_BKSUPPL_D: 管理登记补充数据的持久表

此表定义特定登记实例的补充。其中包含常规预订补充数据,例如预订补充标识和价格信息。要唯一标识预订补充实例,表必须包含预订补充的 UUID 字段。在 UUID 场景中,父 UUID 和锁定主数据 UUID(在本例中为根 UUID)充当数据库中的外键字段。对于 ETag 主处理,预订补充数据库表会收到一个字段,用于存储更新实例的时戳。

展开以下代码示例以查看 /DMO/A_BKSUPPL_D 的源代码。

示例代码

@EndUserText.label : 'Active BookingSupplement Persistence for Draft Ref. Scenario'
@AbapCatalog.enhancement.category : #NOT_EXTENSIBLE
@AbapCatalog.tableCategory : #TRANSPARENT
@AbapCatalog.deliveryClass : #A
@AbapCatalog.dataMaintenance : #RESTRICTED
define table /DMO/A_BKSUPPL_D{
  key client            : abap.clnt not null;
  key booksuppl_uuid    : sysuuid_x16 not null;
  root_uuid             : sysuuid_x16;
  parent_uuid           : sysuuid_x16;
  booking_supplement_id : /dmo/booking_supplement_id not null;
  supplement_id         : /dmo/supplement_id;
  @Semantics.amount.currencyCode : '/dmo/a_bksuppl_d.currency_code'
  price                 : /dmo/supplement_price;
  currency_code         : /dmo/currency_code;
  local_last_changed_at : abp_locinst_lastchange_tstmpl;

}

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 数据模型和业务对象结构 · 创建 CDS 视图实体 →