为具有草稿功能的示例业务对象公开消息

ABAP RESTful 应用程序编程模型 › 开发 › 开发单个业务对象功能 › 在 UI 和消息映射上公开消息 › 在 UI 上显示消息 › 为具有草稿功能的示例业务对象公开消息

本主题说明如何在行为实施中集成消息。

前提条件

您已为与 业务对象相关的所有 T100 消息创建消息包装器类。此示例使用在创建消息异常类中创建的消息文本和消息包装器类。

有关示例业务对象结构的详细信息,请参阅示例业务对象结构。

实施示例列出了消息实施 - 在每个部分的底部,您可以找到每种方法的完整源代码,以查看消息实施如何在源代码的上下文中集成。

备注

强烈建议将所有验证添加到 PREPARE 操作。由于验证返回状态消息,因此状态消息仅在 PREPARE 和 ACTIVATE 之前触发时根据其属性进行渲染。即使在 ACTIVATE 期间再次触发验证,状态消息处理也有所不同:PREPARE 中包含的验证在草稿实例上运行,并渲染状态消息,因为如果验证失败,则不会触发回滚。但是,如果验证稍后在 ACTIVATE 期间失败,则会触发回滚,直到此时触发的所有状态消息都将由框架转换为转换消息。有关 PREPARE 的详细信息,请参阅准备草稿实例以供激活。

示例实施:validateCustomer(差旅)

此示例显示 Travel 实体 validateCustomer 的消息实施。

此验证检查用户输入的 CustomerID 是否存在于 /DMO/CUSTOMER 表中。由于验证会检查业务对象状态的一致性,因此会返回差旅实体 reported 结构中的状态消息。要实现状态消息,必须使用字符串填充组件 %state_area。ValidateCustomer 本质上检查两个条件,每次只能有一个条件为真 - 用户输入的 CustomerID 未知或用户未输入任何值。因此,两个消息可以具有相同的 %state_area,因此在实施开始时只需要一个失效语句。%state_area 的名称与验证名称相同。两种情况下的目标字段均为 CustomerID 字段。由于消息在 failed 结构中的条目后返回,因此所有消息均按严重性错误进行分类。

备注

建议在验证实施中使用相同的 %state_area。如果 %state_area 不同,则必须单独使每个 %state_area 失效。

    " Invalidate state messages
    APPEND VALUE #(  %tky                 = ls_travel-%tky
                     %state_area          = 'VALIDATE_CUSTOMER' ) TO reported-travel.

    [...]
    "Return state message when no CustomerID was entered
    APPEND VALUE #(  %tky = ls_travel-%tky
                     %msg = NEW dmo_messagewrapper(
                              textid     = dmo_messagewrapper=>customer_id_not_initial
                              severity   = if_abap_behv_message=>severity-error  )
                     %element-customerid = if_abap_behv=>mk-on
                     %state_area         = 'VALIDATE_CUSTOMER'
      )  TO reported-travel.

    [...]

    "Return state message if incorrect CustomerID was entered
    APPEND VALUE #(  %tky                = ls_travel-%tky
                     %msg                = NEW dmo_messagewrapper(
                                             textid = dmo_messagewrapper=>customerid_not_exist
                                             severity = if_abap_behv_message=>severity-error  )
                     %element-customerid = if_abap_behv=>mk-on
                     %state_area         = 'VALIDATE_CUSTOMER'
      )  TO reported-travel.

展开以下代码示例以查看 validateCustomer 的源代码。

