启用 CDS 视图
ABAP RESTful 应用程序编程模型 › 扩展 › RAP 可扩展性启用 › 开发可扩展性启用 › 启用数据模型扩展 › 启用 CDS 视图
本章将指导您完成启用参考业务对象的 CDS 视图以进行数据模型扩展的必要步骤。
所需的赋能步骤
与数据库级别类似,您需要创建扩展 include 视图并从 CDS 视图 /DMO/R_AGENCYTP 定义与其的关联。然后,扩展程序可以为扩展 include 视图和 CDS 视图 /DMO/R_AGENCYTP 添加视图扩展。在后一种情况下,扩展器使用与扩展 include 视图 的关联,以便使用新字段扩展 CDS 视图 /DMO/R_AGENCYTP。
为了为字段扩展准备整个业务对象堆栈,您需要在基础层以及映射和接口层上使用 CDS 注释将 CDS 视图定义为可显式扩展。
有关 CDS 启用体系结构的详细信息和概览,请参阅 CDS 视图的可扩展性启用。
定义扩展 Include 视图
创建名称为 /DMO/E_AGENCY 的 CDS 视图实体,该实体将用作扩展 include 视图。在 CDS 视图中,仅从数据库表 agency_id 中选择关键字段 /DMO/AGENCY 并为数据源提供别名 Agency。使用以下 CDS 注释定义扩展包括视图的启用范围:
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]:允许扩展select列表。@AbapCatalog.extensibility.extensible: true:将扩展 include 视图定义为可扩展。@AbapCatalog.extensibility.elementSuffix: 'ZAG':定义要用于此扩展 include 视图的视图扩展的元素后缀。@AbapCatalog.extensibility.allowNewDatasources: false:定义在 CDS 视图中定义的关联是否可用于寻址路径表达式中的数据源。在此示例中,我们不希望在 CDS 视图 中使用任何其他数据源,因此我们选择选项false。@AbapCatalog.extensibility.dataSources: ['Agency']:定义别名Agency可用于此 CDS 视图的扩展。@AbapCatalog.extensibility.quota.maximumFields: 500:定义扩展器可以添加的最大字段数。@AbapCatalog.extensibility.quota.maximumBytes: 50000:定义为扩展器保留的字节容量。
生成的扩展包括如下视图:
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Agency - Extension Include View'
@AbapCatalog.extensibility: {
extensible: true,
elementSuffix: 'ZAG',
allowNewDatasources: false,
dataSources: ['Agency'],
quota: {
maximumFields: 500,
maximumBytes: 50000
}
}
define view entity /DMO/E_Agency
as select from /dmo/agency as Agency
{
key agency_id as AgencyId
}
备注
我们建议您添加 C0 审批合同以指定此开发对象旨在作为稳定的扩展 API。
启用 CDS 视图 /DMO/R_AGENCYTP
定义与扩展的关联,包括基数为
[1]/DMO/E_AGENCY、关联名称为_Extension且字段为代理标识作为连接条件的视图。association [1] to /DMO/E_Agency as _Extension on $projection.AgencyID = _Extension.AgencyId
使用定义 CDS 视图启用范围的 CDS 注释。大多数注释值与上述扩展 include 视图相同。对于注释
@AbapCatalog.extensibility.dataSources,使用关联_Extension。这使扩展者可以在此 CDS 视图的扩展中使用此关联。
生成的 CDS 视图的上半部分如下所示:
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Agency'
@Search.searchable: true
@AbapCatalog.extensibility: {
extensible: true,
elementSuffix: 'ZAG',
allowNewDatasources: false,
dataSources: ['_Extension'],
quota: {
maximumFields: 500,
maximumBytes: 50000
}
}
define root view entity /DMO/R_AgencyTP
as select from /DMO/I_Agency as Agency
association [0..1] to I_Country as _Country on $projection.CountryCode = _Country.Country
association [1] to /DMO/E_Agency as _Extension on $projection.AgencyID = _Extension.AgencyId
{
key AgencyID,
备注
我们建议您添加 C0 审批合同以指定此开发对象旨在作为稳定的扩展 API。
启用 CDS 视图 /DMO/C_AGENCYTP
使用定义 CDS 视图启用范围的 CDS 注释。大多数注释值与上述视图相同。对于注释 @AbapCatalog.extensibility.dataSources,使用别名 Agency。这允许扩展程序在此 CDS 视图的扩展中使用此别名。此外,注释 @Metadata.allowExtensions: true 用于为此视图添加元数据扩展。
生成的 CDS 视图的上半部分如下所示:
@EndUserText.label: 'Agency'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Search.searchable: true
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['AgencyID']
@AbapCatalog.extensibility: {
extensible: true,
dataSources: ['Agency'],
elementSuffix: 'ZAG',
quota: {
maximumFields: 500,
maximumBytes: 50000
}
}
define root view entity /DMO/C_AgencyTP
provider contract transactional_query
as projection on /DMO/R_AgencyTP as Agency
{
key AgencyID,
备注
我们建议您添加 C0 审批合同以指定此开发对象旨在作为稳定的扩展 API。
启用 CDS 视图 /DMO/I_AGENCYTP
使用定义 CDS 视图启用范围的 CDS 注释。大多数注释值与上述视图相同。对于注释 @AbapCatalog.extensibility.dataSources,使用别名 Agency。这允许扩展程序在此 CDS 视图的扩展中使用此别名。
生成的 CDS 视图的上半部分如下所示:
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Agency'
@Search.searchable: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AbapCatalog.extensibility: {
extensible: true,
dataSources: ['AGENCY'],
elementSuffix: 'ZAG',
quota: {
maximumFields: 500,
maximumBytes: 50000
}
}
define root view entity /DMO/I_AgencyTP
provider contract transactional_interface
as projection on /DMO/R_AgencyTP as Agency
{
@ObjectModel.text.element: ['Name']
key AgencyID,
备注
我们建议您添加 C0 审批合同以指定此开发对象旨在作为稳定的扩展 API。
备注
建议添加 C1 发布合同,以指定此开发对象旨在作为稳定的使用数据源。
出于维护原因,/DMO/ 参考内容的部件不会随定义的发布合同一起提供。
定义草稿查询视图 /DMO/R_AGENCYDRAFT
创建名为
/DMO/R_AgencyDraft的 CDS 视图实体,该实体选择数据库表/DMO/AGENCY_D并为数据源提供别名Agency。移除抬头中的所有 CDS 注释,@AccessControl.authorizationCheck: #NOT_REQUIRED和@EndUserText.label: 'Draft Query View: Agency'除外。CDS 视图将用作草稿查询视图。使用定义 CDS 视图启用范围的 CDS 注释。大多数注释值与上述视图相同。对于注释
@AbapCatalog.extensibility.dataSources,使用别名Agency。这允许扩展程序在此 CDS 视图的扩展中使用此别名。生成的 CDS 视图如下所示:
@AccessControl.authorizationCheck: #NOT_REQUIRED @EndUserText.label: 'Draft Query View: Agency' @AbapCatalog.extensibility: { extensible: true, dataSources: ['Agency'], elementSuffix: 'ZAG', quota: { maximumFields: 500, maximumBytes: 50000 } } define view entity /DMO/R_AgencyDraft as select from /dmo/agency_d as Agency { key agencyid as Agencyid, key draftuuid as Draftuuid, name as Name, street as Street, postalcode as Postalcode, city as City, countrycode as Countrycode, phonenumber as Phonenumber, emailaddress as Emailaddress, webaddress as Webaddress, attachment as Attachment, mimetype as Mimetype, filename as Filename, localcreatedby as Localcreatedby, localcreatedat as Localcreatedat, locallastchangedby as Locallastchangedby, locallastchangedat as Locallastchangedat, lastchangedat as Lastchangedat, draftentitycreationdatetime as Draftentitycreationdatetime, draftentitylastchangedatetime as Draftentitylastchangedatetime, draftadministrativedatauuid as Draftadministrativedatauuid, draftentityoperationcode as Draftentityoperationcode, hasactiveentity as Hasactiveentity, draftfieldchanges as Draftfieldchanges }
备注
我们建议您添加 C0 审批合同以指定此开发对象旨在作为稳定的扩展 API。
在行为定义
/DMO/R_AGENCYTP中,将参考添加到创建的草稿查询视图。... define behavior for /DMO/R_AgencyTP alias Agency persistent table /dmo/agency draft table /dmo/agency_d query /DMO/R_AgencyDraft ...
结果
现在,您已启用数据模型扩展的业务对象。请参阅开发数据模型扩展章节,了解如何将新字段添加到数据库表和 CDS 数据模型。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 启用数据库表 · 启用非标准行为和字段相关行为 →