实施全局权限

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发权限 › 实施全局权限

对于具有草稿的管理场景,授权用户通常修改差旅实例。

在行为定义中定义全局权限,并在 Travel 的行为实施类中实施。有关概念信息,请参阅权限控制。

备注

在 ABAP 航班参考场景中,权限对象未在后端配置,因此将阻止任何用户进行任何操作。因此,除了通过权限对象 进行的检查外,代码示例还提供模拟的权限检查,而不使用权限对象。不要在生产应用程序中使用模拟代码。

定义

如果尚未执行此操作,请在行为定义中为差旅实体定义 authorization master (global),为预订和预订补充实体定义 authorization dependent by _Travel。

此外,委派所有操作的权限控制,内部操作和草稿操作除外,以及与更新操作逐个创建的关联。使用语法 authorization: update。

示例代码

...
define behavior for /DMO/R_Travel_D alias Travel
implementation in class /DMO/BP_TRAVEL_D unique
persistent table /DMO/A_TRAVEL_D
...
authorization master ( global )
{...
  association _Booking { create ( features : instance, authorization: update ) ; }

...

  action ( features : instance, authorization: update ) acceptTravel result [1] $self;
  action ( features : instance, authorization: update ) rejectTravel result [1] $self;
  action ( features : instance, authorization: update ) deductDiscount parameter /DMO/A_TRAVEL_DISCOUNT result [1] $self;
  internal action reCalcTotalPrice;

...}

define behavior for /DMO/R_Booking_D alias Booking
implementation in class /DMO/BP_BOOKING_D unique
....
authorization dependent by _Travel
{...
  association _BookingSupplement { create ( authorization: update ); }
...}

define behavior for /DMO/R_BookingSupplement_D alias BookingSupplement
implementation in class /DMO/BP_BOOKINGSUPPLEMENT_D unique
...
authorization dependent by _Travel
{
...
}

通过快速修复,您可以直接在行为定义编辑器中为行为池中的权限控制实施生成方法声明。

实施

全局权限控制必须在方法 FOR GLOBAL AUTHORIZATION 的行为实施中实施。您可以在方法声明的行为定义中使用快速修复。方法导入参数 requested_authorizations,指示请求权限的操作。在实施中,必须填充参数 result,该参数必须使用每个请求操作的权限结果填充。该方法还具有更改参数 reported,如果要返回未授权案例的消息,则填充该参数。有关实施详细信息的详细信息,请参阅权限实施。

本指南中的权限概念假设创建、更新和删除实例可能存在不同的权限。考虑与更新操作具有相同权限的差旅业务对象的所有操作。通过此方法,可能允许一个用户创建新的差旅实例,但不允许其使用操作。操作和按关联创建通过附加项 authorization: update 定义,因此不得在权限实施中单独处理。

由于创建、更新和删除权限对于全局权限和实例权限是相同的(实例权限的相关权限字段除外),因此最佳实践是以单独的方法外包实际权限检查,这些方法可由业务对象实施中所需的所有权限检查调用。

以下步骤将指导您完成实施。

权限检查方法

  1. 为每个操作创建方法以检查其权限。

  2. 我们使用权限对象 /DMO/TRVL 检查每个操作的权限。

    有关使用和配置权限对象的详细信息,请参阅应用服务器 ABAP 的用户和角色管理

    在每种方法中,调用权限对象并检查相关活动。

    操作

    活动字段

    create

    字段 01(添加或创建)

    update + 所有操作

    字段 02(更改)

    delete

    字段 06(删除)

    权限对象根据权限字段 /DMO/CNTRY 进行检查。对于全局权限,这不相关,因为执行操作的权限与相应实例的状态无关,因此与权限字段的值无关。为此,您可以将 'DUMMY' 用于权限字段。

    该实施单独考虑每个修改操作的权限。在差旅业务对象中创建、更新和删除实例可能有不同的权限。

  3. 根据 sy-subrc 评估相应操作的权限并填充方法的响应参数。

  4. 由于由权限对象检查的权限未在后端配置,因此我们提供模拟实施以允许所有用户执行所有操作。不要在生产应用程序中使用此代码。

    展开以下代码示例以查看方法 is_create_granted、is_update_granted 和 is_delete_granted 的源代码。

    示例代码

    CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
    
      PRIVATE SECTION.
    
    ...
        METHODS is_create_granted
          RETURNING VALUE(create_granted) TYPE abap_bool.
        METHODS is_update_granted
          RETURNING VALUE(update_granted) TYPE abap_bool.
        METHODS is_delete_granted
          RETURNING VALUE(delete_granted) TYPE abap_bool.
    
    ENDCLASS.
    
    CLASS lhc_travel IMPLEMENTATION.
      METHOD is_create_granted.
          AUTHORITY-CHECK OBJECT '/DMO/TRVL'
            ID '/DMO/CNTRY' DUMMY
            ID 'ACTVT'      FIELD '01'.
          create_granted = COND #( WHEN sy-subrc = 0 THEN abap_true ELSE abap_false ).
    
          "Simulation for full authorization
          "(not to be used in productive code)
        create_granted = abap_true.
        ENDIF.
    
      ENDMETHOD.
    
      METHOD is_update_granted.
          AUTHORITY-CHECK OBJECT '/DMO/TRVL'
            ID '/DMO/CNTRY' DUMMY
            ID 'ACTVT'      FIELD '02'.
          update_granted = COND #( WHEN sy-subrc = 0 THEN abap_true ELSE abap_false ).
    
          "Simulation for full authorization
          "(not to be used in productive code)
        update_granted = abap_true.
        ENDIF.
    
      ENDMETHOD.
    
      METHOD is_delete_granted.
          AUTHORITY-CHECK OBJECT '/DMO/TRVL'
            ID '/DMO/CNTRY' DUMMY
            ID 'ACTVT'      FIELD '06'.
          delete_granted = COND #( WHEN sy-subrc = 0 THEN abap_true ELSE abap_false ).
    
          "Simulation for full authorization
          "(not to be used in productive code)
        delete_granted = abap_true.
        ENDIF.
    
      ENDMETHOD.
    
    ENDCLASS.
    

