补充场景:细化测试类结构
ABAP RESTful 应用程序编程模型 › 测试 › 单元测试 › 为行为实施开发单元测试 › 为补充参考场景开发测试类 › 补充场景:细化测试类结构
现在您已创建基本测试类结构,可以通过定义提供所需测试配置的基本测试属性、测试关系、变量和固定设备方法来细化此结构。定义的测试类构成了测试方法的基础,将在下一章中实施这些测试方法。
本主题涵盖使用 RAP BO 测试双重框架的单元测试的特定测试类结构。有关 RAP 测试类结构的常规信息,请参阅基本测试类结构。
测试类定义
测试类的定义部分包含基本元信息、参考变量和所用方法的声明。
分配测试属性
由于测试方法的大小相对较小,因此测试代码的执行时间不应超过 5 秒。因此,您可以使用 DURATION SHORT。根据相应的运行模式和运行时监控器,超过所选执行时间可能会影响测试结果。
由于您不会通过单元测试更改持久数据或系统设置,因此可以使用风险级别威胁。如果所选风险级别高于系统中允许的风险级别,则不会执行测试。
CLASS ltcl_tdf_buffer DEFINITION FINAL FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS.
指定测试关系
您将为业务对象投影 /DMO/C_SUPPLEMENT 开发单元测试。通过指定与此行为定义的测试关系,您可以通过上下文菜单直接运行单元测试。
"! @testing BDEF:/DMO/C_SUPPLEMENT
CLASS ltcl_tdf_buffer DEFINITION FINAL FOR TESTING
...
声明类组件
首先,使用 RAP BO 测试双重框架为要隔离的业务对象名称定义常量。
由于您将使用 RAP BO Test Double Framework 来隔离由 EML 语句产生的相关性,因此需要声明相应接口的参考变量:
定义要在固定设备方法中使用的静态变量,并使用接口 if_botd_txbufdbl_bo_test_env 键入。此接口的框架实施用于创建允许访问和维护 RAP 业务对象测试双倍的环境。接下来,为设置和拆卸方法定义实例变量,并使用接口 if_botd_txbufdbl_test_double 键入该变量。此变量将保留对 RAP BO 测试双重本身的引用。
此外,使用相应的派生类型定义投影层和基础层中已映射、失败和已报告响应的结构。
PRIVATE SECTION.
CONSTANTS:
cv_i_bdef_name TYPE abp_root_entity_name VALUE '/DMO/I_Supplement'
CLASS-DATA:
environment TYPE REF TO if_botd_txbufdbl_bo_test_env.
DATA:
double_supplement TYPE REF TO if_botd_txbufdbl_test_double.
DATA:
mapped TYPE RESPONSE FOR MAPPED EARLY /dmo/c_supplement,
failed TYPE RESPONSE FOR FAILED EARLY /dmo/c_supplement,
reported TYPE RESPONSE FOR REPORTED EARLY /dmo/c_supplement,
i_mapped TYPE RESPONSE FOR MAPPED EARLY /dmo/i_supplement,
i_failed TYPE RESPONSE FOR FAILED EARLY /dmo/i_supplement,
i_reported TYPE RESPONSE FOR REPORTED EARLY /dmo/i_supplement.
备注
在此示例中,使用 RAP 业务对象测试双重框架的事务缓冲区双重变式。此变式提供 READ 和 MODIFY 操作的通用模拟实施,以及这些操作要使用的双倍事务缓冲区。
如果要为提供的输入配置特定 EML 输出,则需要使用具有模拟 EML 响应的框架变式。
声明固定设备和测试方法
除了声明测试方法外,还声明固定设备方法。固定设备方法用于设置和拆卸测试环境,为每个执行的测试生成唯一的测试行为。
展开以下代码示例以查看源代码。
示例代码
CLASS-METHODS:
class_setup,
class_teardown.
METHODS:
setup,
teardown.
METHODS:
supplement_create FOR TESTING RAISING cx_static_check,
supplement_create_text_update FOR TESTING RAISING cx_static_check,
supplement_update_text_create FOR TESTING RAISING cx_static_check,
supplement_update_text_update FOR TESTING RAISING cx_static_check,
text_create FOR TESTING RAISING cx_static_check,
text_update FOR TESTING RAISING cx_static_check,
update_with_invalid_keys FOR TESTING RAISING cx_static_check,
update_invalid_keys_descr FOR TESTING RAISING cx_static_check.
测试类实施
本部分介绍固定设备方法的实施,这些固定设备方法指定测试方法使用的测试配置。
实施方法 class_setup
准备 RAP BO 测试双框架环境的配置:提供要加倍的业务对象的根实体名称,并为此测试双重启用草稿处理。使用此配置创建框架环境。
METHOD class_setup.
DATA(env_config) = cl_botd_txbufdbl_bo_test_env=>prepare_environment_config(
)->set_bdef_dependencies( VALUE #( ( cv_i_bdef_name ) )
)->handle_draft( VALUE #( ( cv_i_bdef_name ) ) ).
environment = cl_botd_txbufdbl_bo_test_env=>create( env_config ).
ENDMETHOD.
实施方法 setup
清除 RAP BO Test Double Framework 环境创建的所有双倍的配置。
从框架环境中获取业务对象的测试双精度,并将对业务对象的参考分配到参考变量 double_supplement。
在测试中,需要创建补充实例,以触发要测试的增强方法。在自然业务对象环境中,这些实例的主键将通过早期编号提供。但是,由于早期编号逻辑是由 RAP BO 测试双框架隔离的行为的一部分,因此需要自己为补充实例提供主键。但是,无法使用 MODIFY CREATE 语句提供此补充标识,因为静态功能控制信息(例如字段补充标识的只读属性)未被 RAP 业务对象测试双重框架隔离。为了仍为实例提供补充标识,需要实施字段处理器,该处理器负责要在事务缓冲区双倍创建的实例的补充标识分配。将此处理程序的类命名为 ltd_fields_handler 并将其设置为业务对象测试双重的附加行为。您将在下一部分中实施处理器类。
METHOD setup.
environment->clear_doubles( ).
double_supplement = environment->get_test_double( cv_i_bdef_name ).
double_supplement->configure_additional_behavior( )->set_fields_handler( fields_handler = NEW ltd_fields_handler( ) ).
ENDMETHOD.
定义字段处理器类 ltd_fields_handler
您需要能够在另一个类中实例化处理器类,因此定义类选项 CREATE PUBLIC。
为 RAP BO 测试字段提供附加行为的处理器类需要双重实施接口 if_botd_bufdbl_fields_handler。在公共部分指定此接口。
声明类型为 /dmo/supplement_id 且值为 0 的实例变量。
CLASS ltd_fields_handler DEFINITION CREATE PUBLIC.
PUBLIC SECTION.
INTERFACES: if_botd_bufdbl_fields_handler.
PROTECTED SECTION.
PRIVATE SECTION.
DATA:
max_supplement_id TYPE /dmo/supplement_id VALUE 0.
ENDCLASS.
实施字段处理器类 ltd_fields_handler
实施接口 set_readonly_fields 的方法 if_botd_bufdbl_fields_handler,如下所示:
对于实体 /DMO/I_SUPPLEMENT 的创建操作,将传入实例分配到使用该实体创建操作的派生类型键入的字段符号。
对于字段符号引用的表中的每个代理实例,将补充标识数增加 1,并将此编号分配到实例的字段 supplementid。
CLASS ltd_fields_handler IMPLEMENTATION.
METHOD if_botd_bufdbl_fields_handler~set_readonly_fields.
CASE entity_name.
WHEN '/DMO/I_SUPPLEMENT'.
CASE operation.
WHEN if_abap_behv=>op-m-create.
TYPES: ty_create_instances TYPE TABLE FOR CREATE /dmo/i_supplement.
FIELD-SYMBOLS: <create_instances> TYPE ty_create_instances.
ASSIGN instances TO <create_instances>.
LOOP AT <create_instances> ASSIGNING FIELD-SYMBOL(<instance>).
max_supplement_id += 1.
<instance>-supplementid = max_supplement_id.
ENDLOOP.
ENDCASE.
ENDCASE.
ENDMETHOD.
ENDCLASS.
实施方法 teardown
从事务缓冲区双精度中清除业务对象测试的数据。
METHOD teardown.
double_supplement->clear_double( ).
ENDMETHOD.
实施方法 class_teardown
拆卸 RAP BO Test Double Framework 环境。
METHOD class_teardown.
environment->destroy( ).
ENDMETHOD.
结果测试类
遵循上述步骤后,您的测试类如下所示,并准备好实施测试方法:
展开以下代码示例以查看测试类 ltcl_tdf_buffer 的源代码。
示例代码
CLASS ltd_fields_handler DEFINITION CREATE PUBLIC.
PUBLIC SECTION.
INTERFACES: if_botd_bufdbl_fields_handler.
PROTECTED SECTION.
PRIVATE SECTION.
DATA:
max_supplement_id TYPE /dmo/supplement_id VALUE 0.
ENDCLASS.
CLASS ltd_fields_handler IMPLEMENTATION.
METHOD if_botd_bufdbl_fields_handler~set_readonly_fields.
CASE entity_name.
WHEN '/DMO/I_SUPPLEMENT'.
CASE operation.
WHEN if_abap_behv=>op-m-create.
TYPES: ty_create_instances TYPE TABLE FOR CREATE /dmo/i_supplement.
FIELD-SYMBOLS: <create_instances> TYPE ty_create_instances.
ASSIGN instances TO <create_instances>.
LOOP AT <create_instances> ASSIGNING FIELD-SYMBOL(<instance>).
max_supplement_id += 1.
<instance>-supplementid = max_supplement_id.
ENDLOOP.
ENDCASE.
ENDCASE.
ENDMETHOD.
ENDCLASS.
"! @testing BDEF:/DMO/C_SUPPLEMENT
CLASS ltcl_tdf_buffer DEFINITION FINAL FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS.
PRIVATE SECTION.
CONSTANTS:
cv_i_bdef_name TYPE abp_root_entity_name VALUE '/DMO/I_Supplement'
CLASS-DATA:
environment TYPE REF TO if_botd_txbufdbl_bo_test_env.
DATA:
double_supplement TYPE REF TO if_botd_txbufdbl_test_double.
DATA:
mapped TYPE RESPONSE FOR MAPPED EARLY /dmo/c_supplement,
failed TYPE RESPONSE FOR FAILED EARLY /dmo/c_supplement,
reported TYPE RESPONSE FOR REPORTED EARLY /dmo/c_supplement,
i_mapped TYPE RESPONSE FOR MAPPED EARLY /dmo/i_supplement,
i_failed TYPE RESPONSE FOR FAILED EARLY /dmo/i_supplement,
i_reported TYPE RESPONSE FOR REPORTED EARLY /dmo/i_supplement.
CLASS-METHODS:
class_setup,
class_teardown.
METHODS:
setup,
teardown.
METHODS:
supplement_create FOR TESTING RAISING cx_static_check,
supplement_create_text_update FOR TESTING RAISING cx_static_check,
supplement_update_text_create FOR TESTING RAISING cx_static_check,
supplement_update_text_update FOR TESTING RAISING cx_static_check,
text_create FOR TESTING RAISING cx_static_check,
text_update FOR TESTING RAISING cx_static_check,
update_with_invalid_keys FOR TESTING RAISING cx_static_check,
update_invalid_keys_descr FOR TESTING RAISING cx_static_check.
ENDCLASS.
CLASS ltcl_tdf_buffer IMPLEMENTATION.
METHOD class_setup.
DATA(env_config) = cl_botd_txbufdbl_bo_test_env=>prepare_environment_config(
)->set_bdef_dependencies( VALUE #( ( cv_i_bdef_name ) )
)->handle_draft( VALUE #( ( cv_i_bdef_name ) ) ).
environment = cl_botd_txbufdbl_bo_test_env=>create( env_config ).
ENDMETHOD.
METHOD class_teardown.
environment->destroy( ).
ENDMETHOD.
METHOD setup.
environment->clear_doubles( ).
double_supplement = environment->get_test_double( cv_i_bdef_name ).
double_supplement->configure_additional_behavior( )->set_fields_handler( fields_handler = NEW ltd_fields_handler( ) ).
ENDMETHOD.
METHOD teardown.
double_supplement->clear_double( ).
ENDMETHOD.
METHOD supplement_create.
ENDMETHOD.
METHOD supplement_create_text_update.
ENDMETHOD.
METHOD supplement_update_text_create.
ENDMETHOD.
METHOD supplement_update_text_update.
ENDMETHOD.
METHOD text_create.
ENDMETHOD.
METHOD text_update.
ENDMETHOD.
METHOD update_with_invalid_keys.
ENDMETHOD.
METHOD update_invalid_keys_descr.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← 补充场景:创建测试类 · 补充场景:实施测试方法 →