EML 测试:细化测试类结构
ABAP RESTful 应用程序编程模型 › 测试 › 集成测试 › EML 集成测试 › EML 测试:细化测试类结构
现在您已创建基本测试类结构,可以通过定义提供所需测试配置的基本测试属性、测试关系、变量和固定设备方法来细化此结构。定义的测试类构成了测试方法的基础,将在接下来的章节中实施这些测试方法。
本主题涵盖托管航班参考场景的特定集成测试类结构。有关 RAP 测试类结构的常规信息,请参阅基本测试类结构。
测试类定义
测试类的定义部分包含基本元信息、参考变量以及固定设备和测试方法的声明。
分配测试属性
由于测试方法的执行预计持续时间不会超过 5 秒,因此可以使用 DURATION SHORT。根据相应的运行模式和运行时监控器,超过所选执行时间可能会影响测试结果。
由于您不会通过单元测试更改持久数据或系统设置,因此可以使用 RISK LEVEL HARMLESS。如果所选风险级别高于系统中允许的风险级别,则不会执行测试。
CLASS /DMO/TC_TRAVEL_M DEFINITION
FOR TESTING
DURATION SHORT
RISK LEVEL HARMLESS
指定测试关系
您将为业务对象 /DMO/I_TRAVEL_M 开发集成测试。通过指定与此业务对象的测试关系,您可以通过业务对象的行为定义的上下文菜单直接运行集成测试。
"! @testing BDEF:/DMO/I_TRAVEL_M
CLASS /DMO/TC_TRAVEL_M DEFINITION
声明类组件
由于您将使用 CDS 测试双框架和 SQL 测试双框架的接口来模拟测试数据,因此您需要在 CLASS-DATA 部分中声明这些接口的参考变量。
此外,使用航班参考场景中的相应类型声明开始日期和结束日期的变量。您将使用这些变量为要创建的差旅实例准备航班数据。
声明将用于存储相应模拟数据的两个代理和客户数据表。从航班参考场景中选择供应类型。
最后,声明用于每个实体级别的内容标识的常量。
PRIVATE SECTION.
CLASS-DATA:
cds_test_environment TYPE REF TO if_cds_test_environment,
sql_test_environment TYPE REF TO if_osql_test_environment,
begin_date TYPE /dmo/begin_date,
end_date TYPE /dmo/end_date,
agency_mock_data TYPE STANDARD TABLE OF /dmo/agency,
customer_mock_data TYPE STANDARD TABLE OF /dmo/customer.
CONSTANTS cid TYPE abp_behv_cid VALUE 'ROOT1'.
CONSTANTS cid_node TYPE abp_behv_cid VALUE 'NODE1'.
CONSTANTS cid_subnode TYPE abp_behv_cid VALUE 'SUBNODE1'.
声明固定设备和测试方法
声明所需的测试和固定设备方法。固定设备方法用于设置和拆卸测试环境,为每个执行的测试生成唯一的测试行为。
CLASS-METHODS:
class_setup,
class_teardown.
METHODS:
setup,
teardown,
create_validation_negative FOR TESTING RAISING cx_static_check,
create_validation_positive FOR TESTING RAISING cx_static_check,
cba_fc_negative FOR TESTING RAISING cx_static_check,
cba_fc_positive FOR TESTING RAISING cx_static_check,
deep_create_determination FOR TESTING RAISING cx_static_check,
create_action_fc_negative FOR TESTING RAISING cx_static_check,
create_action_fc_positive FOR TESTING RAISING cx_static_check,
create_additional_save FOR TESTING RAISING cx_static_check.
测试类实施
本部分介绍固定设备方法的实施,这些固定设备方法指定测试方法使用的测试配置。
实施方法 class_setup
使用示例内容填充表 agency_mock_data 和 customer_mock_data。
您的测试方法将包含通过 CDS 实体差旅、预订和预订补充访问实例数据的 EML 语句。为了让这些 EML 语句访问测试双数据库的数据而不是实际数据库表,现在需要使用 CDS 测试双层框架创建测试二倍。指定 CDS 视图 /DMO/I_TRAVEL_M、/DMO/I_BOOKING_M 和 /DMO/I_BOOKSUPPL_M 以确保基础数据库表翻倍。
测试的业务对象包含验证以及访问数据库表 /DMO/AGENCY、/DMO/CUSTOMER 和 /DMO/LOG_TRAVEL 的 OpenSQL 语句的附加保存实施。为了使这些 OpenSQL 语句访问测试双倍而不是实际数据库,还需要使用 SQL 测试双框架为这些数据库表创建测试替身。
最后,将代理和客户模拟数据插入到测试双倍中。对于模拟数据库表 /DMO/LOG_TRAVEL,不需要测试数据。
METHOD class_setup.
agency_mock_data = VALUE #( ( agency_id = '987654' name = 'Miles and More' ) ).
customer_mock_data = VALUE #( ( customer_id = '987653' last_name = 'Buchholm' ) ).
cds_test_environment = cl_cds_test_environment=>create_for_multiple_cds(
VALUE #(
( i_for_entity = '/DMO/I_TRAVEL_M' )
( i_for_entity = '/DMO/I_BOOKING_M' )
( i_for_entity = '/DMO/I_BOOKSUPPL_M' )
)
).
sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #(
( '/DMO/AGENCY' )
( '/DMO/CUSTOMER' )
( '/DMO/LOG_TRAVEL' )
) ) .
sql_test_environment->insert_test_data( agency_mock_data ).
sql_test_environment->insert_test_data( customer_mock_data ).
ENDMETHOD.
实施方法 setup
为确保您的测试方法不受其他测试方法数据的影响,请在每次测试方法执行之前清除 CDS 测试两倍的内容。
METHOD setup.
cds_test_environment->clear_doubles( ).
ENDMETHOD.
实施方法 teardown
为确保每次测试方法执行后为相关的 CDS 实体重置事务缓冲区,请在拆卸方法中使用 EML 语句 ROLLBACK ENTITIES。
METHOD teardown.
ROLLBACK ENTITIES.
ENDMETHOD.
实施方法 class_teardown
测试结束时,清除测试环境和创建的测试两倍。
METHOD class_teardown.
cds_test_environment->destroy( ).
sql_test_environment->destroy( ).
ENDMETHOD.
结果测试类
遵循上述步骤后,您的测试类应如下所示,并准备好实施测试方法:
展开以下代码示例以查看测试类 /DMO/TC_TRAVEL_M 的源代码。
示例代码
"! @testing BDEF:/DMO/I_TRAVEL_M
CLASS /dmo/tc_travel_m DEFINITION
FOR TESTING
RISK LEVEL HARMLESS
DURATION SHORT
PUBLIC
FINAL
CREATE PUBLIC .
PUBLIC SECTION.
PROTECTED SECTION.
PRIVATE SECTION.
CLASS-DATA:
cds_test_environment TYPE REF TO if_cds_test_environment,
sql_test_environment TYPE REF TO if_osql_test_environment,
begin_date TYPE /dmo/begin_date,
end_date TYPE /dmo/end_date,
agency_mock_data TYPE STANDARD TABLE OF /dmo/agency,
customer_mock_data TYPE STANDARD TABLE OF /dmo/customer.
CONSTANTS cid TYPE abp_behv_cid VALUE 'ROOT1'.
CONSTANTS cid_node TYPE abp_behv_cid VALUE 'NODE1'.
CONSTANTS cid_subnode TYPE abp_behv_cid VALUE 'SUBNODE1'.
CLASS-METHODS:
class_setup,
class_teardown.
METHODS:
setup,
teardown,
create_validation_negative FOR TESTING RAISING cx_static_check,
create_validation_positive FOR TESTING RAISING cx_static_check,
deep_create_determination FOR TESTING RAISING cx_static_check,
create_action_fc_negative FOR TESTING RAISING cx_static_check,
create_action_fc_positive FOR TESTING RAISING cx_static_check,
cba_fc_negative FOR TESTING RAISING cx_static_check,
cba_fc_positive FOR TESTING RAISING cx_static_check,
create_additional_save FOR TESTING RAISING cx_static_check.
ENDCLASS.
CLASS /dmo/tc_travel_m IMPLEMENTATION.
METHOD class_setup.
agency_mock_data = VALUE #( ( agency_id = '987654' name = 'Miles and More' ) ).
customer_mock_data = VALUE #( ( customer_id = '987653' last_name = 'Buchholm' ) ).
cds_test_environment = cl_cds_test_environment=>create_for_multiple_cds(
VALUE #(
( i_for_entity = '/DMO/I_TRAVEL_M' )
( i_for_entity = '/DMO/I_BOOKING_M' )
( i_for_entity = '/DMO/I_BOOKSUPPL_M' )
)
).
sql_test_environment = cl_osql_test_environment=>create( i_dependency_list = VALUE #(
( '/DMO/AGENCY' )
( '/DMO/CUSTOMER' )
( '/DMO/LOG_TRAVEL' )
) ) .
sql_test_environment->insert_test_data( agency_mock_data ).
sql_test_environment->insert_test_data( customer_mock_data ).
ENDMETHOD.
METHOD setup.
cds_test_environment->clear_doubles( ).
ENDMETHOD.
METHOD teardown.
ROLLBACK ENTITIES.
ENDMETHOD.
METHOD class_teardown.
cds_test_environment->destroy( ).
sql_test_environment->destroy( ).
ENDMETHOD.
METHOD create_validation_negative.
ENDMETHOD.
METHOD create_validation_positive.
ENDMETHOD.
METHOD deep_create_determination.
ENDMETHOD.
METHOD create_action_fc_negative.
ENDMETHOD.
METHOD create_action_fc_positive.
ENDMETHOD.
METHOD cba_fc_negative.
ENDMETHOD.
METHOD cba_fc_positive.
ENDMETHOD.
METHOD create_additional_save.
ENDMETHOD.
ENDCLASS.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← EML 测试:创建测试类 · EML 测试:实施测试方法 →