实施扩展行为
ABAP RESTful 应用程序编程模型 › 扩展 › RAP 扩展 › 开发 RAP 扩展 › 开发行为扩展 › 实施扩展行为
在本章中,实施在上一步中定义的扩展行为。
行为扩展中定义的行为的实施遵循与为原始业务对象定义的行为实施相同的方法。不需要与可扩展性相关的特殊类语法。但是,在通过 EML 从扩展中访问原始业务对象时存在差异。
备注
接口是业务对象的合并消耗点,每个使用者都需要使用该消耗点。这也适用于在其扩展中通过 EML 访问原始业务对象的扩展器。这就是行为扩展实施中的 EML 语句必须始终通过其接口寻址原始业务对象的原因。
如果在行为扩展的 EML 语句中使用关键字
IN LOCAL MODE,则仅绕过此扩展的功能控件和权限实施。此类语句不会绕过原始业务对象的功能控制和权限实施。
以下部分描述了实施扩展行为所需的步骤。
前提条件
已按照 定义扩展行为 章节中所述定义扩展行为并为扩展创建行为实施类。
定义所需类组件
作为实施验证和确定的准备步骤,您需要为验证报告的消息定义状态区域。此外,验证和确定需要查找表才能使用拨号和国家/地区代码。按如下方式定义这些组件:
在行为实施类的公共部分,使用类型 string 和值 validate_dialling_code 定义常量 VALIDATE_DIALLING_CODE。您将使用此常量作为验证 validateDiallingCode 所报告消息的状态区域。
CLASS lhc_Agency DEFINITION INHERITING FROM cl_abap_behavior_handler. PUBLIC SECTION. CONSTANTS: validate_dialling_code TYPE string VALUE 'VALIDATE_DIALLING_CODE' ##NO_TEXT.
要开发的验证和确定将使用拨号代码和国家/地区代码的查找表。查找表的内容在类构造函数中初始化。在公共部分定义必要的类型和查找表,并使用方法 class constructor 中的示例值填充 表。
CLASS lhc_Agency DEFINITION INHERITING FROM cl_abap_behavior_handler. PUBLIC SECTION. CONSTANTS: validate_dialling_code TYPE string VALUE 'VALIDATE_DIALLING_CODE' ##NO_TEXT. TYPES: BEGIN OF t_countries, number TYPE /dmo/phone_number, code TYPE land1, END OF t_countries. CLASS-DATA: countries TYPE STANDARD TABLE OF t_countries WITH KEY number. CLASS-METHODS: class_constructor. PRIVATE SECTION. METHODS validateDiallingCode FOR VALIDATE ON SAVE IMPORTING keys FOR /DMO/Agency~/DMO/validateDiallingCode. METHODS determineCountryCode FOR DETERMINE ON MODIFY IMPORTING keys FOR /DMO/Agency~/DMO/determineCountryCode. METHODS determineDiallingCode FOR DETERMINE ON MODIFY IMPORTING keys FOR /DMO/Agency~/DMO/determineDiallingCode. METHODS get_global_authorizations FOR GLOBAL AUTHORIZATION IMPORTING REQUEST requested_authorizations FOR /DMO/Agency RESULT result. METHODS createFromTemplate FOR MODIFY IMPORTING keys FOR ACTION /DMO/Agency~/DMO/createFromTemplate. ENDCLASS. CLASS lhc_Agency IMPLEMENTATION. METHOD validateDiallingCode. ENDMETHOD. METHOD determineCountryCode. ENDMETHOD. METHOD determineDiallingCode. ENDMETHOD. METHOD get_global_authorizations. ENDMETHOD. METHOD createFromTemplate. ENDMETHOD. METHOD class_constructor. countries = VALUE #( ( number = '+1' code = 'US' ) ( number = '+49' code = 'DE' ) ( number = '+39' code = 'IT' ) ( number = '+43' code = 'AT' ) ( number = '+44' code = 'GB' ) ( number = '+81' code = 'JP' ) ( number = '+33' code = 'FR' ) ( number = '+358' code = 'FI' ) ( number = '+385' code = 'HR' ) ). ENDMETHOD. ENDCLASS.
实施验证 validateDiallingCode
读取要验证的所有实例的字段
PhoneNumber和CountryCode及其键值,并将结果存储在内部表中。所有待验证实例的循环。对于每个实例,执行以下操作:
使状态区域
validate_dialling_code的状态消息无效,以避免为代理实例持续添加具有相同状态区域的消息。如果字段
PhoneNumber为初始值,则继续下一个实例。不需要验证电话号码为空的实例。如果电话号码的前两个字符是
00,则将其替换为+符号。如果电话号码的第一个字符不是
+,则使用状态区域reported将相应的消息附加到此实例的validate_dialling_code结构。在PhoneNumber组件中标记字段element。如果查找表中
countries没有条目,其中电话号码与循环实例的前两个、三个和四个电话号码字符匹配,并且国家/地区代码与已循环实例之一匹配,则使用状态区域validate_dialling_code将相应的消息附加到此实例的reported结构。在PhoneNumber组件中标记字段element。
METHOD validateDiallingCode.
READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
ENTITY /DMO/Agency
FIELDS ( PhoneNumber CountryCode ) WITH CORRESPONDING #( keys )
RESULT DATA(agencies).
LOOP AT agencies INTO DATA(agency).
APPEND VALUE #( %tky = agency-%tky
%state_area = validate_dialling_code ) TO reported-/DMO/Agency.
IF agency-PhoneNumber IS INITIAL.
CONTINUE.
ENDIF.
IF agency-PhoneNumber(2) = '00'.
REPLACE FIRST OCCURRENCE OF '00' IN agency-Phonenumber WITH '+'.
ENDIF.
IF agency-PhoneNumber(1) <> '+'.
APPEND VALUE #( %tky = agency-%tky
%state_area = validate_dialling_code
%msg = NEW /dmo/zz_cx_agency_country( textid = /dmo/zz_cx_agency_country=>number_invalid
phonenumber = agency-PhoneNumber )
%element-PhoneNumber = if_abap_behv=>mk-on )
TO reported-/DMO/Agency.
ELSEIF NOT line_exists( countries[ number = agency-phonenumber(2) code = agency-CountryCode ] )
AND NOT line_exists( countries[ number = agency-phonenumber(3) code = agency-CountryCode ] )
AND NOT line_exists( countries[ number = agency-phonenumber(4) code = agency-CountryCode ] ).
APPEND VALUE #( %tky = agency-%tky
%state_area = validate_dialling_code
%msg = NEW /dmo/zz_cx_agency_country( textid = /dmo/zz_cx_agency_country=>combination_invalid )
%element-PhoneNumber = if_abap_behv=>mk-on )
TO reported-/DMO/Agency.
ENDIF.
ENDLOOP.
ENDMETHOD.
实施确定 determineCountryCode
读取要处理的所有实例的字段
PhoneNumber和CountryCode及其键值,并将结果存储在内部表agencies中。从内部表
agencies中删除已具有国家代码的所有实例。这样可以防止不必要的执行以及确定determineCountryCode和determineDiallingCode之间的无限循环。在原始 BO 的接口上,使用 EML 更新的派生类型声明名为
agencies_to_update的表。将内部表
agencies中所有实例的%tky组件内容添加到表agencies_to_update,其电话号码以查找表中的一个数字开头countries。从查找表中添加相应的国家/地区代码。使用内部表
agencies_to_update执行 EML 更新。METHOD determineCountryCode. READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE ENTITY /DMO/Agency FIELDS ( PhoneNumber CountryCode ) WITH CORRESPONDING #( keys ) RESULT DATA(agencies). DELETE agencies WHERE CountryCode IS NOT INITIAL. DATA: agencies_to_update TYPE TABLE FOR UPDATE /dmo/i_agencytp. LOOP AT countries INTO DATA(country). DATA(country_with_00) = country-number. REPLACE FIRST OCCURRENCE OF '+' IN country_with_00 WITH '00'. LOOP AT agencies INTO DATA(agency) WHERE PhoneNumber CP country-number && '*' OR PhoneNumber CP country_with_00 && '*'. APPEND VALUE #( %tky = agency-%tky countrycode = country-code ) TO agencies_to_update. ENDLOOP. ENDLOOP. MODIFY ENTITIES OF /dmo/i_agencytp IN LOCAL MODE ENTITY /DMO/Agency UPDATE FIELDS ( countrycode ) WITH agencies_to_update REPORTED DATA(reported_modify). ENDMETHOD.
实施确定 determineDiallingCode
读取要处理的所有实例的字段
PhoneNumber和CountryCode及其键值,并将结果存储在内部表agencies中。从内部表
agencies中删除已具有电话号码的所有实例。这样可以防止不必要的执行以及确定determineDiallingCode和determineCountryCode之间的无限循环。在原始 BO 的接口上,使用 EML 更新的派生类型声明名为
agencies_to_update的表。将内部表
agencies中所有实例的%tky组件内容添加到国家agencies_to_update/地区代码与查找表中的国家/地区代码之一相匹配的表countries。从查找表中添加相应的电话号码。使用内部表
agencies_to_update执行 EML 更新。METHOD determineDiallingCode. READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE ENTITY /DMO/Agency FIELDS ( PhoneNumber CountryCode ) WITH CORRESPONDING #( keys ) RESULT DATA(agencies). DELETE agencies WHERE PhoneNumber IS NOT INITIAL. DATA: agencies_to_update TYPE TABLE FOR UPDATE /dmo/i_agencytp. LOOP AT agencies INTO DATA(agency). DATA(PhoneNumber) = VALUE #( countries[ code = agency-countrycode ]-number OPTIONAL ) . IF PhoneNumber IS NOT INITIAL. APPEND VALUE #( %tky = agency-%tky phonenumber = PhoneNumber ) TO agencies_to_update. ENDIF. ENDLOOP. MODIFY ENTITIES OF /dmo/i_agencytp IN LOCAL MODE ENTITY /DMO/Agency UPDATE FIELDS ( PhoneNumber ) WITH agencies_to_update REPORTED DATA(reported_modify). ENDMETHOD.
实施操作 createFromTemplate
读取所有已提供实例的
CountryCode、PostalCode、City和Street字段的值。使用业务对象接口 /DMO/I_AgencyTP 上的创建操作的派生类型声明名为
agencies_to_create的内部表。将所有读取代理实例附加到表
agencies_to_create。对于agencies_to_create中的每个实例,从读取结果中分配 %cid,并将草稿标识分别设置为if_abap_behv=>mk-on。最后,使用准备的内部表 agencies_to_create 创建实例。将 EML
CREATE语句的映射响应转发到工厂操作的映射响应。METHOD createFromTemplate. READ ENTITIES OF /DMO/I_AgencyTP IN LOCAL MODE ENTITY /DMO/Agency FIELDS ( CountryCode PostalCode City Street ) WITH CORRESPONDING #( keys ) RESULT DATA(agencies). DATA: agencies_to_create TYPE TABLE FOR CREATE /DMO/I_AgencyTP. LOOP AT keys INTO DATA(key). READ TABLE agencies INTO DATA(agency) WITH KEY id COMPONENTS %tky = key-%tky. IF sy-subrc EQ 0. APPEND CORRESPONDING #( agency EXCEPT agencyid ) TO agencies_to_create ASSIGNING FIELD-SYMBOL(<agency_to_create>). <agency_to_create>-%cid = key-%cid. <agency_to_create>-%is_draft = if_abap_behv=>mk-on. "The action always creates draft instances ELSE. APPEND CORRESPONDING #( key MAPPING %fail = DEFAULT VALUE #( cause = if_abap_behv=>cause-not_found ) ) TO failed-/dmo/agency. ENDIF. ENDLOOP. MODIFY ENTITIES OF /DMO/I_AgencyTP IN LOCAL MODE ENTITY /DMO/Agency CREATE FIELDS ( CountryCode PostalCode City Street ) WITH agencies_to_create MAPPED mapped. ENDMETHOD.
结果
您已实施扩展的行为。现在,您可以按照 公开 UI 使用的操作扩展 章节中所述公开操作供 UI 使用。
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 定义扩展行为 · 公开操作扩展供 UI 使用 →