获取映射视图中的语言相关文本

ABAP RESTful 应用程序编程模型 › 开发 › 开发通用功能 › 使用文本元素 › 获取映射视图中的语言相关文本

对于包含在投影视图中并通过注释 @ObjectModel.text.element: ['<text_element>'] 引用的文本元素,通过关键字 localized 完成投影视图中语言相关文本的非规范化。

上下文

您具有文本提供者视图,其中维护了不可读元素的文本。要从中获取文本,无需在文本提供者视图中进行任何准备。

要建立与此文本提供程序视图的连接,投影视图必须与文本提供程序视图关联。

备注

要在映射视图中使用非规范化,不得在投影视图中使用文本关联 @ObjectModel.text.association: '<text_association> 的标识。

然后,可以通过映射视图中的关联将文本元素包括在内。标识符元素与相应文本之间的关系通过注释 @ObjectModel.text.element: ['<text_element>'] 在投影视图中定义,请参阅 CDS 投影视图。如果使用关键字 localized,则绘制系统登录语言的文本。

下图说明了投影视图中文本非规范化的建模。。

前提条件

  • 文本提供者视图具有指示文本语言的关键元素。

  • 投影 CDS 视图 与文本提供者视图 具有关联,但不使用注释 ObjectModel.text.association。

过程

示例代码片段取自 ABAP 航班场景,可从 GitHub 下载,请参阅 ABAP 航班参考场景。

  1. 将文本提供者视图中的文本元素包括在投影视图中。

  2. 在投影视图中对要为其提供文本的元素进行注释 @ObjectModel.text.element: [<text_element>] 并引用文本元素。

  3. 要获取语言相关文本,请使用文本元素上的关键字 localized。

展开以下代码示例以查看源代码

示例代码

//Text Provider View
//The text provider view selects from a database table, in which the description texts in different languages are stored.
define view entity /DMO/I_SupplementText
  as select from /dmo/suppl_text as SupplementText

{
      @ObjectModel.text.element: ['Description']
  key SupplementText.supplement_id as SupplementID,

      @Semantics.language: true
  key SupplementText.language_code as LanguageCode,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Semantics.text: true
      SupplementText.description   as Description
}
Projected View
define view entity /DMO/I_BookSuppl_M
  as select from /dmo/booksuppl_m as BookingSupplement

  association        to parent /DMO/I_Booking_M  as _Booking     on  $projection.travel_id    = _Booking.travel_id
                                                                 and $projection.booking_id   = _Booking.booking_id

...
  association [1..*] to /DMO/I_SupplementText as _SupplementText on $projection.supplement_id = _SupplementText.SupplementID
{
  key travel_id,
  key booking_id,
  key booking_supplement_id,
      supplement_id,
...
      _SupplementText
}
//Projection View
//The projection view denormalizes the supplement description and filters the relevant values based on the requested language.It depends on the language configuration of your cloud system, which language is allowed.
define view entity /DMO/C_BookSuppl_Processor_M
  as projection on /DMO/I_BookSuppl_M
{
  key travel_id                   as TravelID,
  key booking_id                  as BookingID,
  key booking_supplement_id       as BookingSupplementID,
      @ObjectModel.text.element: ['SupplementDescription']
      supplement_id               as SupplementID,
      _SupplementText.Description as SupplementDescription : localized,
...
      _SupplementText
}

如果为此示例创建 UI 服务,则可以在以不同语言发送请求时检查结果,前提是数据库表上提供了不同语言的文本。

英语和德语的补充描述