投影业务对象数据模型
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用多行编辑功能开发事务应用 › 预测 UI 敞口的业务对象 › 投影业务对象数据模型
对于多行编辑场景,为业务对象映射创建和定义数据模型。
上下文
多行编辑场景提供一个映射用例,该用例重用要为 UI 服务公开的业务对象视图实体中定义的所有元素。在投影层中,数据模型使用通过 映射视图中的 CDS 注释或关键字实施并在服务元数据中显示的 UI 功能进行丰富。
过程
为承运方业务对象的两个业务对象实体创建映射视图的数据定义。在 ADT 中,使用基础 CDS 视图实体上的上下文菜单打开用于创建 CDS 数据定义的向导,然后选择模板定义映射视图。
映射视图 /DMO/C_CarrierLockSingleton_S
投影视图是 /DMO/I_CarrierLockSingleton_S 上的投影。在投影视图中包含关键字 root。
使用基础业务对象差旅实体的所有元素。
使用注释 @Metadata.allowExtension:true 启用元数据扩展。
要指示 CarrierSingleton 是业务对象实体的语义标识符,请在投影视图的抬头中使用注释 @ObjectModel.semanticKey: ['CarrierSingleton']。
CarrierSingleton 仅用于成分的条件。在 UI 表示上不是必需的。使用注释 @Consumption.hidden:true。
只要业务对象成分结构的所有映射视图都可用,就将成分重定向到运输公司实体的映射视图。
展开以下代码示例以查看投影视图 /DMO/C_CarrierLockSingleton_S 的源代码。
示例代码
@EndUserText.label: 'Carrier Singleton Projection View'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['CarrierSingletonID']
define root view entity /DMO/C_CarriersLockSingleton_S
as projection on /DMO/I_CarriersLockSingleton_S
{
key CarrierSingletonID,
@Consumption.hidden: true
LastChangedAtMax,
/* Associations */
_Airline : redirected to composition child /DMO/C_Carrier_S
}
映射视图 /DMO/C_Carrier_S
投影视图是 /DMO/I_Carrier_S 上的投影。
使用基础业务对象差旅实体的所有元素。您不需要在投影视图中使用管理数据,表示 ETag 主数据 LocalLastChangedAt 的元素除外。
使用注释 @Metadata.allowExtension:true 启用元数据扩展。
使用实体抬头和指定元素上的@Search 注释为差旅实体启用搜索功能。有关详细信息,请参阅在 SAP Fiori 应用中启用文本和模糊搜索
要指示 CarrierID 是业务对象实体的语义标识符,请在投影视图的抬头中使用注释 @ObjectModel.semanticKey: ['AirlineID]。
CarrierSingletonID 仅用于成分的条件。在 UI 表示上不是必需的。使用注释 @Consumption.hidden:true。
定义元素 CurrencyCode 的值帮助。有关详细信息,请参阅添加值帮助。
业务对象的构成结构的所有映射视图可用后,将关联重定向到根实体到相应的映射视图。
展开以下代码示例以查看投影视图 /DMO/C_Carrier_S 的源代码。
示例代码
@EndUserText.label: 'Projection View Carrier'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['AirlineID']
define view entity /DMO/C_Carrier_S
as projection on /DMO/I_Carrier_S
{
key AirlineID,
@Consumption.hidden: true
CarrierSingletonID,
Name,
@Consumption.valueHelpDefinition: [{entity: {name: 'I_CurrencyStdVH', element: 'Currency' }, useForValidation: true }]
CurrencyCode,
LocalLastChangedAt,
/* Associations */
_CarrierSingleton : redirected to parent /DMO/C_CarriersLockSingleton_S
}
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 预测 UI 敞口的业务对象 · 添加 UI 使用的 UI 元数据 →