实施节点扩展的行为

ABAP RESTful 应用程序编程模型 › 扩展 › RAP 扩展 › 开发 RAP 扩展 › 开发节点扩展 › 实施节点扩展的行为

在本章中,实施上一章中为节点定义的行为。

行为扩展中定义的行为的实施遵循与为原始业务对象定义的行为实施相同的方法。不需要与可扩展性相关的特殊类语法。但是,在通过 EML 从扩展中访问原始业务对象时存在差异。

备注

接口是业务对象的合并消耗点,每个使用者都需要使用该消耗点。这也适用于在其扩展中通过 EML 访问原始业务对象的扩展器。这就是行为扩展实施中的 EML 语句必须始终通过其接口寻址原始业务对象的原因。

如果在行为扩展的 EML 语句中使用关键字 IN LOCAL MODE,则仅绕过此扩展的功能控件和权限实施。此类语句不会绕过原始业务对象的功能控制和权限实施。

以下部分描述了实施扩展行为所需的步骤。

实施方法 get_instance_features

读取所有需要验证的审核实例的审核人。

为具有现有用户的所有审核人启用更新和删除操作。

METHOD get_instance_features.
    READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
      ENTITY /dmo/zz_review
        FIELDS ( reviewer )
        WITH CORRESPONDING #( keys )
        RESULT DATA(reviews)
      FAILED failed.

    result = VALUE #(
        FOR review IN reviews
        LET enabled = COND #( WHEN review-reviewer = cl_abap_context_info=>get_user_technical_name( )
                                THEN if_abap_behv=>fc-o-enabled
                                ELSE if_abap_behv=>fc-o-disabled ) IN
        (
          %tky = review-%tky
          %update = enabled
          %delete = enabled
        )
      ).
  ENDMETHOD.

实施方法 reviewWasHelpful

读取执行操作的审核实例的所有字段。

在内部表中为每个审核实例将有用的投票数以及总投票数增加 1,并将实例附加到操作的结果表中。

使用更新的内部表,更新相应实例的有用投票数和总投票数。

METHOD reviewwashelpful.
    READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
      ENTITY /dmo/zz_review
        ALL FIELDS WITH CORRESPONDING #( keys )
        RESULT DATA(reviews)
        FAILED failed.

    LOOP AT reviews ASSIGNING FIELD-SYMBOL(<review>).
      <review>-helpfulcount += 1.
      <review>-helpfultotal += 1.

      APPEND VALUE #(
          %tky   = <review>-%tky
          %param = CORRESPONDING #( <review> )
        ) TO result.
    ENDLOOP.

    MODIFY ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
      ENTITY /dmo/zz_review
        UPDATE FIELDS ( helpfulcount helpfultotal )
          WITH CORRESPONDING #( reviews ).
  ENDMETHOD.

实施方法 reviewWasNotHelpful

读取执行操作的审核实例的所有字段。

在内部表中将每个审核实例的总投票数增加 1,并将实例附加到操作的结果表。

使用更新的内部表更新相应实例的总投票数。

METHOD reviewwasnothelpful.
    READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
      ENTITY /dmo/zz_review
        ALL FIELDS WITH CORRESPONDING #( keys )
        RESULT DATA(reviews)
        FAILED failed.

    LOOP AT reviews ASSIGNING FIELD-SYMBOL(<review>).
      <review>-helpfultotal += 1.

      APPEND VALUE #(
          %tky   = <review>-%tky
          %param = CORRESPONDING #( <review> )
        ) TO result.
    ENDLOOP.

    MODIFY ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
      ENTITY /dmo/zz_review
        UPDATE FIELDS ( helpfultotal )
          WITH CORRESPONDING #( reviews ).
  ENDMETHOD.

实施方法 ratingInRange

读取所有待验证审核实例的评级,及其相应代理实例的键值。

对于每个读取审核实例,清除状态区域。如果审核实例的评级高于 5 或低于 1,则将消息附加到标识受影响审核和相应代理实例的报告结构。

