创建投影视图
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用分层数据结构开发应用 › 具有只读功能的树视图 › 创建投影视图
在映射视图中,来自接口视图的公开数据与层次结构实体中数据的层次结构解释相连接。
要连接层次结构,请添加以下注释,指向层次结构实体:
@OData.hierarchy.recursiveHierarchy:[{ entity.name: '/DMO/I_EmployeeHN_HR' }]
将映射视图定义为接口视图上的投影:
示例代码
define view entity /DMO/C_Employee_HR
as select from /DMO/I_Employee_HR
association of many to one /DMO/C_Employee_HR as _Manager
on $projection.Manager = _Manager.Employee
消耗视图 /DMO/C_Employee_HR
展开以下代码示例以查看数据定义的源代码 /DMO/C_Employee_HR。
示例代码
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Hierarchy: Read Only: Employee'
@Metadata.allowExtensions: true
@Search.searchable: true
@OData.hierarchy.recursiveHierarchy:[{ entity.name: '/DMO/I_EmployeeHN_HR' }]
define view entity /DMO/C_Employee_HR
as select from /DMO/I_Employee_HR
association of many to one /DMO/C_Employee_HR as _Manager on $projection.Manager = _Manager.Employee
{
key Employee,
@Search: {
defaultSearchElement: true,
fuzzinessThreshold: 0.87
}
FirstName,
@Search: {
defaultSearchElement: true,
fuzzinessThreshold: 0.87
}
LastName,
Salary,
SalaryCurrency,
Manager,
/* Associations */
_Manager
}
创建业务服务
要完成 RAP 业务对象,请添加服务定义。在我们的示例中,此为 /DMO/UI_Employee_HR。
展开以下代码示例以查看数据定义的源代码 /DMO/UI_Employee_HR。
示例代码
@EndUserText.label: 'Hierarchy: Read Only: Employee'
@ObjectModel.leadingEntity.name: '/DMO/C_Employee_HR'
define service /DMO/UI_Employee_HR {
expose /DMO/C_Employee_HR as Employee;
}
Morevoer,您需要设置服务绑定。在我们的示例中,此为 /DMO/UI_Employee_HR_O4。
有关如何创建业务服务的详细信息,请参阅业务服务。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译