实施 MODIFY

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 通过访问远程服务开发 UI 服务 › 使用远程 OData 服务 › 将事务行为添加到业务对象 › 实施业务对象的行为池 › 实施 MODIFY

MODIFY 将更新数据。

在行为定义中定义 MODIFY 时,框架调用 UPDATE 方法。它修改应用程序缓冲区中的数据。在此消耗场景中,调用缓冲区方法 put_data 执行此操作。要返回足够的消息,MODIFY 方法还包括消息的映射方法。

为 MODIFY 声明方法

MODIFY 方法的声明由行为实施的模板生成,因为 UPDATE 已在行为定义中声明。

  1. 将导入参数的名称更改为 it_travel_update。

    CLASS lhc_Travel_SCM DEFINITION INHERITING FROM cl_abap_behavior_handler.
      PRIVATE SECTION.
    
    ...
        METHODS update FOR MODIFY
          IMPORTING it_travel_update FOR UPDATE Travel_SCM.
    
    ...
    ENDCLASS.
    

为 MODIFY 实施 方法

实际更新由缓冲区类中的方法 put_data 完成。此方法首先调用方法 get_data 以从缓冲区检索数据或从远程服务获取数据。然后更新所选差旅实例的折扣数据并计算 totalpricewithdiscount 的金额。

如果存在故障事件,则针对相应消息的处理,在方法 _map_messages 中调用 update 方法。

  1. 使用方法 get_instance 实例化缓冲区。

  2. 调用缓冲区类的 put_data 方法以更新所选差旅标识的折扣数据。

    如果 UPDATE 不起作用,则失败差旅实例的键值必须写入 failed 表。

    记住

    failed 表是 MODIFY 的 方法的隐式更改参数。

    将 put_data 的消息写入本地表 lt_message。

  3. 调用 _map_messages 方法将 lt_message 映射到 reported 表。

    记住

    reported 表是 MODIFY 的 方法的隐式更改参数。

METHOD update.
  DATA(lo_buffer) = lcl_buffer=>get_instance( ).

    lo_buffer->put_data(
        EXPORTING
          it_travel_upd      = it_travel_update
          IMPORTING
          et_travel_failed   = failed-travel_scm
          et_message         = DATA(lt_message)
    ).

    _map_messages(
      EXPORTING
        it_message         = lt_message
       IMPORTING
        et_travel_reported = reported-travel_scm
    ).
  ENDMETHOD.

消息处理

如果失败,必须将问题传输到 REPORTED 表,其中包括所有实例特定的消息。对于此类消息的处理,使用方法 _map_messages。在使用场景中,由于它仅在 MODIFY 方法中使用,因此在本地处理器类中定义。

声明 _map_messages

  1. 使用与消息返回的方法 _map_messages 类型兼容的导入参数 it_message 声明方法 put_data 以及与差旅实体的 reported 表兼容的导出参数 et_travel_reported。

    CLASS lhc_Travel_SCM DEFINITION INHERITING FROM cl_abap_behavior_handler.
      PRIVATE SECTION.
    ...
       TYPES:        tt_travel_reported   TYPE TABLE FOR REPORTED /DMO/R_TRAVEL_SCM_TP.
    
        METHODS: _map_messages
          IMPORTING it_message         TYPE lcl_buffer=>tt_message
          EXPORTING et_travel_reported TYPE tt_travel_reported.
    ...
    ENDCLASS.
    

实施 _map_messages

要将消息写入 REPORTED 表,它们必须与固定结构保持一致。此结构的消息通过方法 new_message 创建,该方法继承自接口 IF_ABAP_BEHV_MESSAGE。

  1. 对于 it_message 中的每条消息,通过调用方法 new_message 为 REPORTED 表创建新消息。

  2. 使用消息的差旅标识填充 ls_travel_reported 中的相关字段,并更改导致消息的元素的标志。

    METHOD _map_messages.
    
        DATA: ls_travel_reported LIKE LINE OF et_travel_reported.
        FIELD-SYMBOLS: <fs_element> TYPE data.
    
        LOOP AT it_message ASSIGNING FIELD-SYMBOL(<fs_message>).
          CLEAR ls_travel_reported.
          ls_travel_reported-%msg = new_message( id       = <fs_message>-symsg-msgid
                                                 number   = <fs_message>-symsg-msgno
                                                 severity = if_abap_behv_message=>severity-error
                                                 v1       = <fs_message>-symsg-msgv1
                                                 v2       = <fs_message>-symsg-msgv2
                                                 v3       = <fs_message>-symsg-msgv3
                                                 v4       = <fs_message>-symsg-msgv4 ).
          IF <fs_message>-travelid IS NOT INITIAL.
            ls_travel_reported-%key-travel_id = <fs_message>-travelid.
            ls_travel_reported-travel_id      = <fs_message>-travelid.
            LOOP AT <fs_message>-fields ASSIGNING FIELD-SYMBOL(<fs_field>).
              ASSIGN COMPONENT <fs_field> OF STRUCTURE ls_travel_reported-%element TO <fs_element>.
              CHECK sy-subrc = 0.
              <fs_element> = if_abap_behv=>mk-on.
            ENDLOOP.
            APPEND ls_travel_reported TO et_travel_reported.
          ENDIF.
        ENDLOOP.
      ENDMETHOD.
    

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 实施 READ · 实施 SAVE →