为差旅实体添加功能控制

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发功能控制 › 为差旅实体添加功能控制

对于具有草稿的管理场景,使用差旅实体的功能控制启用和禁用功能。

在行为定义中定义静态和动态功能控制,并在 Travel 的行为实施类中实施动态功能控制。

定义

定义字段、操作和工序控制。对于动态功能控制,将 (feature: instance) 添加到功能控件定义。

示例代码

define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
  association _Booking { create ( features : instance ); }

  field ( numbering : managed, readonly ) TravelUUID;
  field ( readonly ) TravelID, OverallStatus, TotalPrice, LocalCreatedAt, LocalCreatedBy, LocalLastChangedAt, LocalLastChangedBy, LastChangedAt;
  field ( mandatory ) CustomerID, AgencyID, BeginDate, EndDate, CurrencyCode;
  field ( features : instance ) BookingFee;

  action ( features : instance ) acceptTravel result [1] $self;
  action ( features : instance ) rejectTravel result [1] $self;
  action ( features : instance ) deductDiscount parameter /DMO/A_TRAVEL_DISCOUNT result [1] $self;

… }

通过快速修复,您可以直接在行为定义编辑器中为行为池中的功能控制实施生成方法声明。

差旅实体的动态功能控制实施

动态功能控制必须在方法 FOR FEATURES 的行为实施中实施。您可以在方法声明的行为定义中,对其中一个动态功能控制功能使用快速修复。以下步骤将指导您完成实施。

  1. 读取导入 keys 到内部表 travels 的所有实例。与决定功能是否可用的字段相关,必须包含在读取结果中。对于差旅实体,仅字段 OverallStatus 相关。

  2. 使用相应特征填充方法的结果表。使用交易码 %tky 标识差旅实例。导入参数 keys 包含 %field 、 %action 、 %assoc 组件,用于确定控制的功能类型。使用条件语句定义每个动态控制功能的情况和结果。您可以使用在行为类的专用部分中定义的常量,以参考整体状态值。

展开以下代码示例以查看 GET_INSTANCE_FEATURES 的源代码。

示例代码

  METHOD get_instance_features.

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Travel
        FIELDS ( OverallStatus )
        WITH CORRESPONDING #( keys )
      RESULT DATA(travels)
      FAILED failed.

    result = VALUE #( FOR ls_travel IN travels
                          ( %tky                   = ls_travel-%tky

                            %field-BookingFee      = COND #( WHEN ls_travel-OverallStatus = travel_status-accepted
                                                             THEN if_abap_behv=>fc-f-read_only
                                                             ELSE if_abap_behv=>fc-f-unrestricted )
                            %action-acceptTravel   = COND #( WHEN ls_travel-OverallStatus = travel_status-accepted
                                                             THEN if_abap_behv=>fc-o-disabled
                                                             ELSE if_abap_behv=>fc-o-enabled )
                            %action-rejectTravel   = COND #( WHEN ls_travel-OverallStatus = travel_status-rejected
                                                             THEN if_abap_behv=>fc-o-disabled
                                                             ELSE if_abap_behv=>fc-o-enabled )
                            %action-deductDiscount = COND #( WHEN ls_travel-OverallStatus = travel_status-accepted
                                                             THEN if_abap_behv=>fc-o-disabled
                                                             ELSE if_abap_behv=>fc-o-enabled )
                            %assoc-_Booking        = COND #( WHEN ls_travel-OverallStatus = travel_status-rejected
                                                            THEN if_abap_behv=>fc-o-disabled
                                                            ELSE if_abap_behv=>fc-o-enabled )
                          ) ).

  ENDMETHOD..

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 开发功能控制 · 为预订实体添加功能控制 →