为目录创建行为定义

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用分层数据结构开发应用 › 具有草稿功能的可编辑树视图 › 可编辑树视图:概览中的开发流程 › 为目录创建行为定义

接下来,根据根视图实体 /DMO/R_AgencyTP_HD 创建行为定义 /DMO/R_AgencyTP_HD。

本演示基于使用草稿管理的实施类型。因此,此处必须将 managed 与 draft 一起使用。

示例代码

managed;
strict ( 2 );
with draft;

如果要允许插入层次结构实例,请使用 create 将构成公开到层次结构实体。

示例代码

association _Employee { create; with draft; }

生成草稿数据库表

如果尚未执行此操作,请在行为定义的源代码 /DMO/R_AgencyTP_HD 中使用快速修复来生成草稿数据库表 /dmo/agency_d_hd 和 /dmo/employ_d_hd。

有关如何草稿启用被管理业务对象的更多信息,请参阅草稿启用被管理业务对象。

记住

无论何时更改事务模型,都必须重新生成草稿表以将其对齐。行为定义为重新生成提供了快速修复,但应用程序开发人员负责使草稿表与事务模型保持同步。请记住,每次重新生成草稿数据库表时,都可能需要调整数据库表以保留现有数据。

展开以下代码示例以查看行为定义的源代码/DMO/R_AGENCYTP_HD。

示例代码

managed;
strict ( 2 );
with draft;

define behavior for /DMO/R_AgencyTP_HD alias Agency
implementation in class /dmo/bp_r_agencytp_hd unique
early numbering
persistent table /dmo/agency_a_hd
draft table /dmo/agency_d_hd
lock master
total etag LastChangedAt
authorization master ( none )
etag master LocalLastChangedAt
{
  create;
  update;
  delete;

  field ( readonly ) Agency, LocalCreatedBy, LocalCreatedAt, LocalLastChangedBy, LocalLastChangedAt, LastChangedAt;
  field ( mandatory ) CountryCode, EMailAddress, Name;

  association _Employee { create; with draft; }

  draft action Resume;
  draft action Edit;
  draft action Activate optimized;
  draft action Discard;

  validation validateEMailAddress on save { create; field EMailAddress; }
  validation validateCountryCode on save { create; field CountryCode; }
  validation validateName on save { create; field Name; }

  draft determine action Prepare
  {
    validation validateEMailAddress;
    validation validateCountryCode;
    validation validateName;
    validation Employee~validationSalaryPositive;
    validation Employee~validationCurrencyExists;
    validation Employee~validationNameGiven;
  }

  mapping for /dmo/agency_a_hd
    {
      Agency             = agency;
      Name               = name;
      Street             = street;
      PostalCode         = postal_code;
      City               = city;
      CountryCode        = country_code;
      PhoneNumber        = phone_number;
      EMailAddress       = email_address;
      WebAddress         = web_address;
      LocalCreatedBy     = local_created_by;
      LocalCreatedAt     = local_created_at;
      LocalLastChangedBy = local_last_changed_by;
      LocalLastChangedAt = local_last_changed_at;
      LastChangedAt      = last_changed_at;
    }

}

[...]