示例代码

    METHOD validatecustomer.

      READ ENTITIES OF dmo_i_travel_messages IN LOCAL MODE
        ENTITY travel
          FIELDS ( customerid )
          WITH CORRESPONDING #( keys )
      RESULT DATA(lt_travel)
      FAILED DATA(lt_failed).

      failed =  CORRESPONDING #( DEEP lt_failed  ).

      DATA lt_customer TYPE SORTED TABLE OF /dmo/customer WITH UNIQUE KEY customer_id.

      " Optimization of DB select: extract distinct non-initial customer IDs
      lt_customer = CORRESPONDING #( lt_travel DISCARDING DUPLICATES MAPPING customer_id = customerid EXCEPT * ).
      DELETE lt_customer WHERE customer_id IS INITIAL.

      IF  lt_customer IS NOT INITIAL.
        " Check if customer ID exists
        SELECT FROM /dmo/customer FIELDS customer_id
                                  FOR ALL ENTRIES IN @lt_customer
                                  WHERE customer_id = @lt_customer-customer_id
        INTO TABLE @DATA(lt_customer_db).
      ENDIF.

      " Raise message for non existing customer id
      LOOP AT lt_travel INTO DATA(ls_travel).

      " Invalidate state messages
          APPEND VALUE #(  %tky        = ls_travel-%tky
                         %state_area = 'VALIDATE_CUSTOMER' ) TO reported-travel.

        IF ls_travel-customerid IS  INITIAL.
          APPEND VALUE #(  %tky = ls_travel-%tky ) TO failed-travel.
          APPEND VALUE #(  %tky = ls_travel-%tky
                           %msg = NEW dmo_messagewrapper(
                                    textid     = dmo_messagewrapper=>customer_id_not_initial
                                    severity   = if_abap_behv_message=>severity-error  )
                           %element-customerid = if_abap_behv=>mk-on
                           %state_area         = 'VALIDATE_CUSTOMER'
          )  TO reported-travel.

          ELSEIF ls_travel-customerid IS NOT INITIAL AND NOT line_exists( lt_customer_db[ customer_id = ls_travel-customerid ] ).
          APPEND VALUE #(  %tky = ls_travel-%tky ) TO failed-travel.

          " Message if customerID is unknown
          APPEND VALUE #(  %tky = ls_travel-%tky
                           %msg = NEW dmo_messagewrapper(
                                    textid     = dmo_messagewrapper=>customerid_not_exist
                                    severity   = if_abap_behv_message=>severity-error  )
                           %element-customerid = if_abap_behv=>mk-on
                           %state_area         = 'VALIDATE_CUSTOMER'

          )  TO reported-travel.
        ENDIF.

示例实施:setToBooked(差旅)

此示例显示 Travel 实体的 setToBooked 的消息实施。

此操作将 overall_status 字段设置为 B(有值)。通常,操作会返回转换消息,因为它们会触发业务对象的更改。因此,此操作将返回转换消息:此消息用于确认 overallStatus 的转换成功。转换消息分类为成功并将其分配到 reported-travel,因为它在语义上与此实体上触发的请求相关。目标字段为 overallStatus。对于转换消息,必须在 %op 中指定相应的操作。在这种情况下,消息属于操作 setToBooked。

    "Return transition message in case of successful request
    APPEND VALUE #( %tky = result[ 1 ]-%tky
                    %msg = NEW dmo_messagewrapper(
                             textid        = dmo_messagewrapper=>action_successful
                             severity      = if_abap_behv_message=>severity-success  )
                    %element-overallstatus = if_abap_behv=>mk-on
                    %action-setToBooked    = if_abap_behv=>mk-on
          ) TO reported-travel.

展开以下代码示例以查看 setToBooked 的源代码。

示例代码

    " Modify travel instance
     MODIFY ENTITIES OF z_fd_i_travel_messages_demo IN LOCAL MODE
           ENTITY travel
            UPDATE FIELDS ( overallstatus )
            WITH VALUE #(   FOR key IN keys ( %tky = key-%tky
                                              overallstatus = 'B' ) ) "Booked
     FAILED   failed.

     " read changed data for action result
     READ ENTITIES OF dmo_travel_messages IN LOCAL MODE
         ENTITY travel ALL FIELDS WITH
         CORRESPONDING #( keys  )
     RESULT DATA(lt_travel).

    result = VALUE #( FOR travel IN lt_travel ( %tky      = travel-%tky
                                                %param    = travel ) ).

*add success MESSAGE at the END of the action
    APPEND VALUE #( %tky = result[ 1 ]-%tky
                    %msg = NEW dmo_messagewrapper(
                             textid        = dmo_messagewrapper=>action_successful
                             severity      = if_abap_behv_message=>severity-success  )
                    %element-overallstatus = if_abap_behv=>mk-on
                    %action-setToBooked    = if_abap_behv=>mk-on
             ) TO reported-travel.

示例实施:validateBookingDate(预订)

此示例显示 Booking 实体 validateBookingDate 的消息实施。

