测试场景创建 + 附加保存
ABAP RESTful 应用程序编程模型 › 测试 › 集成测试 › EML 集成测试 › EML 测试:实施测试方法 › 测试场景创建 + 附加保存
对于执行的修改创建操作,此集成测试会检查附加保存实施是否正确记录使用的操作和更改的字段。
首先,测试方法填充开始日期和结束日期的变量。
接下来,该方法执行创建差旅实例的 EML 修改创建调用。为确保正确执行创建操作,将为航班日期以及代理和客户标识提供有效数据。
预期将正确执行创建操作。因此,该方法断言来自 EML 创建语句的 mapped 响应包含预期内容和差旅标识,并且 failed 和 reported 响应为空。
现在,测试方法使用 COMMIT ENTITIES 语句触发保存顺序,在此期间执行附加保存实施。
预期将正确执行保存顺序。因此,方法 断言提交操作的 failed 和 reported 响应为空。此外,系统字段 sy-subrc 应包含值 0,表示已成功执行提交。
最后,该方法断言附加保存实施使用的表 /dmo/log_travel 包含已用操作和已更改字段的预期日志条目。
展开以下代码示例以查看方法 create_additional_save 的源代码。
示例代码
METHOD create_additional_save.
begin_date = cl_abap_context_info=>get_system_date( ) + 10.
end_date = cl_abap_context_info=>get_system_date( ) + 30.
" Create a Travel
MODIFY ENTITIES OF /dmo/i_travel_m
ENTITY travel
CREATE FIELDS ( agency_id customer_id begin_date end_date description booking_fee currency_code overall_status ) WITH
VALUE #( ( %cid = cid
agency_id = agency_mock_data[ 1 ]-agency_id
customer_id = customer_mock_data[ 1 ]-customer_id
begin_date = begin_date
end_date = end_date
description = 'TestTravel 1'
booking_fee = '10.5'
currency_code = 'EUR'
overall_status = 'A' ) )
MAPPED DATA(mapped_create)
FAILED DATA(failed_create)
REPORTED DATA(reported_create).
" Travel was created successfully
cl_abap_unit_assert=>assert_equals( exp = 1 act = lines( mapped_create-travel ) ).
DATA(key_of_new_travel) = mapped_create-travel[ 1 ].
cl_abap_unit_assert=>assert_equals( exp = cid act = key_of_new_travel-%cid ).
cl_abap_unit_assert=>assert_not_initial( act = key_of_new_travel-travel_id ).
cl_abap_unit_assert=>assert_initial( failed_create ).
cl_abap_unit_assert=>assert_initial( reported_create ).
" Trigger additional save
COMMIT ENTITIES
RESPONSE OF /DMO/I_Travel_M
FAILED DATA(failed_commit)
REPORTED DATA(reported_commit).
cl_abap_unit_assert=>assert_subrc( exp = 0 ).
cl_abap_unit_assert=>assert_initial( act = failed_commit ).
cl_abap_unit_assert=>assert_initial( act = reported_commit ).
" Ensure that a create operation has been executed
SELECT changed_field_name FROM /dmo/log_travel WHERE changing_operation = 'CREATE' ORDER BY changed_field_name INTO TABLE @DATA(log_fields).
cl_abap_unit_assert=>assert_equals( act = lines( log_fields ) exp = 2 ).
cl_abap_unit_assert=>assert_equals( act = log_fields[ 1 ] exp = 'booking_fee' ).
cl_abap_unit_assert=>assert_equals( act = log_fields[ 2 ] exp = 'overall_status' ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译