为目录创建视图实体作为构成子项

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用分层数据结构开发应用 › 具有草稿功能的可编辑树视图 › 可编辑树视图:概览中的开发流程 › 为目录创建视图实体作为构成子项

使用接口视图 /DMO/R_EmployeeTP_HD 为目录创建视图实体 /DMO/I_Employee_HD 作为组合子项。在此,您必须定义至父关联。

在我们的示例中,关联 _Agency 用作事务层次结构目录的构成父项。关联 _Agency 将每个员工连接到其父机构。

示例代码

 association         to parent /DMO/R_AgencyTP_HD as _Agency   on  $projection.Agency   = _Agency.Agency

由于可以将多个员工分配给同一经理,因此将以下关联的基数定义为多对一。

示例代码

association of many to one /DMO/R_EmployeeTP_HD  as _Manager  on  $projection.Agency   = _Manager.Agency
                                                                and $projection.Manager  = _Manager.Employee

第三个关联具有多对多关系。_Employee 关联是 _Manager 关联的反向关联。它具有确切的镜像关联条件。

示例代码

association of one to many /DMO/R_EmployeeTP_HD as _Employee on  $projection.Agency   = _Employee.Agency
                                                                and $projection.Employee = _Employee.Manager

展开以下代码示例以查看数据定义的源代码 /DMO/R_EmployeeTP_HD。

示例代码

@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Hierarchy: Draft: Employee'

define view entity /DMO/R_EmployeeTP_HD
  as select from /DMO/I_Employee_HD

  association         to parent /DMO/R_AgencyTP_HD as _Agency   on  $projection.Agency = _Agency.Agency
  association of many to one /DMO/R_EmployeeTP_HD  as _Manager  on  $projection.Agency  = _Manager.Agency
                                                                and $projection.Manager = _Manager.Employee
  association of one to many /DMO/R_EmployeeTP_HD as _Employee on  $projection.Agency   = _Employee.Agency
                                                                and $projection.Employee = _Employee.Manager
  association of one  to one I_Currency            as _Currency on  $projection.SalaryCurrency = _Currency.Currency

{

  key Agency,
  key Employee,
      FirstName,
      LastName,
      @Semantics.amount.currencyCode: 'SalaryCurrency'
      Salary,
      SalaryCurrency,
      Manager,
      SiblingOrderNumber,
      LocalCreatedBy,
      LocalCreatedAt,
      LocalLastChangedBy,
      LocalLastChangedAt,
      /* Associations */
      _Agency,
      _Manager,
      _Employee,
      _Currency

}

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 为目录创建根视图实体 · 定义层次结构 →