实施预检查

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发权限 › 实施预检查

对于具有草稿的托管场景,添加预检查以根据传入值检查权限,以防止值到达事务缓冲区。

在行为定义中定义预检查,并在 Travel 的行为实施类中实施。有关概念信息,请参阅操作预检查。

定义

使用附加项 create 定义 update 和 (precheck)。通过添加 precheck,在执行主要操作之前调用预检查的行为实施。要使用 create 和其他标准操作获取 precheck 和 update 的运行时行为概览,请参阅标准操作。precheck 操作接收所有要创建的实体,如果针对传入值的检查返回负结果,则返回 failed 和 reported 作为更改参数。有关响应参数的详细信息,请参阅响应参数。

此外,向行动草案添加 with additional implementation Resume。如果是 edit draft,则需要执行此操作才能触发对 AgencyID 字段的检查。仅具有草稿功能的 RAP 业务对象需要此附加检查。

展开以下代码示例以查看 /DMO/R_Travel_D 的行为定义的源代码。

示例代码

...
define behavior for /DMO/R_Travel_D alias Travel
implementation in class /dmo/bp_travel_d unique
persistent table /dmo/a_travel_d
draft table /dmo/d_travel_d
lock master
total etag LastChangedAt
authorization master ( global, instance )
etag master LocalLastChangedAt
{
  create ( precheck );
  update ( precheck );
  ...
  draft action Resume with additional implementation;
}

通过快速修复,您可以直接在行为定义编辑器中为行为池中的预检查生成方法声明。

实施

预检查

根据代理的国家/地区代码的值检查使用提供的代理标识创建或保存已更新实例的权限。只能使用特定值 country_code 保存新创建或更新的实例。演示场景使用美国,可以更改为任何其他国家/地区代码。create 和 update 操作的 precheck 检查在触发 create 之前是否满足此条件。由于两个操作均根据相同的传入值进行检查,因此创建了帮助程序方法 precheck_auth 以简化实施。两个预检查实施都会根据助手方法的 agencyID 国家/地区代码委托实际检查。这两种方法都返回 failed 和 reported 作为更改参数。

展开以下代码示例以查看**方法 precheck_create FOR CREATE 和 precheck_update FOR UPDATE 的源代码。

示例代码

 METHOD precheck_create.
    precheck_auth(
        EXPORTING
          entities_create = entities
        CHANGING
          failed          = failed-travel
          reported        = reported-travel
      ).
  ENDMETHOD.

  METHOD precheck_update.
    precheck_auth(
        EXPORTING
          entities_update = entities
        CHANGING
          failed          = failed-travel
          reported        = reported-travel
      ).
  ENDMETHOD.

方法 precheck_auth

方法 precheck_auth 首先根据其导入参数和 FOR UPDATE 变量区分是从预检查方法 FOR CREATE 还是 operation 中调用它。断言确保方法只能从其中一个预检查实施中调用,不能同时从两者中调用。select 从数据库表中检索 AgencyID 的相应 country_code。实施循环所有已导入实体,并根据操作类型委托对 country_code US 值的检查:如果 operation 变量标记为 create,则调用方法 is_create_granted 并接收检索到的 country_code 作为导入参数。如果 operation 标记为 update,则调用方法 is_update_granted 并检查 country_code。如果设置了 US 以外的任何其他值,则将布尔值 is_modify_granted 设置为 abap_false,这意味着将拒绝授权。在这种情况下,将填充响应参数 failed 和 reported。

备注

在 ABAP 航班参考场景中,权限对象未在后端配置,因此将阻止任何用户进行任何操作。因此,除了通过权限对象 进行的检查外,代码示例还提供模拟的权限检查,而不使用权限对象。不要在生产应用程序中使用模拟代码。

展开以下代码示例以查看**方法 precheck_auth 的源代码。

示例代码