全局权限实施

  1. 对于每个操作,检查是否已请求权限。在此示例中,将所有操作视为更新操作。必须在实施中手动委派编辑草稿操作。所有其他操作的权限均在行为定义中委派。

  2. 如果用户无权执行相应操作,则使用适当的消息填充报告的参数。

    展开以下代码示例以查看方法 get_global_authorizations 的源代码。

    示例代码

    CLASS lhc_travel DEFINITION INHERITING FROM cl_abap_behavior_handler.
    
      PRIVATE SECTION.
    
    ...
        METHODS get_global_authorizations FOR GLOBAL AUTHORIZATION
          IMPORTING REQUEST requested_authorizations FOR travel RESULT result.
    
    ENDCLASS.
    
    CLASS lhc_travel IMPLEMENTATION.
      METHOD get_global_authorizations.
        IF requested_authorizations-%create EQ if_abap_behv=>mk-on.
          IF is_create_granted( ) = abap_true.
            result-%create = if_abap_behv=>auth-allowed.
          ELSE.
            result-%create = if_abap_behv=>auth-unauthorized.
            APPEND VALUE #( %msg    = NEW /dmo/cm_flight_messages(
                                           textid   = /dmo/cm_flight_messages=>not_authorized
                                           severity = if_abap_behv_message=>severity-error )
                            %global = if_abap_behv=>mk-on
                          ) TO reported-travel.
    
          ENDIF.
        ENDIF.
    
        "Edit is treated like update
        IF requested_authorizations-%update                =  if_abap_behv=>mk-on OR
           requested_authorizations-%action-Edit           =  if_abap_behv=>mk-on.
    
          IF  is_update_granted( ) = abap_true.
            result-%update                =  if_abap_behv=>auth-allowed.
            result-%action-Edit           =  if_abap_behv=>auth-allowed.
    
          ELSE.
            result-%update                =  if_abap_behv=>auth-unauthorized.
            result-%action-Edit           =  if_abap_behv=>auth-unauthorized.
    
            APPEND VALUE #( %msg    = NEW /dmo/cm_flight_messages(
                                           textid   = /dmo/cm_flight_messages=>not_authorized
                                           severity = if_abap_behv_message=>severity-error )
                            %global = if_abap_behv=>mk-on
                          ) TO reported-travel.
    
          ENDIF.
        ENDIF.
    
        IF requested_authorizations-%delete =  if_abap_behv=>mk-on.
          IF is_delete_granted( ) = abap_true.
            result-%delete = if_abap_behv=>auth-allowed.
          ELSE.
            result-%delete = if_abap_behv=>auth-unauthorized.
            APPEND VALUE #( %msg    = NEW /dmo/cm_flight_messages(
                                           textid   = /dmo/cm_flight_messages=>not_authorized
                                           severity = if_abap_behv_message=>severity-error )
                            %global = if_abap_behv=>mk-on
                           ) TO reported-travel.
          ENDIF.
        ENDIF.
    
      ENDMETHOD.
    
    ENDCLASS.
    

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 开发权限 · 实施实例权限 →