验证会检查所选预订日期是否在父差旅实体的 开始日期 和 结束日期 之间。在此示例中,验证包括在确定操作 PREPARE 中,以便在 ACTIVATE 之前触发验证。如果 selected1 BookingDate 不在 Start-and Enddate 之间,则此验证将返回状态消息。消息具有严重性错误和目标字段 BookingDate。由于预订实体是差旅实体的直接子项,因此需要通过映射两个草稿实例使用差旅实体的路径填充 %path 组件。此状态消息绑定到 REPORTED-booking 结构。

备注

如果业务对象中有外部编号并将标识作为消息变量传递,则消息包装类不会忽略前导零。

    "Return state message when bookingdate is not in of selected time frame

    APPEND VALUE #( %tky                 = <ls_booking>-%tky
                    %state_area          = lv_state_area
                    %path                = VALUE #( travel-%is_draft  = <ls_booking>-%is_draft
                                                    travel-traveluuid = <ls_booking>-traveluuid )
                    %msg                 = NEW dmo_messagewrapper(
                                             textid    = dmo_messagewrapper=>incorrect_booking_date
                                             travel_id = <ls_booking>-traveluuid
                                             severity  = if_abap_behv_message=>severity-error  )
                    %element-bookingdate = if_abap_behv=>mk-on ) TO reported-booking.

展开以下代码示例以查看 validateDates 的源代码。

示例代码

 METHOD validateDates.
   CHECK keys IS NOT INITIAL.

      READ ENTITIES OF z_fd_i_travel_messages_demo IN LOCAL MODE
           ENTITY booking
              FIELDS ( bookinguuid traveluuid bookingid  bookingdate  )
              WITH CORRESPONDING #( keys )
      RESULT DATA(lt_booking).

      READ ENTITIES OF z_fd_i_travel_messages_demo IN LOCAL MODE
           ENTITY booking BY \_travel
              FIELDS ( traveluuid travelid begindate enddate )
                WITH CORRESPONDING #( lt_booking )
      RESULT DATA(lt_travel).

      LOOP AT lt_booking ASSIGNING FIELD-SYMBOL(<ls_booking>) WHERE bookingdate IS NOT INITIAL.
        ASSIGN lt_travel[ KEY entity COMPONENTS traveluuid = <ls_booking>-traveluuid ] TO FIELD-SYMBOL(<ls_travel>).

        IF <ls_travel>-begindate IS NOT INITIAL AND
        <ls_travel>-enddate   IS NOT INITIAL.

          DATA(lv_state_area) =  'VAL_BOOKING_DATE'.

            IF <ls_booking>-%tky-%is_draft = if_abap_behv=>mk-on.
            APPEND VALUE #( %tky           = <ls_booking>-%tky
                            %state_area    = lv_state_area ) TO reported-booking.

        ENDIF.

        IF <ls_booking>-bookingdate < <ls_travel>-begindate OR
           <ls_booking>-bookingdate > <ls_travel>-enddate.

            APPEND VALUE #( %tky                 = <ls_booking>-%tky ) TO failed-booking.
            APPEND VALUE #( %tky                 = <ls_booking>-%tky
                            %state_area          = lv_state_area
                            %path                = VALUE #( travel-%is_draft  = <ls_booking>-%is_draft
                                                            travel-traveluuid = <ls_booking>-traveluuid )
                            %msg                 =  NEW dmo_messagewrapper(
                                                      textid    = dmo_messagewrapper=>incorrect_booking_date
                                                      travel_id = <ls_booking>-traveluuid
                                                      severity  = if_abap_behv_message=>severity-error  )
                            %element-bookingdate = if_abap_behv=>mk-on ) TO reported-booking.
          ENDIF.
        ENDIF.
      ENDLOOP.
ENDMETHOD.

示例实施:全局上下文中的消息

从全局权限或全局功能控制方法返回的消息不属于特定实例,因为在创建实例之前调用全局方法。这就是全局方法始终返回实体绑定转换消息的原因。有关详细信息,请参阅转换消息。

由于全局权限与实体的状态无关,并且仅检查已执行请求的用户的权限,因此全局权限处理器通常用于禁止特定用户组的特定操作。典型用例是仅允许特定用户组创建新实例。

有关权限的详细信息,请参阅权限控制。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 创建消息异常类 · 在业务对象之间映射消息 →