METHOD precheck_auth.
    DATA:
      entities          TYPE t_entities_update,
      operation         TYPE if_abap_behv=>t_char01,
      agencies          TYPE SORTED TABLE OF /dmo/agency WITH UNIQUE KEY agency_id,
      is_modify_granted TYPE abap_bool.

    " Either entities_create or entities_update is provided.  NOT both and at least one.
    ASSERT NOT ( entities_create IS INITIAL EQUIV entities_update IS INITIAL ).

    IF entities_create IS NOT INITIAL.
      entities = CORRESPONDING #( entities_create MAPPING %cid_ref = %cid ).
      operation = if_abap_behv=>op-m-create.
    ELSE.
      entities = entities_update.
      operation = if_abap_behv=>op-m-update.
    ENDIF.

    DELETE entities WHERE %control-AgencyID = if_abap_behv=>mk-off.

    agencies = CORRESPONDING #( entities DISCARDING DUPLICATES MAPPING agency_id = AgencyID EXCEPT * ).
    CHECK agencies IS NOT INITIAL.
    SELECT FROM /dmo/agency FIELDS agency_id, country_code
                            FOR ALL ENTRIES IN @agencies
                            WHERE agency_id = @agencies-agency_id
      INTO TABLE @DATA(agency_country_codes).

    LOOP AT entities INTO DATA(entity).
      is_modify_granted = abap_false.

      READ TABLE agency_country_codes WITH KEY agency_id = entity-AgencyID
                   ASSIGNING FIELD-SYMBOL(<agency_country_code>).

      "If invalid or initial AgencyID -> validateAgency
      CHECK sy-subrc = 0.
      CASE operation.
        WHEN if_abap_behv=>op-m-create. is_modify_granted = is_create_granted( <agency_country_code>-country_code ).
        WHEN if_abap_behv=>op-m-update. is_modify_granted = is_update_granted( <agency_country_code>-country_code ).
      ENDCASE.
      IF is_modify_granted = abap_false.
        APPEND VALUE #(
                         %cid      = COND #( WHEN operation = if_abap_behv=>op-m-create THEN entity-%cid_ref )
                         %tky      = entity-%tky
                       ) TO failed.

        APPEND VALUE #(
                         %cid      = COND #( WHEN operation = if_abap_behv=>op-m-create THEN entity-%cid_ref )
                         %tky      = entity-%tky
                         %msg      = NEW /dmo/cm_flight_messages(
                                                 textid    = /dmo/cm_flight_messages=>not_authorized_for_agencyid
                                                 agency_id = entity-AgencyID
                                                 severity  = if_abap_behv_message=>severity-error )
                         %element-AgencyID   = if_abap_behv=>mk-on
                      ) TO reported.
      ENDIF.
    ENDLOOP.

  ENDMETHOD.

Resume(含附加实施)

业务对象的草稿功能需要 edit draft 用例的附加检查实施。如果草稿已过期且 AgencyID 已更改,并且用户返回处理实例,则必须再次触发预检查实施以确保针对 country_code 值的权限检查的一致性。实施情况见差旅 AgencyID。然后 %control-AgencyID 设置为 true 以触发预检查实施。edit draft 场景在预检查情况下被视为 update,因此使用导出参数 precheck_auth 调用帮助器方法 entities_update。帮助程序方法在其实现中将此调用视为 update。

展开以下代码示例以查看**方法 resume 的源代码。

示例代码

METHOD resume.
    DATA:
      entities_update TYPE t_entities_update.

    READ ENTITIES OF /dmo/r_travel_d IN LOCAL MODE
      ENTITY Travel
        FIELDS ( AgencyID )
        WITH VALUE #(
                      FOR key IN keys
                        %is_draft = if_abap_behv=>mk-on
                        ( %key = key-%key )
                    )
        RESULT DATA(travels).

    " Set %control-AgencyID (if set) to true, so that the precheck_auth checks the permissions.
    entities_update = CORRESPONDING #( travels CHANGING CONTROL ).

    IF entities_update IS NOT INITIAL.
      precheck_auth(
        EXPORTING
          entities_update = entities_update
        CHANGING
          failed          = failed-travel
          reported        = reported-travel
      ).
    ENDIF.
  ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 实施实例权限 · 开发验证 →