创建远程客户端代理
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 通过访问远程服务开发 UI 服务 › 使用远程 OData 服务 › 创建远程客户端代理
要启用从远程服务检索数据,必须建立与配置系统的连接,并实例化将 OData 请求传递到远程服务的客户端代理。
前提条件
为了能够处理远程服务,请确保满足使用远程服务的前提条件。
上下文
当通过 HTTP 请求远程使用 OData 服务时,使用远程客户端代理。出于重用原因,在单独的帮助程序类中实例化客户端代理非常有用。
异常和消息处理
在服务使用场景中,可能会出现多种类型的错误。查询或事务请求的执行相当复杂,因为一个请求不仅必须传递使用服务,还必须传递配置服务。在编码的不同部分,可能会发生错误。例如,在尝试连接到配置系统时,在实例化客户端代理时,在执行非托管查询时,在应用程序逻辑执行期间或修改折扣值期间。必须使用合适的异常和消息处理每种错误。因此,将所有异常及其相关消息合并到一个异常类和一个消息类中很方便。
在开始实施远程服务的使用之前,请创建异常和消息类。
异常类必须继承自超类 CX_RAP_QUERY_PROVIDER。
在示例场景中,异常类的名称为 CX_TRAVEL_SERV_CONS。消息类的名称为 CM_SERV_CONS。
实施步骤
为客户端代理实施创建辅助类
在项目浏览器中,选择相关包节点,打开上下文菜单,然后选择
New
ABAP Class
启动创建向导。按照创建向导的步骤操作并输入必要的信息。在示例场景中,我们选择名称
/DMO/CL_TRAVEL_CP_AUX。完成向导后,将显示最初生成的源代码并可供编辑。在辅助类的公共部分中声明一个静态方法以创建客户端代理:
create_client_proxy,返回参数为ro_client_proxy,如果存在错误,则引发异常。
CLASS /dmo/cl_travel_cp_aux DEFINITION
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
CLASS-METHODS:
get_client_proxy RETURNING VALUE(ro_client_proxy) TYPE REF TO /iwbep/if_cp_client_proxy
RAISING /dmo/cx_travel_serv_cons.
PROTECTED SECTION.
PRIVATE SECTION.
ENDCLASS.
CLASS /dmo/cl_travel_cp_aux IMPLEMENTATION.
METHOD get_client_proxy.
ENDMETHOD.
ENDCLASS.
创建配置系统的 HTTP 目标
要访问配置租户,您需要使用预先配置的通信安排创建 HTTP 目标。为此,请使用服务使用模型部件 /DMO/TRAVEL_SCM 提供的代码示例作为基础,并提供通信配置的相应值。
调用类
create_by_comm_arrangement的静态方法CL_HTTP_DESTINATION_PROVIDER以使用通信配置创建 HTTP 目标。在我们的场景中,通信场景和系统在名称TRAVEL_BASIC下设置,服务标识为OutboundCommunication。调用类
create_by_http_destination的静态方法CL_WEB_HTTP_CLIENT_MANAGER以使用创建的 HTTP 目标创建 HTTP 客户端。包括错误处理。使用异常类
/DMO/CX_TRAVEL_SERV_CONS发出适当的异常消息。
TRY.
" Create http client
DATA(lo_destination) = cl_http_destination_provider=>create_by_comm_arrangement(
comm_scenario = 'TRAVEL_BASIC'
comm_system_id = 'TRAVEL_BASIC'
service_id = 'OutboundCommunication' ).
lo_http_client = cl_web_http_client_manager=>create_by_http_destination( lo_destination ).
CATCH cx_http_dest_provider_error INTO DATA(lx_web_http_client_error).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>remote_access_failed
previous = lx_web_http_client_error.
CATCH cx_web_http_client_error INTO DATA(lx_http_client_error).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>remote_access_failed
previous = lx_web_http_client_error.
ENDTRY.
3. 实例化客户端代理
要使用配置系统中的远程服务,我们需要将请求委托给远程服务的客户端代理。由于我们的场景使用 OData V4,因此我们需要 V4 客户端代理。
服务使用模型为此提供了代码模板。
调用
create_v4_remote_proxy类的静态方法/IWBEP/CL_CP_FACTORY_REMOTE以实例化 OData V4 客户端代理。提供服务使用模型部件的名称/DMO/TRAVEL_SCM作为代理模型标识。提供远程服务的相对 URL 路径。使用异常类
/DMO/CX_TRAVEL_SERV_CONS发出适当的异常消息。
" Instantiation of client proxy
ro_client_proxy = /iwbep/cl_cp_factory_remote=>create_v4_remote_proxy(
EXPORTING
is_proxy_model_key = VALUE #( repository_id = 'DEFAULT'
proxy_model_id = '/DMO/TRAVEL_SCM'
proxy_model_version = '0001' )
io_http_client = lo_http_client
iv_relative_service_root = '<service_root>' ).
...
CATCH /iwbep/cx_gateway INTO DATA(lx_gateway_error).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>client_proxy_failed
previous = lx_gateway_error.
ENDTRY.
结果方法如下所示:
METHOD get_client_proxy.
DATA:
lo_http_client TYPE REF TO if_web_http_client,
lo_client_proxy TYPE REF TO /iwbep/if_cp_client_proxy.
TRY.
" Create http client
DATA(lo_destination) = cl_http_destination_provider=>create_by_comm_arrangement(
comm_scenario = 'TRAVEL_BASIC'
comm_system_id = 'TRAVEL_BASIC'
service_id = 'OutboundCommunication' ).
lo_http_client = cl_web_http_client_manager=>create_by_http_destination( lo_destination ).
" Instantiation of client proxy
ro_client_proxy = /iwbep/cl_cp_factory_remote=>create_v4_remote_proxy(
EXPORTING
is_proxy_model_key = VALUE #( repository_id = 'DEFAULT'
proxy_model_id = '/DMO/TRAVEL_SCM'
proxy_model_version = '0001' )
io_http_client = lo_http_client
iv_relative_service_root = '<service_root>' ).
CATCH cx_http_dest_provider_error INTO DATA(lx_web_http_client_error).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>remote_access_failed
previous = lx_web_http_client_error.
CATCH cx_web_http_client_error INTO DATA(lx_http_client_error).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>remote_access_failed
previous = lx_web_http_client_error.
CATCH /iwbep/cx_gateway INTO DATA(lx_gateway_error).
RAISE EXCEPTION TYPE /dmo/cx_travel_serv_cons
EXPORTING
textid = /dmo/cx_travel_serv_cons=>client_proxy_failed
previous = lx_gateway_error.
ENDTRY.
ENDMETHOD.