METHOD ratinginrange.
    READ ENTITIES OF /dmo/i_agencytp IN LOCAL MODE
      ENTITY /dmo/zz_review
        FIELDS ( rating )
        WITH CORRESPONDING #( keys )
        RESULT DATA(reviews)
      ENTITY /dmo/zz_review BY \_agency
        FROM CORRESPONDING #( keys )
        LINK DATA(agency_links).

    LOOP AT reviews INTO DATA(review).
      APPEND VALUE #(
          %tky        = review-%tky
          %state_area = rating_in_range
        ) TO reported-/dmo/zz_review.

      IF review-rating > 5 OR review-rating < 1.
        APPEND VALUE #(
            %tky              = review-%tky
            %state_area       = rating_in_range
            %msg              = NEW /dmo/zz_cx_agency_review( /dmo/zz_cx_agency_review=>rating_invalid )
            %element-rating   = if_abap_behv=>mk-on
            %path-/DMO/Agency-%tky = VALUE #( agency_links[ KEY draft  source-%tky = review-%tky ]-target-%tky OPTIONAL )
          ) TO reported-/dmo/zz_review.
        APPEND VALUE #( %tky = review-%tky ) TO failed-/dmo/zz_review.
      ENDIF.
    ENDLOOP.
  ENDMETHOD.

实施方法 adjust_numbers

仅当审阅节点的映射响应不为空时才执行延迟编号 - 换句话说,如果存在需要密钥的审阅实例。

将审核的 mapped 响应中包含的所有不同代理标识存储在名为 agencies 的内部表中。如果此内部表中没有代理标识,则终止执行。

创建一个名为 max_reviews 的内部表,该表包含 /dmo/zz_agn_reva 表中每个代理标识的最高审核标识。 agencies

对于审核节点的映射响应中的每个不同代理标识,将最高审核标识存储在变量 max_review_id 中。对于具有当前代理标识的每个审核,分配新的审核标识。新审核标识通过将变量 max_review_id 递增 1 来计算。

METHOD adjust_numbers.
    TYPES: t_mapped_review TYPE STRUCTURE FOR MAPPED LATE /dmo/zz_i_agency_reviewtp.
    DATA: agencies TYPE STANDARD TABLE OF /dmo/agency_id WITH KEY table_line.
    FIELD-SYMBOLS: <mapped_review> TYPE t_mapped_review.

    CHECK mapped-/dmo/zz_review IS NOT INITIAL.

    LOOP AT mapped-/dmo/zz_review ASSIGNING <mapped_review> GROUP BY <mapped_review>-%tmp-agencyid.
      APPEND <mapped_review>-%tmp-agencyid TO agencies.
    ENDLOOP.

    ASSERT agencies IS NOT INITIAL.

    SELECT
      FROM /dmo/zz_agn_reva  AS db
      JOIN @agencies         AS itab
        ON db~agency_id = itab~table_line
      FIELDS DISTINCT
        db~agency_id,
        MAX( db~review_id ) AS max_review_id
      GROUP BY db~agency_id
      INTO TABLE @DATA(max_reviews).

    LOOP AT mapped-/dmo/zz_review INTO DATA(mapped_review_group) GROUP BY mapped_review_group-%tmp-agencyid.
      DATA(max_review_id) = VALUE #( max_reviews[ agency_id = mapped_review_group-%tmp-agencyid ]-max_review_id OPTIONAL ).
      LOOP AT mapped-/dmo/zz_review ASSIGNING <mapped_review> WHERE %tmp-agencyid = mapped_review_group-%tmp-agencyid.
        <mapped_review>-agencyid = <mapped_review>-%tmp-agencyid.
        max_review_id += 1.
        <mapped_review>-reviewid = max_review_id.
      ENDLOOP.
    ENDLOOP.
  ENDMETHOD.

结果

您已实施扩展节点的行为。现在,您可以使用扩展节点 扩展原始业务对象的服务定义,以将其提供给服务使用,请参阅在服务公开中包含扩展节点。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 扩展节点扩展的行为 · 在服务公开中包括扩展节点 →