为差旅实体实施操作
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发操作 › 为差旅实体实施操作
对于具有草稿的管理场景,定义并对差旅实体实施操作。
操作 acceptTravel 和 rejectTravel
两个操作都会更改差旅实例的状态。它们的实施方式完全相同:在行为定义中定义操作,并在 Travel 的行为实施类中实施这些操作。
定义
定义结果为 $self 的实例操作。字段 OverallStatus 设置为 read only,因此使用者只能通过操作 acceptTravel 和 rejectTravel 更改状态。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( readonly ) OverallStatus;
action acceptTravel result [1] $self;
action rejectTravel result [1] $self;
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
在本地类型的私人部分定义可用于差旅状态的常量。
示例代码
CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler. PRIVATE SECTION. CONSTANTS: BEGIN OF travel_status, open TYPE c LENGTH 1 VALUE 'O', "Open accepted TYPE c LENGTH 1 VALUE 'A', "Accepted rejected TYPE c LENGTH 1 VALUE 'X', "Rejected END OF travel_status. …. ENDCLASS.
使用修改请求更新具有给定键值的所有实例的字段
OverallStatus。提供值accpeted(接受差旅)和rejected(拒绝差旅)。操作返回
$self。这意味着,它们必须在结果参数中返回更新的实例。因此,请从缓冲区中读取更新的实例并填充内部表。将内部表传递到结果参数。
展开以下代码示例以查看 Action acceptTravel 的源代码。
示例代码
METHOD acceptTravel.
"Modify travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( OverallStatus )
WITH VALUE #( FOR key IN keys ( %tky = key-%tky
OverallStatus = travel_status-accepted ) ).
"Read changed data for action result
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
ALL FIELDS WITH
CORRESPONDING #( keys )
RESULT DATA(travels).
result = VALUE #( FOR travel IN travels ( %tky = travel-%tky
%param = travel ) ).
ENDMETHOD.
展开以下代码示例以查看 Action rejectTravel 的源代码。
示例代码
METHOD rejectTravel.
"Modify travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( OverallStatus )
WITH VALUE #( FOR key IN keys ( %tky = key-%tky
OverallStatus = travel_status-rejected ) ).
"Read changed data for action result
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
ALL FIELDS WITH
CORRESPONDING #( keys )
RESULT DATA(travels).
result = VALUE #( FOR travel IN travels ( %tky = travel-%tky
%param = travel ) ).
ENDMETHOD.
操作 deductDiscount
在行为定义中定义操作,并在 Travel 的行为实施类中实施。
deductDiscount 需要输入参数来输入折扣百分比。该值必须与操作请求一起传递。操作参数通过抽象实体建模,该实体对其参数字段使用简单类型。
在抽象实体中为参数字段创建简单类型。
创建不含枚举的 CDS 类型。
为数据类型为
abap.int1的抽象实体字段定义简单类型。
示例代码
@EndUserText.label: 'Discount Percentage'
define type /DMO/BT_DiscountPercentage: abap.int1
为操作输入参数创建抽象实体
为 CDS 抽象实体创建数据定义。
定义使用以上定义的简单类型的折扣百分比元素。
示例代码
@EndUserText.label: 'Abstract Entity for Deducting Discount'
define abstract entity /DMO/A_TRAVEL_DISCOUNT
{
discount_percent : /DMO/BT_DiscountPercentage;
}
在行为定义中定义操作,并在 Travel 的行为实施类中实施。
定义
使用操作参数 /DMO/A_TRAVEL_DISCOUNT 和结果 $self 定义实例操作。
对于 deductDiscount 操作,定义缺省值功能,该功能在 Fiori UI 上触发操作后为输入参数提供缺省值。有关如何定义和实施此缺省值功能的信息,请参阅缺省工序的输入参数。
有关缺省值函数的概念信息,请参见操作缺省设置。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
action deductDiscount parameter /DMO/A_TRAVEL_DISCOUNT result [1] $self { default function GetDefaultsFordeductDiscount ; };
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
备注
参数操作的输入参数作为导入参数中的组件
%param传递到操作方法。
通过扣除提供的折扣百分比来计算差旅实例的新总价。以下步骤将指导您完成实施。
定义内部表并传递导入参数 keys 的条目。对于参数值与百分比值的前提条件不匹配的键值,在内部表中循环:
不得为初始值。
该值必须小于 100。
必须大于或等于 0。
如果存在与前提条件不匹配的键值,则将事务键值附加到失败表并将相应消息附加到报告表。删除内部表中与前提条件不匹配的条目。
如果内部表中仍有与前提条件匹配的条目,则将具有已导入
keys的所有差旅实例读取到其他条目的内部表travels。在内部表中循环,计算新的降低预订费,并将其附加到内部表以进行更新。
执行修改请求以更新缓冲区中实例的字段
BookingFee。要填充操作结果,请读取涉及的差旅实例并相应地填充结果。
展开以下代码示例以查看 Action deductDiscount 的源代码。
示例代码
METHOD deductDiscount.
DATA travels_for_update TYPE TABLE FOR UPDATE /DMO/R_Travel_D.
DATA(keys_with_valid_discount) = keys.
LOOP AT keys_with_valid_discount ASSIGNING FIELD-SYMBOL(<key_with_valid_discount>) WHERE %param-discount_percent IS INITIAL
OR %param-discount_percent > 100
OR %param-discount_percent <= 0.
APPEND VALUE #( %tky = <key_with_valid_discount>-%tky ) TO failed-travel.
APPEND VALUE #( %tky = <key_with_valid_discount>-%tky
%msg = NEW /dmo/cm_flight_messages(
textid = /dmo/cm_flight_messages=>discount_invalid
severity = if_abap_behv_message=>severity-error )
%element-TotalPrice = if_abap_behv=>mk-on
%op-%action-deductDiscount = if_abap_behv=>mk-on
) TO reported-travel.
DELETE keys_with_valid_discount.
ENDLOOP.
CHECK keys_with_valid_discount IS NOT INITIAL.
"get total price
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( BookingFee )
WITH CORRESPONDING #( keys_with_valid_discount )
RESULT DATA(travels).
LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
DATA percentage TYPE decfloat16.
DATA(discount_percent) = keys_with_valid_discount[ KEY id %tky = <travel>-%tky ]-%param-discount_percent.
percentage = discount_percent / 100 .
DATA(reduced_fee) = <travel>-BookingFee * ( 1 - percentage ) .
APPEND VALUE #( %tky = <travel>-%tky
BookingFee = reduced_fee
) TO travels_for_update.
ENDLOOP.
"update total price with reduced price
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( BookingFee )
WITH travels_for_update.
"Read changed data for action result
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
ALL FIELDS WITH
CORRESPONDING #( travels )
RESULT DATA(travels_with_discount).
result = VALUE #( FOR travel IN travels_with_discount ( %tky = travel-%tky
%param = travel ) ).
ENDMETHOD.
操作 reCalcTotalPrice
如果执行差旅实体本身或子实体中的价格更改,则通过确定调用 reCalcTotal price 操作。然后重新计算差旅实体的总价格。
定义
在行为定义中定义内部操作,并在 Travel 的行为实施类中实施。
记住
只能从业务对象内部消费者调用内部操作。
在我们的演示场景中,每当价格字段或货币代码字段发生更改时,都会从所有三个业务对象实体的确定中调用该操作。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
internal action reCalcTotalPrice;
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
要确定差旅的总价格,必须将所有价格转换为差旅货币,然后求和。分别针对每个业务对象实体执行此操作。以下步骤将指导您完成实施。
定义内部标准表
amounts_per_currencycode以处理金额和相关货币代码。读取导入
keys到内部表travels的所有实例。删除空
CurrencyCode的实例。对于此类情况,无法计算总价格。将返回的差旅的所有预订读入内部表
bookings。返回链接表以接收每个差旅的相关预订。将退回预订的所有预订补充读入内部表
bookingsupplements。返回链接表以接收每个受影响预订的相关预订补充。在
travels处循环,然后使用差旅实例中的相应值开始填充每种货币的金额。在
booking_links处循环,其中差旅标识与相应差旅匹配,并将价格添加到表amounts_per_currencycode中的差旅价格(如果其货币代码相同)。在这种情况下,ABAP 语句COLLECT很有用,因为它使用相同的货币代码汇总金额,并在货币代码不同时附加新行。在
bookingsupplement_links循环,其中预订标识与相应预订匹配,并将价格添加到表amounts_per_currencycode中的差旅价格(如果其货币代码相同)。删除未填写
currency_code的此内容中的条目。在表
amounts_per_currencycode循环,并将具有除差旅货币代码之外的货币代码的金额转换为差旅实例的货币代码。汇总一个差旅的已转换金额。
为所有申请的差旅实例修改具有新总价的差旅实体。
展开以下代码示例以查看 Action reCalCTotalPrice 的源代码。
示例代码
METHOD reCalcTotalPrice.
TYPES: BEGIN OF ty_amount_per_currencycode,
amount TYPE /dmo/total_price,
currency_code TYPE /dmo/currency_code,
END OF ty_amount_per_currencycode.
DATA: amounts_per_currencycode TYPE STANDARD TABLE OF ty_amount_per_currencycode.
" Read all relevant travel instances.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( BookingFee CurrencyCode )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DELETE travels WHERE CurrencyCode IS INITIAL.
" Read all associated bookings and add them to the total price.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel BY \_Booking
FIELDS ( FlightPrice CurrencyCode )
WITH CORRESPONDING #( travels )
LINK DATA(booking_links)
RESULT DATA(bookings).
" Read all associated booking supplements and add them to the total price.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking BY \_BookingSupplement
FIELDS ( BookSupplPrice CurrencyCode )
WITH CORRESPONDING #( bookings )
LINK DATA(bookingsupplement_links)
RESULT DATA(bookingsupplements).
LOOP AT travels ASSIGNING FIELD-SYMBOL(<travel>).
" Set the start for the calculation by adding the booking fee.
amounts_per_currencycode = VALUE #( ( amount = <travel>-bookingfee
currency_code = <travel>-currencycode ) ).
LOOP AT booking_links INTO DATA(booking_link) USING KEY id WHERE source-%tky = <travel>-%tky.
" Short dump occurs if link table does not match read table, which must never happen
DATA(booking) = bookings[ KEY id %tky = booking_link-target-%tky ].
COLLECT VALUE ty_amount_per_currencycode( amount = booking-flightprice
currency_code = booking-currencycode ) INTO amounts_per_currencycode.
LOOP AT bookingsupplement_links INTO DATA(bookingsupplement_link) USING KEY id WHERE source-%tky = booking-%tky.
DATA(bookingsupplement) = bookingsupplements[ KEY id %tky = bookingsupplement_link-target-%tky ].
COLLECT VALUE ty_amount_per_currencycode( amount = bookingsupplement-booksupplprice
currency_code = bookingsupplement-currencycode ) INTO amounts_per_currencycode.
ENDLOOP.
ENDLOOP.
DELETE amounts_per_currencycode WHERE currency_code IS INITIAL.
CLEAR <travel>-TotalPrice.
LOOP AT amounts_per_currencycode INTO DATA(amount_per_currencycode).
" If needed do a Currency Conversion
IF amount_per_currencycode-currency_code = <travel>-CurrencyCode.
<travel>-TotalPrice += amount_per_currencycode-amount.
ELSE.
/DMO/CL_FLIGHT_AMDP=>convert_currency(
EXPORTING
iv_amount = amount_per_currencycode-amount
iv_currency_code_source = amount_per_currencycode-currency_code
iv_currency_code_target = <travel>-CurrencyCode
iv_exchange_rate_date = cl_abap_context_info=>get_system_date( )
IMPORTING
ev_amount = DATA(total_booking_price_per_curr)
).
<travel>-TotalPrice += total_booking_price_per_curr.
ENDIF.
ENDLOOP.
ENDLOOP.
" write back the modified total_price of travels
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY travel
UPDATE FIELDS ( TotalPrice )
WITH CORRESPONDING #( travels ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译