开发者扩展实战工作坊(RAP630)

项目

内容

官方仓库

SAP-samples/abap-platform-rap630

业务场景

在 SAP S/4HANA Cloud Public Edition 上对标准业务对象进行开发者扩展(developer extensibility)

技术栈

ABAP Cloud、RAP 扩展、已发布 API(released APIs)、Clean Core 原则

对应课程

S4D426

对应路径

第 1 条 获取核心 ABAP 技能

为什么值得做:Clean Core 最难的部分不是概念本身,而是弄清哪些内容可以修改、哪些内容只能扩展。 这个工作坊用一整套练习划出了这条边界,是 S4D426 的官方配套材料。

动手要点:

  • 注意扩展点(extension point)与增强实现(enhancement implementation)的区别。

  • 留意哪些场景必须采用并行扩展(side-by-side),而不能做应用内扩展。

本页内容抓取自官方仓库 SAP-samples/abap-platform-rap630,共收录 16 篇官方文档(README 与 docs)。原仓库内容版权归 SAP SE,遵循其许可证。

RAP630 - 云 ERP 扩展

https://github.com/SAP-samples/abap-platform-rap630/tree/main

说明

本仓库收录了名为 RAP630 - Use ABAP Cloud for developer extensibility 的 RAP 动手工作坊材料,其中使用的是 Developer Extensibility(开发者扩展)。

按 SAP 的定义,开发者扩展基本上包含两类活动:

  1. 开发自定义代码,实现你自己的业务逻辑。

    在这里,你可以使用 SAP 为此目的发布的现有 API。

  2. 扩展现有的 RAP 业务对象,为其增加额外的业务功能。

    这类可扩展的 RAP 业务对象通常位于另一个软件组件中,也可能是 SAP 或 SAP 合作伙伴交付的现有可扩展 RAP BO。
    通过扩展现有 RAP 业务对象的功能,可以让它适配你的具体业务需求。

    SAP S/4HANA Cloud 的扩展选项

概述

本次课程向学员介绍 ABAP RESTful 应用编程模型(RAP),以及如何利用它来

  • 在 SAP BTP ABAP 环境中构建扩展(自己的代码),以及

  • 扩展现有的 RAP 业务对象。

📋参加本工作坊的前提条件

^返回页首

你需要在笔记本或 PC 上安装最新版本的 ABAP Development Tools for Eclipse(ADT),并拥有一个合适的 ABAP 系统*,以完成本工作坊的实践练习。
(*)受支持的 ABAP 系统为 SAP BTP ABAP Environment 和 SAP S/4HANA Cloud, Public Edition。
如需在本地部署(on-prem)系统上运行本工作坊,请使用 on-prem 分支。
必须将开源的 RAP Generator 导入相关系统。

在 SAP ABAP Environment Trial 系统中,已为你预先导入了 RAP Generator。

点击展开!

要完成本仓库中的练习,需要满足以下前提条件:

  1. 安装最新的 Eclipse 平台与最新的 ABAP Development Tools(ADT)插件

  2. 在 SAP BTP ABAP Environment Trial 上创建用户(请阅读下方的例外说明)

  3. 创建 ABAP Cloud 项目

⚠ 关于 SAP 主办活动的例外说明,例如“ABAP Developer Day”和“SAP CodeJam”:
→ 我们会为动手工作坊的参与者提供一个专用的 ABAP 系统,其中已预先生成好相关包。
→ 现场工作坊的系统访问信息将由讲师在课程期间提供。

解决方案代码

源 BO 的代码可在此仓库中找到: ZRAP630

而扩展项目的代码可在这里找到: ZRAP630_EXT

幻灯片

演示文稿

🛠 练习

^返回页首

练习

在 入门(Getting Started)一节中,你将了解完成本教程需要预先准备哪些内容。

开发者扩展的第一个方面是:如何使用 SAP 或 SAP 合作伙伴以 C1 合同发布的 RAP 业务对象,以便在 ABAP Cloud 开发中使用。

在 练习 1 中,你将学习如何利用已发布的 RAP 业务对象 I_BankTP。你将了解 ADT 中新增的向导,它让你无需编写一行代码,就能在已发布的 RAP 业务对象之上生成自定义 UI。还有一个附加(可选)任务:在类中调用同一个已发布的 RAP 业务对象,这展示了已发布的 RAP 业务对象同样可以用于应用程序作业(application job)。

开发者扩展的第二个方面是:扩展 SAP 或 SAP 合作伙伴交付的可扩展 RAP 业务对象。

在 练习 2 中,你将_扩展行为_(extend the behavior),对象是 入门 一节中生成的基础 RAP 业务对象。你将学习如何通过验证(validation)、确定(determination)和副作用(side effect)来扩展基础 RAP BO 的行为。

在 练习 3 中,你将继续_扩展数据模型_,为其添加新字段。

由于最新版本 2408 已经提供了 Extension Field Wizard(扩展字段向导),我们针对 ABAP 环境系统和本地部署系统(SAP S/4HANA 2023)准备了不同的操作脚本。

在 练习 4 中,你将继续_扩展行为_,为基础 RAP 业务对象添加一个动作(action)。由于动作只能通过扩展添加到那些本身就通过扩展添加的字段上,因此通过扩展添加动作必须在练习 3 之后进行。

那么我们就开始吧,请看 入门 一节。

然后你可以继续构建利用已发布 API 的自定义代码。

最后,你将学习如何扩展 RAP 业务对象。

  • 练习 2、3、4 - 扩展 RAP 业务对象(行为与数据模型)

在线帮助

https://help.sap.com/docs/abap-cloud/abap-rap/develop-rap-extensions

https://help.sap.com/docs/SAP_S4HANA_CLOUD/6aa39f1ac05441e5a23f484f31e477e7/1b345c53060846b091f55ea901e21ae7.html

下载与安装

包含本工作坊解决方案的包 ZRAP630_SOL 和 ZRAP630_SOL_EXT 可以通过 abapGit 下载到 SAP BTP, ABAP Environment 系统或 SAP S/4HANA Cloud, ABAP environment 系统中。

请注意,这些包已经安装在 SAP BTP, ABAP Environment Trial 系统中!
因此无需在 ABAP Environment trial 系统上再安装它们。

点击展开下载与安装步骤。

下载并安装基础 RAP 业务对象所在包的步骤见下文:

  1. 创建一个包 'ZRAP630_SOL',父包(superpackage)使用 'ZLOCAL'。

  2. 将该包与 RAP630 GitHub 仓库的 URL https://github.com/SAP-samples/abap-platform-rap630 关联。

  3. 使用分支 main。

  4. 拉取更改(Pull changes)。

  5. 使用批量激活(mass activation)激活第 3 步中导入的对象。

  6. 发布服务绑定 ZRAP630UI_SHOP_O4_SOL。

    完成上述步骤后,你可以继续下载扩展项目的解决方案包 ZRAP630_SOL_EXT。

    出于技术原因,这些内容存放在另一个 GitHub 仓库 abap-platform-rap630-ext 中,因此你需要从该仓库 'https://github.com/SAP-samples/abap-platform-rap630-ext' 下载源代码。

已知问题

如何获得支持

如果你发现缺陷或对内容有疑问,请在本仓库中创建 issue。

如需更多支持,请在 SAP Community 中提问。

参与贡献

如果你想贡献代码、提供修复或改进,请发送 pull request。出于法律原因,贡献者在向本项目首次提交 pull request 时需接受 DCO。这会在提交流程中自动完成。SAP 使用Linux 基金会的标准 DCO 文本。

行为准则

请阅读 SAP 开源行为准则。

许可证

Copyright (c) 2023-2026 SAP SE or an SAP affiliate company and abap-platform-rap630 contributors. All rights reserved. 本项目基于 Apache Software License 2.0 版授权,除非 LICENSE 文件中另有说明;除非符合许可证要求,否则你不得使用本项目的任何文件。

除非适用法律要求或书面同意,否则依据许可证分发的软件均按“原样”提供,不附带任何明示或暗示的保证或条件。具体授权条款与限制请参阅 LICENSE 文件。

入门

主页 - 云 ERP 扩展

共有三种方式:

  • 方式 1:在 SAP 活动上完成这些练习,我们会为你提供专用系统和专用的演示用户。

  • 方式 2:在共享的 ABAP trial 系统中自行完成这些练习。

  • 方式 3:在你自己的 SAP BTP ABAP 环境中自行完成这些练习。

方式 1 - SAP 主办的手把手工作坊(例如 SAP TechEd、SAP 用户组活动、SAP CodeJam 等)

点击展开练习说明

如果参加的是 SAP 主办的手把手课程,我们已为你准备好以下内容:

  • 两个练习包 ZRAP630_### 和 ZRAP630_###_EXT,以及

  • 一个可扩展的托管业务对象(BO),其中包含一个实体 Shop,带有通用的交易行为,即 CRUD:创建、读取、更新和删除。

  1. ⚠ 检查你的演示用户后缀 ###(例如 developer-###@abapcloud.sap)。

  2. 在“项目资源管理器”(Project Explorer)中右键单击 Favorite Packages,然后单击 Add Package...。
    输入 ZRAP630_###,并同时选中两个包,然后单击 OK。

方式 2 - 在 SAP BTP Trial 中自学

点击展开练习说明

如果你在 SAP BTP ABAP Trial 中完成练习,需要先启动一个辅助类,它会生成后续练习所需的必要对象。

你将生成:

  • 两个练习包,以及

  • 一个可扩展的托管业务对象(BO),其中包含一个实体 Shop,带有通用的交易行为,即 CRUD:创建、读取、更新和删除。

你将使用类 ZDMO_GEN_RAP630_SINGLE 生成两个包。

⚠️ 请注意,如果找不到这个类,你需要先按照“入门”一节的说明导入开源的 RAP Generator。

第一个包 ZRAP630_### 将包含一个可扩展的 RAP 业务对象,你会在练习 2 中扩展它。

第二个包 ZRAP630_###_EXT 用于存放你将在练习 1 和练习 2 中创建的对象。

  1. 右键单击 Favorite Objects,然后单击 Add Object。

  2. 搜索 ZDMO_GEN_RAP630_SINGLE,选中它,然后单击 OK。

  3. 右键单击 ZDMO_GEN_RAP630_SINGLE,选择 Run As > ABAP Application (Console) F9。

    通过 F9 运行

  4. 现在会创建你的包 ZRAP630_### 和 ZRAP630_###_EXT
    (其中后缀 ### 表示你的组号,包中会包含你所需的一切)。

    ⚠ 生成过程需要几分钟。
    ⚠ 因此请耐心等待,并留意 ABAP 控制台的输出。

    Console 选项卡的结果

  5. ⚠ 记下后缀 ###,后面会用到。

  6. 在“项目资源管理器”(Project Explorer)中右键单击 Favorite Packages,然后单击 Add Package...。
    输入 ZRAP630_###,并同时选中两个包,然后单击 OK。

    包

方式 3 - 在你自己的 SAP BTP ABAP 环境中自学

点击展开练习说明

小结

现在你已经生成了自己的可扩展 RAP 业务对象,可以继续学习 - 练习 1

练习 1:在既有技术栈上构建新应用(开发者扩展)

主页 - 云 ERP 扩展

⚠️ 请务必先完成 入门一节 中描述的步骤。在那里你将了解如何访问本次动手课程所需的包和仓库对象。

引言

在练习 1.1 中,你将基于已发布的 API I_BankTP 构建一个自定义 UI。这个应用可以让你创建银行。

作为附加(可选)的练习 1.2,你可以尝试在类中通过 EML 使用这个已发布的 API。

基于既有技术栈的新应用

我们首先演示如何搜索已发布的 RAP 业务对象。为此,我们会使用 ADT 中 Project Explorer 的 Released Objects 部分。

提醒:
不要忘记在下面的练习步骤中,把所有占位符 ### 替换成你的组号。
为此可以使用 ADT 的 Replace All 功能(Ctrl+F)。

组号

练习 1.1:为已发布的业务对象接口生成 UI

在练习 1.1 中,你将基于已发布的 API I_BankTP 构建一个自定义 UI。

点击展开!
  1. 在项目资源管理器中选择 Released Objects 树,然后选择节点 USE_IN_CLOUD_DEVELOPMENT。在这里需要依次打开文件夹 Core Data Services 和 Behavior Definitions,你可以在其中找到以 C1 合同发布的业务对象接口 I_BankTP。

    接口

  2. 右键单击接口 I_BankTP,选择 Generate ABAP Repository Objects。

    接口

  3. 选择 OData UI Service,然后单击 Next。

    生成器

  4. 通过 Browse 按钮选择包 ZRAP630_###_EXT,其中 ### 是生成器类选定的唯一 ID,然后单击 Next。

    生成器

  5. 生成器最后会显示 Configure Generator 屏幕。

    服务投影实体

    在 Artifacts Suffix 字段中输入你的组号 ###。

    这会把该后缀加到将要生成的仓库对象名称后面。你可以通过选择 Service Projection Entities、Service Projection Behavior、Service Definition 和 Service Binding 这些条目,查看生成器将要采用的名称。
    由于生成器会建议唯一的名称,我们保持建议值不变。

    单击 Next 继续。

  6. 向导会显示将要生成的仓库对象概览。单击 Next。

    eclipse

  7. 选择一个已有传输请求或新建一个,然后单击 Finish 开始生成仓库对象。

    eclipse

发布服务并测试应用

  1. 生成过程结束后,ADT 中会打开一个包含所生成服务绑定的新选项卡。单击 Publish 在本地发布服务绑定。在项目资源管理器中,你可以看到所有已生成的对象。

    结果

    结果

  2. 选择实体集 Bank,单击 Preview,或双击实体集 Bank。这会启动 SAP Fiori elements 预览。

    Fiori elements 预览

  3. 在应用预览中单击 Create 按钮,创建一家新银行。

    Fiori

  4. 在 Bank Country / Region 字段中输入值,例如 CZ,在 Bank Key 字段中输入值,例如 1234,然后单击 Continue。

    Fiori

  5. 随后会打开对象页,你需要为剩余的必填字段(例如 Bank Name)提供数据。

    Fiori

故障排查

点击展开!
  1. 当你的开发用户没有创建银行的权限时,会收到以下错误消息:You are not authorized to create bank data for country/region CZ.

    结果

  2. 为了找出缺少哪些授权,你可以查看 I_BANKTP 的 Knowledge Transfer Document(KTD)。你可以使用快捷键 Ctrl+Shift+A 打开它,也可以按下图所示在项目资源管理器中导航到它。

    结果

  3. 如你所见,业务对象 I_BankTP 会检查授权对象 F_BNKA_MAO 和 F_BNKA_INT。

    结果

    F_BNKA_INT

    F_BNKA_MAO

⚠️
该问题只能通过创建合适的 IAM 应用、把它分配给某个业务目录,最终再分配给一个新建或已有的角色,并将该角色分配给你的用户来解决。
在下一个(可选)练习中,我们会在把 BO 作为 API 调用时,演示一种变通办法,即如何以所谓的特权模式(privileged mode)调用该 API。

练习 1.2:在自定义应用中使用已发布的 RAP BO(可选)

^返回页首

另一个典型用例是:SAP S/4HANA 系统中的已发布 API 常被用在你自己编写的代码里,例如这些代码可能作为应用程序作业(application job)的一部分被调用。

这种情况下,运行该作业的用户可能没有相应的应用授权。

测试 EML 调用

点击展开!

在扩展包 ZRAP630_###_EXT 中创建一个类 类,以规避 EML 调用中的授权问题。

  1. 右键单击你的 ABAP 包 ZRAP630_###_EXT,在上下文菜单中选择 New > ABAP Class。

    包.

  2. 维护所需信息(### 是你的组号)。

    • 名称:zcl_test_abap_cloud_###

    • 描述:Test ABAP Cloud Governance

    单击 Add,选择接口 if_oo_adt_classrun,然后单击 OK。

    接着单击 Next >。

    包.

  3. 选择一个传输请求或新建一个,然后单击 Finish 创建该类。

  4. 把方法 if_oo_adt_classrun~main( ) 中的代码替换为以下代码片段。

    提示 你必须把 '####' 的值替换为只包含数字的字符串。

    代码说明:
    该代码利用了 EML 语句的 response 参数,该参数用于为 ABAP EML 语句指定响应参数,从而获取以下信息:

    • 失败情况,即无法处理的操作(FAILED failed_resp)

    • 键映射信息(MAPPED mapped_resp)

    • 返回的错误消息(REPORTED reported_resp)

  

   METHOD if_oo_adt_classrun~main.
    DATA create_bank    TYPE STRUCTURE FOR CREATE i_banktp.
    DATA bank_id_number TYPE i_banktp-BankInternalID VALUE '8035'.

    SELECT SINGLE *
      FROM I_Bank_2
*     WITH
*      PRIVILEGED ACCESS
      WHERE BankInternalID = @bank_id_number
      INTO @DATA(my_bank).

    IF sy-subrc = 0.
      out->write( |my new bank { my_bank-BankName } { my_bank-BankInternalID } already exists.| ).
      EXIT.
    ENDIF.

    create_bank = VALUE #( BankCountry         = 'ZW'
                           BankInternalID      = bank_id_number
                           LongBankName        = 'Bank name'
                           LongBankBranch      = 'Bank branch'
                           BankNumber          = bank_id_number
                           BankCategory        = ''
                           BankNetworkGrouping = ''
                           SWIFTCode           = 'SABMGB2LACP'
                           IsMarkedForDeletion = '' ).

    MODIFY ENTITIES OF i_banktp
*           PRIVILEGED
           ENTITY bank
           CREATE FIELDS ( bankcountry
                         bankinternalid
                         longbankname
                         longbankbranch
                         banknumber
                         bankcategory
                         banknetworkgrouping
                         swiftcode
                         IsMarkedForDeletion )
           WITH VALUE #( ( %cid                = 'cid1'
                           BankCountry         = create_bank-BankCountry
                           BankInternalID      = create_bank-BankInternalID
                           LongBankName        = create_bank-LongBankName
                           LongBankBranch      = create_bank-LongBankBranch
                           BankNumber          = create_bank-BankNumber
                           BankCategory        = create_bank-BankCategory
                           BankNetworkGrouping = create_bank-BankNetworkGrouping
                           SWIFTCode           = create_bank-SWIFTCode
                           IsMarkedForDeletion = create_bank-IsMarkedForDeletion ) )

           MAPPED DATA(mapped)
           REPORTED DATA(reported)
           " TODO: variable is assigned but never used (ABAP cleaner)
           FAILED DATA(failed).

    LOOP AT mapped-bank INTO DATA(mapped_success).
      out->write( |mapped key { mapped_success-%key-BankInternalID }|  ).
    ENDLOOP.

    LOOP AT reported-bank INTO DATA(reported_error_1).
      DATA(exc_create_bank) = cl_message_helper=>get_longtext_for_message( text = reported_error_1-%msg ).
      out->write( |error EML { exc_create_bank } |  ).
    ENDLOOP.

    IF reported-bank IS NOT INITIAL.
      EXIT.
    ENDIF.

    COMMIT ENTITIES
           RESPONSE OF i_banktp
           " TODO: variable is assigned but never used (ABAP cleaner)
           FAILED DATA(failed_commit)
           REPORTED DATA(reported_commit).

    LOOP AT reported_commit-bank INTO DATA(reported_error_2).
      DATA(exc_create_bank2) = cl_message_helper=>get_longtext_for_message( text = reported_error_2-%msg ).
      out->write( |error commit entities { exc_create_bank2 } |  ).
    ENDLOOP.

    IF reported_commit-bank IS NOT INITIAL.
      EXIT.
    ENDIF.

    COMMIT WORK.

    SELECT SINGLE *
      FROM I_Bank_2
*     WITH
*      PRIVILEGED ACCESS
      WHERE BankInternalID = @bank_id_number
      INTO @my_bank.

    IF sy-subrc = 0.
      out->write( |my new bank { my_bank-BankName } { my_bank-BankInternalID }| ).
    ELSE.
      out->write( |my new bank { my_bank-BankName } does not exist| ).
    ENDIF.
  ENDMETHOD.
  1. 按 Ctrl+F3 激活更改。

  2. 按 F9 运行测试类。

    你应当会收到类似下面的错误消息: error You are not authorized to create bank data for country/region ZW.

    这是因为你的用户只有创建以下国家/地区代码的银行的权限:

    测试类

测试 PRIVILEGED 调用

点击展开!
  1. 在 EML 调用中加入 PRIVILEGED

    当我们在 EML 调用中加入关键字 PRIVILEGED 后,对授权对象 F_BNKA_MAO 和 F_BNKA_INT 的授权检查基本上就会被跳过。只需取消源代码中 PRIVILEGED 语句的注释即可。

      
    MODIFY ENTITIES OF i_banktp
    PRIVILEGED
    ENTITY bank
    CREATE FIELDS ( bankcountry
                   bankinternalid
                   longbankname
                   ...
    

    现在按 F9 再次运行该类,你会发现新银行的创建似乎已经成功。

    但是,SELECT 语句却无法读取到刚创建的数据。

    点击了解关于 PRIVILEGED EML 访问的更多信息

    接下来我们查看 Bank RAP 业务对象的行为定义。为此,按 Ctrl+Shift+A 打开行为定义 R_BankTP。

    在源代码中(见下文)可以看到,BDEF R_BankTP 定义了两个所谓的授权上下文(authorization context):

    Own authorization context:列出 RAP BO 实现中使用的所有授权对象。
    NoCheckWhenPrivileged:列出具有特权访问权限的 RAP BO 使用方可以跳过的授权对象。

    managed with unmanaged save implementation in class bp_r_banktp unique;
    strict ( 2 );
    with draft;
    extensible
    {
      with additional save;
      with determinations on modify;
      with determinations on save;
      with validations on save;
    }
    
    with privileged mode disabling NoCheckWhenPrivileged;
    
    //NoCheckWhenPrivileged
    define authorization context NoCheckWhenPrivileged
    {
     'F_BNKA_MAO';
     'F_BNKA_INT';
     }
    
  2. 再次按 F9 运行你的类。

    你应当会收到类似下面的响应:

    mapped key ####
    my new bank  does not exist
    

    这意味着你现在可以创建新银行,但无法通过 SQL 读取数据。

  3. 在 ABAP SQL 语句中加入 WITH PRIVILEGED ACCESS

    与创建银行时强制跳过授权检查类似,也可以强制跳过底层 DCL 施加的授权检查。该 DCL 会针对授权对象 F_BNKA_MAO 和字段 BBANKS 执行检查,以控制数据的显示。

    打开该 DCL 并检查其源代码。

    为此请按 Ctrl+Shift+A,输入 I_Bank_2,搜索 DCL 对象。

    PRIVILEGED 1

    PRIVILEGED 1

    现在我们把类 zcl_test_abap_cloud_### 中的两条 ABAP SQL 语句都改一下,为它们加上关键字 WITH PRIVILEGED ACCESS:


    METHOD if_oo_adt_classrun~main.

    "...
       
    SELECT SINGLE *
      FROM I_Bank_2
      WITH
       PRIVILEGED ACCESS
      WHERE BankInternalID = @bank_id_number
      INTO @DATA(my_bank).

    "...

    SELECT SINGLE *
      FROM I_Bank_2
      WITH
       PRIVILEGED ACCESS
      WHERE BankInternalID = @bank_id_number
      INTO @my_bank.

     "...
       
       ENDMETHOD.

可以看到,数据现在已成功创建,并且也能被读取。

PRIVILEGED 1

其他潜在问题

I_BankTP RAP BO 会检查所提供的 SWIFT 代码是否与该地区的 ISO 代码匹配。

  • error ISO 代码 GB 与 SWIFT 代码 SABMGB2LACP 不匹配,对于国家/地区 US 来说不正确。诊断:SWIFT 代码的第 5 位和第 6 位与国家/地区 US 的 ISO 代码不对应。处理:检查你的输入。如有必要,请检查国家/地区 US 的 ISO 代码是否已正确定义。

当所提供的 ID 对应的银行已经存在时,你也会收到一条错误消息。

  • error 银行 CZ 8888 已存在。

小结

^返回页首

现在你已经了解如何在 ABAP Cloud 中利用已发布的 API I_BankTP,接下来可以继续下一个练习,在那里你将学习如何扩展可扩展的 RAP 业务对象 - 练习 2。

延伸阅读

^返回页首

点击展开!

系统中没有相关信息?--> 到 GitHub 上查找已发布 API 的信息

在为 S/4HANA 本地部署 或 S/4HANA 私有云版本 开发 ABAP 应用时,你会收到如下错误消息:“Use of is not permitted”。

但该错误消息并不会提示应该改用哪个 API 或对象。原因在于,本地部署系统中的后继对象信息不包含最新更新,而 SAP S/4HANA Cloud, ABAP Environment 系统或 SAP BTP, ABAP Environment 中的信息是更新的。

一个例子是表 BNK2。

作为开发者,你仍然希望查明应该改用哪些对象,并查看它们的文档。

  1. 查看 GitHub 仓库。

 该仓库包含 S/4HANA Cloud 的已发布 API 列表。此外,它还包含未发布的对象及其后继对象说明。所有对象都放在一个 JSON 文件中。该文件用作 ABAP 测试驾驶舱(ABAP Test Cockpit)检查“Usage of Released APIs (Cloudification Repository)”的内容。客户和合作伙伴可以用这项检查来分析现有自定义代码在所有 ECC 和 S/4HANA 版本中使用已发布和未发布 API 的情况。该检查在 SAP BTP, ABAP Environment 中可用。
 
 [S/4HANA Cloud - 用于 ATC 检查的已发布对象(Cloudification Repository)](https://github.com/SAP/abap-atc-cr-cv-s4hc)。
 
 当我们查看公开可用的 **csv 文件**时,可以获取表 BNKA 的后继对象列表。  

 MARA  

对人工来说 csv 文件很方便,但计算机更喜欢 json 文件。

JSON 示例文件链接

你可以继续下一个练习 - 练习 2.1。

练习 2 - 行为扩展

主页 - 云 ERP 扩展

在本练习中,我们将扩展一个可扩展 RAP BO 的行为。也就是说,我们会通过扩展为 RAP BO 的行为添加一个验证、一个确定以及副作用。

BDEF 扩展

练习 2.1 用验证扩展行为定义

完成这些步骤后,你将创建一个用于检查交货日期的验证。

🔵 点击展开!
  1. 右键单击行为定义 ZRAP630R_ShopTP_###,在上下文菜单中选择 New Behavior Extension。

    BDEF 扩展

  2. 在 Create Behavior Extension 对话框中输入以下值:

    ⚠⚠⚠ 注意
    请务必将包名从 ZRAP630_### 改为 ZRAP630_###_EXT。 默认情况下,该对话框会建议使用基础 RAP BO 所在的包。
    如果包由 SAP 交付,则会抛出错误消息,因为不允许在 SAP 命名空间中创建对象。 而这里我们希望把扩展构建在客户命名空间 Z 下的另一个包中。

    Package:⚠ZRAP630_###_EXT⚠
    Name:ZRAP630R_EXT_SHOPTP_###
    Description:Extension for ZRAP630R_ShopTP_###
    Behavior Definition:ZRAP630R_SHOPTP_###
    BO Interface:ZRAP630I_SHOPTP_###

    BDEF 扩展

  3. 选择一个传输请求,然后单击 Finish <

  4. 在行为定义中添加验证 zz_validateDeliverydate,让它响应 create; 和字段 DeliveryDate;。
    该验证还必须添加到 draft determine action Prepare 中。不要忘记激活更改。

    extension using interface zrap630i_shoptp_###
    implementation in class zbp_rap630r_ext_shoptp_### unique;
    

    extend behavior for Shop {
    validation zz_validateDeliverydate on save { create; field DeliveryDate; }

    extend draft determine action Prepare { validation zz_validateDeliveryDate; } }

  5. 单击行为扩展所建议的行为实现类名称 (1),按 Ctrl+1 启动内容辅助,单击建议的操作 (2),然后单击 Next (3)。

    BDEF 扩展

  6. 选择一个传输请求,然后单击 Finish。

  7. 这会打开行为实现类的编辑器。由于行为的实现是在本地类中完成的,你需要导航到 Local Types 选项卡。

    BDEF 扩展

  8. 把以下代码添加到实现该验证的本地类 lhc_shop 中。

       
    CLASS lhc_shop DEFINITION INHERITING FROM cl_abap_behavior_handler.   
    
      PUBLIC SECTION.  
        CONSTANTS state_area_check_delivery_date       TYPE string VALUE 'CHECK_DELIVERYDATE'       ##NO_TEXT.   
      PRIVATE SECTION.  
        METHODS zz_validateDeliverydate               FOR VALIDATE ON SAVE  
          IMPORTING keys FOR Shop~zz_validateDeliverydate.  
    
    ENDCLASS.  
    
    CLASS lhc_shop IMPLEMENTATION.  
    
      METHOD zz_validateDeliverydate.  
        READ ENTITIES OF ZRAP630i_ShopTP_### IN LOCAL MODE  
                ENTITY Shop  
                FIELDS ( DeliveryDate OverallStatus )  
                WITH CORRESPONDING #( keys )  
                RESULT DATA(onlineorders).  
    
        LOOP AT onlineorders INTO DATA(onlineorder).  
          APPEND VALUE #( %tky           = onlineorder-%tky  
                          %state_area    = state_area_check_delivery_date )  
                 TO reported-shop.  
          DATA(deliverydate)             =  onlineorder-DeliveryDate - cl_abap_context_info=>get_system_date(  ).  
          IF onlineorder-deliverydate IS INITIAL  .  
            APPEND VALUE #( %tky           = onlineorder-%tky ) TO failed-shop.  
            APPEND VALUE #( %tky           = onlineorder-%tky  
                            %state_area    = state_area_check_delivery_date  
                            %msg           = new_message_with_text(  
                                                severity = if_abap_behv_message=>severity-error  
                                                text     = 'delivery period cannot be initial'  
                           ) )  
                    TO reported-shop.  
          ENDIF.  
        ENDLOOP.  
      ENDMETHOD.  
    ENDCLASS.  
    
  9. 打开 RAP 基础 BO 的服务绑定 ZRAP630UI_SHOP_O4_###。

  10. 双击实体 Shop。这会启动 Shop RAP BO 的 ADT 预览。

    BDEF 扩展

  11. 在列表页上单击 Create 按钮。

  12. 打开 New : Shop 对象页,你需要在这里为新订单输入数据。

  13. 为 OrderedItem 字段选择一种产品,但不要选择 Delivery Date。

  14. 单击 Create。

  15. 此时应会抛出以下错误消息:

    BDEF 扩展

练习 2.2 用确定扩展行为定义

下一步,我们将在行为定义扩展中添加一个确定 ZZ_setOverallStatus。当用户修改字段 OrderedItem 的内容时,该确定会被执行。

🔵 点击展开!
  1. 在行为定义扩展 ZRAP630R_EXT_SHOPTP_### 中添加以下语句。

      determination ZZ_setOverallStatus on modify {  field OrderedItem; }
    

    这样你的 BDEF 代码现在应当如下所示:

       
    extension using interface zrap630i_shoptp_###
      implementation in class zbp_rap630r_ext_shoptp_### unique;
    

    extend behavior for Shop { validation zz_validateDeliverydate on save { create; field DeliveryDate; }

    extend draft determine action Prepare { validation zz_validateDeliveryDate; } determination ZZ_setOverallStatus on modify { field OrderedItem; } }

  2. 按 Ctrl+1 启动内容辅助,双击建议项,在行为实现类 zbp_rap630r_ext_shoptp_### 中添加相应代码。

  3. 将以下代码添加到方法 ZZ_setOverallStatus 的实现中。不要忘记把所有 ### 替换成你的组号。

    该代码首先使用 EML 发起读取请求,它使用框架提供的 RAP BO 键字段,读取所有受影响订单的数据。 在随后的循环语句中,检查价格是否超过某个阈值(1000 欧元),并根据价格决定订单是自动批准还是等待批准。 产品价格从 CDS 视图中读取,并相应地修改 RAP BO 的实例。

    METHOD ZZ_setOverallStatus.
    

    DATA update_bo TYPE TABLE FOR UPDATE ZRAP630i_ShopTP_###\Shop. DATA update_bo_line TYPE STRUCTURE FOR UPDATE ZRAP630i_ShopTP_###\Shop .

    READ ENTITIES OF ZRAP630I_ShopTP_### IN LOCAL MODE ENTITY Shop ALL FIELDS " ( OrderItemPrice OrderID ) WITH CORRESPONDING #( keys ) RESULT DATA(OnlineOrders) FAILED DATA(onlineorders_failed) REPORTED DATA(onlineorders_reported).

    DATA(product_value_help) = NEW zrap630_cl_vh_product_###( ). data(products) = product_value_help->get_products( ).

    LOOP AT onlineorders INTO DATA(onlineorder).

    update_bo_line-%tky = onlineorder-%tky.

    SELECT SINGLE * FROM @products as hugo WHERE Product = @onlineorder-OrderedItem INTO @data(product).

    update_bo_line-OrderItemPrice = product-Price. update_bo_line-CurrencyCode = product-Currency.

    IF product-Price > 1000. update_bo_line-OverallStatus = 'Awaiting approval'. ELSE. update_bo_line-OverallStatus = 'Automatically approved'. ENDIF.

    APPEND update_bo_line TO update_bo. ENDLOOP.

    MODIFY ENTITIES OF zrap630i_shoptp_### IN LOCAL MODE ENTITY Shop UPDATE FIELDS ( OverallStatus CurrencyCode OrderItemPrice ) WITH update_bo REPORTED DATA(update_reported).

    reported = CORRESPONDING #( DEEP update_reported ).

    ENDMETHOD.

  4. 当你收到错误消息时:
    The entity "SHOP" does not have a determination "ZZ_SETOVERALLSTATUS". 这可能是因为你还没有激活自己的 BDEF。

  5. 创建一个新实体并选择某个物料项,或者修改已有实体中的物料项,
    但不要保存更改,这样只会影响草稿。

    你会注意到,草稿中物料项名称的数据会更新,但价格不会在草稿中更新。 同样,如果产品价格超过 1000 欧元,草稿中的审批状态也不会改变。
    只有在保存数据后,数据才会在 UI 中更新。
    我们将在练习的下一步中通过副作用来改变这一点。

练习 2.3 用副作用扩展行为定义

现在你可以继续,通过行为定义扩展来添加副作用。

请注意:
只有可扩展的 RAP 业务对象在其行为投影或接口投影中提供了 use side effects 语句,才能通过副作用进行扩展。 由于 use side effects 语句本身无法通过扩展添加,因此这必须由开发人员预先考虑。

🔵 点击展开!
  1. 按 Ctrl+Shift+A 打开行为扩展 ZRAP630R_Ext_ShopTP_###。

  2. 添加以下代码片段:

    side effects { field OrderedItem affects field OrderItemPrice , field CurrencyCode  , field OverallStatus ; }

    把它加到行为扩展中确定语句的后面。

    你的 BDEF 扩展代码现在应当如下所示:

      extension using interface zrap630i_shoptp_###
        implementation in class zbp_rap630r_ext_shoptp_### unique;
    
    extend behavior for Shop
    

    { validation zz_validateDeliverydate on save { create; field DeliveryDate; } extend draft determine action Prepare { validation zz_validateDeliveryDate; } determination ZZ_setOverallStatus on modify { field OrderedItem; } side effects { field OrderedItem affects field OrderItemPrice , field CurrencyCode , field OverallStatus ; } }

  3. 创建一个新订单,指定交货日期,或者打开一个现有订单并切换到编辑模式,然后选择一个(新的)产品。

    你会注意到,在 SAP Fiori UI 中所选产品的数据会自动更新。
    如果价格从低于 1000 欧元变为超过 1000 欧元,或者反过来,审批状态也会随之改变。

    BDEF 扩展

小结

现在你已经扩展了基础 RAP 业务对象的行为。为此,你只需在 R 层为基础 BO 的 BDEF 创建一个扩展。

继续学习 - 练习 3 - 扩展数据模型

练习 2、3、4 - 扩展 RAP 业务对象

主页 - 云 ERP 扩展

在接下来的练习 2、3、4 中,你将扩展一个 RAP 业务对象。

扩展现有 SAP 应用的场景

由于多名开发者并行扩展同一个 RAP 业务对象可能会造成严重问题,因此每位参与者都使用自己专属的基础 RAP 业务对象。为方便起见,我们在“入门”一节中运行类 zdmo_gen_rap630_single,生成了一个可扩展 RAP BO。

除了普通 RAP 业务对象所需的仓库对象之外,启用了可扩展性的 RAP 业务对象还需要为每个实体额外提供三个仓库对象。

  • 扩展包含结构(Extension include)

  • 扩展包含视图(Extension include view)

  • 草稿查询视图(Draft query view)

启用了可扩展性的 RAP BO

你可以继续下一个练习 - 练习 2。

练习 3 - 扩展可扩展 RAP 基础业务对象的 CDS 数据模型

主页 - 云 ERP 扩展

引言

在上一练习中,我们通过添加确定、验证和副作用,扩展了基础 RAP BO 的_行为_。

现在我们来调整_CDS 数据模型_,也就是为 Shop 实体添加新字段。

与添加行为的操作相比,这项工作的量更大,因为需要扩展完整的 CDS 视图栈,而不只是扩展行为定义(BDEF)。

概览

要扩展 RAP BO 的数据模型,基础 RAP BO 必须按照在线帮助中的说明启用可扩展性支持。
RAP Extensibility-Enablement 为方便起见,已为你准备好的生成式 RAP BO ZRAP630R_ShopTP_### 支持数据模型扩展。

如上图所示,我们需要扩展可扩展基础 BO 的以下对象。

扩展顺序

仓库对象名称

名称

说明

1

ZRAP630SSHOP_###

扩展包含结构(Extension include)

用附加字段扩展活动表和草稿表

2

ZRAP630E_Shop_###

扩展包含视图(Extension include view)

从(扩展后的)活动表中读取

3

ZRAP630R_ShopTP_###

受限基础视图(Restricted base view)

从 (2) 中读取

4

ZRAP630C_ShopTP_###

CDS 投影视图(CDS projection view)

从 (3) 中读取

5

ZRAP630I_ShopTP_###

接口视图(Interface view)

从 (3) 中读取

6

ZRAP630R_Shop_D_###

草稿查询视图(Draft query view)

从(扩展后的)草稿表中读取

分步指南

对于 SAP BTP ABAP Environment 和 SAP S/4HANA Cloud ABAP Environment,可以使用扩展字段向导,而在 SAP S/4HANA 2023 中,你必须手动为上述对象创建扩展对象。

因此,根据你所使用的 ABAP 系统类型,我们提供两份不同的操作指南。

如果在 SAP BTP ABAP Environment 或 SAP S/4HANA ABAP Environment 中工作,请从这里继续:

练习 3 - 使用字段可扩展性向导添加字段

如果在本地部署或私有云的 SAP S/4HANA 2023 系统中工作,请从这里继续:

练习 3 - 手动添加字段

小结

现在你已经为可扩展 RAP 业务对象添加了一个可编辑字段。
在下一个练习中,我们将演示如何添加动作。

继续学习 - 练习 4 - 添加动作

练习 3 - 扩展可扩展 RAP 基础业务对象的 CDS 数据模型

主页 - 云 ERP 扩展

如上图所示,我们需要扩展可扩展基础 BO 的以下对象。

扩展顺序

仓库对象名称

名称

说明

1

ZRAP630SSHOP_###

扩展包含结构(Extension include)

用附加字段扩展活动表和草稿表

2

ZRAP630E_Shop_###

扩展包含视图(Extension include view)

从(扩展后的)活动表中读取

3

ZRAP630R_ShopTP_###

受限基础视图(Restricted base view)

从 (2) 中读取

4

ZRAP630C_ShopTP_###

CDS 投影视图(CDS projection view)

从 (3) 中读取

5

ZRAP630I_ShopTP_###

接口视图(Interface view)

从 (3) 中读取

6

ZRAP630R_Shop_D_###

草稿查询视图(Draft query view)

从(扩展后的)草稿表中读取

需要扩展的对象

练习 3.1 - 通过追加结构扩展扩展包含结构 - 添加字段

我们通过创建_追加结构_(append structure)来为_扩展包含结构_(extension include structure)添加字段,从而开始对基础 RAP BO 的扩展。

🔵 点击展开!
  1. 右键单击_扩展包含结构_ ZRAP630SSSHOP_###,在上下文菜单中选择 New Append Structure。

    添加追加结构

  2. 在 New Append Structure 对话框中输入以下值。

    请务必将包名改为 ZRAP630_###_EXT,因为 ADT 中的向导默认会建议使用基础 RAP BO 包含结构所在的包。

    Package: ZRAP630_###_EXT ⚠️
    Name: ZAPD_ZRAP630SSHOP_###
    Description: Extend Extension Include Structure

    然后单击 Next。

  3. 选择为你的扩展包创建的传输请求,然后单击 Finish。

  4. 在代码编辑器中输入以下代码片段:

       zzfeedbackzaa : text100;
    

    这样你的代码应当如下所示:

      
    @EndUserText.label : 'extend ZRAP630SSHOP_###'
    @AbapCatalog.enhancement.category : #NOT_EXTENSIBLE
    extend type zrap630sshop_### with zapd_zrap630sshop_### {
     zzfeedbackzaa : text100;
    }
    
  5. 激活更改

练习 3.2 - 扩展扩展包含视图

下面我们说明如何扩展其余 5 个 CDS 视图实体。由于每个 CDS 视图实体的操作过程(向导)都相同,我们只对第一个需要扩展的 CDS 视图——即_扩展包含视图_ ZRAP630E_Shop_###——给出截图。

对于其余 CDS 视图,我们只提供代码片段。

🔵 点击展开!

我们首先要扩展扩展包含视图 ZRAP630E_Shop_###,因为 R 视图是从该视图中读取数据的。

  1. 右键单击基础 RAP 业务对象中需要扩展的 CDS 视图。在本例中,右键单击 ´ZRAP630E_Shop_###´。

    e-view

  2. 在上下文菜单中选择 New Data Definition。

    e-view

  3. 在 New Data Defintion 屏幕中输入以下值:

    Package: ZRAP630_###_EXT --> !!! 请务必修改包名,因为 ADT 会建议使用基础 RAP BO 所在的包名

    Name: ZX_ZRAP630E_SHOP_### Description: Extension for Extension Include View

    然后单击 Next。

  4. 选择一个传输请求,然后单击 Next。

    注意: 不要按 Finish,因为在接下来的屏幕上你需要选择要使用的模板。

  5. 选择模板 Extend View Entity,然后单击 Finish。

    Extend View Entity 模板

  6. 编辑器窗口随即打开。在这里你需要输入以下代码。

          
      extend view entity ZRAP630E_Shop_### with {
          Shop.zz_feedback_zaa as zz_feedback_zaa
      } 
    

    CDS 视图扩展

练习 3.3 - 扩展剩余的 CDS 视图

现在你需要按照以下顺序、使用以下代码片段扩展剩余的 4 个 CDS 视图,做法与我们在练习 3.5 中对扩展包含视图所做的一样。

🔵 点击展开!

R-CDS 视图的扩展

Name: ZX_ZRAP630R_SHOPTP_###
Package: ZRAP630_###_EXT
Description: Extension for R-CDS view

请注意: R-CDS 视图的代码扩展从 _Extension 关联中读取数据,将其作为数据源。 其他所有扩展都从别名 Shop 读取数据,将其作为数据源。

extend view entity ZRAP630R_SHOPTP_### with 
{
  @EndUserText.label: 'Feedback'
  _EXTENSION.ZZFEEDBACKZAA as ZZFEEDBACKZAA
}

C-CDS 视图的扩展

Name: ZX_ZRAP630C_SHOPTP_###
Package: ZRAP630_###_EXT
Description: Extension for P-CDS view

extend view entity ZRAP630C_SHOPTP_### with 
{
  @EndUserText.label: 'Feedback'
  @UI.dataFieldDefault: [{hidden: false}]
  @UI.identification: [{hidden: false}]
  @UI.lineItem: [{hidden: false}]
  SHOP.ZZFEEDBACKZAA as ZZFEEDBACKZAA

}

I-CDS 视图的扩展

Name: ZX_ZRAP630I_SHOPTP_###
Package: ZRAP630_###_EXT
Description: Extension for interface view

extend view entity ZRAP630I_SHOPTP_### with 
{
  @EndUserText.label: 'Feedback'
  SHOP.ZZFEEDBACKZAA as ZZFEEDBACKZAA

}

草稿查询视图的扩展

Name: ZX_ZRAP630R_SHOP_D_###
Package: ZRAP630_###_EXT
Description: Extension for draft query view

extend view entity ZRAP630R_SHOP_D_### with 
{
  SHOP.ZZFEEDBACKZAA as ZZFEEDBACKZAA

}
结果

扩展项目现在应当如下所示:

扩展概览

No.

扩展仓库对象

被扩展的仓库对象

说明

1

ZAPD_ZRAP630SSHOP_###

ZRAP630SSHOP_###

扩展扩展包含结构

2

ZX_ZRAP630E_SHOP_###

ZRAP630E_Shop_###

扩展扩展包含视图

3

ZX_ZRAP630R_SHOPTP_###

ZRAP630R_ShopTP_###

扩展受限事务性基础视图

4

ZX_ZRAP630C_SHOPTP_###

ZRAP630C_ShopTP_###

扩展事务性投影视图

5

ZX_ZRAP630I_SHOPTP_###

ZRAP630I_ShopTP_###

扩展事务性接口视图

6

ZX_ZRAP630R_SHOP_D_###

ZRAP630R_Shop_D_###

扩展草稿查询视图

练习 3.3 - 测试字段可扩展性

扩展完基础 RAP 业务对象层次结构中的所有对象后,你现在就可以在 UI 中使用新增字段了。

🔵 点击展开!
  1. 打开可扩展 RAP 业务对象的服务绑定,然后双击实体 Shop。

  2. 单击 Go 按钮。

    这时你应当看到一个名为“Feedback”的新列。

    扩展后的列表页

  3. 选择一条记录,然后使用 Edit 按钮。

    扩展后的对象页

如果没有看到该字段,应当检查投影视图 ZRAP630C_EXT_SHOPTP_### 的扩展,并检查 UI 注解。

小结

现在你已经为可扩展 RAP 业务对象添加了一个可编辑字段。
在下一个练习中,我们将演示如何添加动作。

继续学习 - 练习 4 - 添加动作

练习 3 - 使用扩展字段向导扩展 CDS 数据模型

主页 - 云 ERP 扩展

扩展字段向导(extension field wizard)可以从消费视图(C 视图)、接口投影视图(I 视图)或底层的受限基础视图(R 视图)启动。根据所选的起始视图不同,向导中会有一些选项被预先设置。

扩展字段向导的启动选项

例如,以 C 视图作为入口时,向导默认会建议扩展 C 视图。

练习 3.1 - 使用扩展字段向导扩展数据结构

  1. 右键单击消费投影视图 ZRAP630C_ShopTP_###(即包含语句 provider contract TRANSACTIONAL_QUERY 的那个视图),选择 Generate ABAP Repository Objects ..。

    扩展字段向导的启动选项

  2. 在 Select Generator 屏幕中选择 ABAP Cloud: Extensibility,然后选择 Extension Fields。单击 Next。

    启动扩展字段向导

  3. 在 Enter Package 屏幕中输入包名 ZRAP630_###_EXT,然后单击 Next。

    选择生成器

  4. 在 Configure Generator 屏幕中单击 Add (1)。然后在 Add Field 对话框中输入以下值 (2),添加一个用于输入反馈的字段:

    • Name ZZFEEDBACKZAA

    • Label: Feedback

    • Data Elemeent: TEXT100

    • 勾选复选框 Generate UI annotations (3)

    然后单击 Add (4)

    选择生成器

  5. 展开 Business Service Layer Extensions 区域,确认 Extend Object ? 选项已勾选,然后单击 Next。

    选择生成器

  6. 向导现在会显示将要创建/修改的 ABAP 工件列表。

    选择生成器

    你还可以查看将要生成的其他工件的代码。

    🔵 点击显示其他工件

    扩展包含结构

    扩展包含结构

    扩展包含视图

    扩展包含结构

    草稿查询视图的扩展

    扩展包含结构

    受限制基础视图的扩展

    扩展包含结构

    事务性接口视图的扩展

    扩展包含结构

    事务性消费视图的扩展

    扩展包含结构

  1. 单击 Next 继续。

  2. 选择一个传输请求。

练习 3.2 - 检查数据结构扩展

向导生成了以下仓库对象:

No.

扩展仓库对象

被扩展的仓库对象

说明

1

ZAPD_ZRAP630SSHOP_###

ZRAP630SSHOP_###

扩展扩展包含结构

2

ZX_ZRAP630E_SHOP_###

ZRAP630E_Shop_###

扩展扩展包含视图

3

ZX_ZRAP630R_SHOPTP_###

ZRAP630R_ShopTP_###

扩展受限事务性基础视图

4

ZX_ZRAP630C_SHOPTP_###

ZRAP630C_ShopTP_###

扩展事务性投影视图

5

ZX_ZRAP630I_SHOPTP_###

ZRAP630I_ShopTP_###

扩展事务性接口视图

6

ZX_ZRAP630R_SHOP_D_###

ZRAP630R_Shop_D_###

扩展草稿查询视图

扩展项目现在应当如下所示:

生成的扩展对象

练习 3.3 - 测试字段可扩展性

扩展完基础 RAP 业务对象层次结构中的所有对象后,你现在就可以在 UI 中使用新增字段了。

🔵 点击展开!
  1. 打开可扩展 RAP 业务对象的服务绑定,然后双击实体 Shop。

  2. 单击 Go 按钮。

    这时你应当看到一个名为“Feedback”的新列。

    扩展后的列表页

  3. 选择一条记录,然后使用 Edit 按钮。

    扩展后的对象页

提示:
⚠️ 如果没有看到该字段,应当检查投影视图 ZX_ZRAP630C_SHOPTP_### 的扩展,并检查 UI 注解。

小结

现在你已经为可扩展 RAP 业务对象添加了一个可编辑字段。
在下一个练习中,我们将演示如何添加动作。

继续学习 - 练习 4 - 添加动作

练习 4 - 用动作扩展业务对象

主页 - 云 ERP 扩展

添加字段之后,我们将在基础 RAP BO 中添加一个动作。

⚠ 请注意:
通过可扩展性添加动作时,动作只能添加到那些本身通过可扩展性添加的字段上。 这就是为什么我们把本练习放在第四个,即在为 Shop RAP 业务对象添加用于输入反馈的字段之后。

该动作将用于创建/更新评论。 因此,我们会把为输入评论而新增的字段设为只读, 并为以下对象添加所需的扩展:

  • BDEF(添加动作)

  • 投影 BDEF(添加 use 语句)

  • 投影视图(添加 UI 注解,使动作按钮可见)

练习 4.1 创建抽象实体

我们希望把订单的反馈作为动作的参数来提供,而该动作将通过扩展添加。 参数是通过抽象实体传递给动作的。

  1. 右键单击包 ZRAP630_###_EXT 中的文件夹 Data Definition。

  2. 在上下文菜单中选择 New data defintion。

    • Package: ZRAP630_###_EXT

    • Name: ZRAP630_A_Feedback_###

    • Description: Pass feedback as a parameter
      然后单击 Next。

  3. 选择一个传输请求。

  4. 展开文件夹 Abstract Entity(creation)。

  5. 选择模板 Define abstract entity with parameters,然后单击 Finish。

    选择 DDLS 模板

  6. 输入以下代码。

    @EndUserText.label: 'Pass feedback as a parameter'
    define abstract entity ZRAP630_A_Feedback_###  
    {
        feedback : abap.char(100);  
    }
    
  7. 激活更改。

练习 4.2 扩展行为定义

现在我们可以使用刚刚创建的参数来定义动作了。

  1. 打开行为扩展 ZRAP630R_EXT_SHOPTP_###。

  2. 在行为扩展 ZRAP630R_EXT_SHOPTP_### 中添加以下代码片段。

    field(readonly) zzfeedbackzaa;
    action(authorization : global, features : instance ) ZZ_ProvideFeedback  parameter ZRAP630_A_Feedback_### result\[1\] $self;
    

    这样你的代码现在如下所示:

      
    extension using interface zrap630i_shoptp_###
    implementation in class zbp_rap630r_ext_shoptp_### unique;
    
    extend behavior for Shop
    {
    
      validation zz_validateDeliverydate on save { create; field DeliveryDate; }
    
      extend draft determine action Prepare
      {
        validation zz_validateDeliveryDate;
      }
      determination ZZ_setOverallStatus on modify { field OrderedItem; }
    
      side effects { field OrderedItem affects field OrderItemPrice , field CurrencyCode ; }
    
      field(readonly) zzfeedbackzaa;
      action(authorization : global, features : instance ) ZZ_ProvideFeedback  parameter ZRAP630_A_Feedback_### result[1] $self;
     }
    
  3. 激活更改。

  4. 在 Shop 实体上使用代码辅助(按 Ctrl+1),让框架生成缺失的工件。

    通过动作提供反馈

练习 4.3 - 在行为实现类中实现该动作的方法

  1. 打开行为实现类的本地类。

    通过动作提供反馈

  2. 实现方法 zz_providefeedback 并激活更改。

    METHOD ZZ_ProvideFeedback.
        MODIFY ENTITIES OF ZRAP630I_ShopTP_### IN LOCAL MODE
      ENTITY Shop
    
      UPDATE FIELDS ( zzfeedbackzaa )
      WITH VALUE #( FOR key IN keys ( %tky              = key-%tky
                                       zzfeedbackzaa  = key-%param-feedback  ) ).
    
        "Read the changed data for action result
        READ ENTITIES OF ZRAP630I_ShopTP_### IN LOCAL MODE
          ENTITY Shop
            ALL FIELDS WITH
            CORRESPONDING #( keys )
          RESULT DATA(result_read).
        "return result entities
        result = VALUE #( FOR order_2 IN result_read ( %tky   = order_2-%tky
                                                       %param = order_2 ) ).
    
      ENDMETHOD.
    

练习 4.4 - 扩展投影 BDEF

为了使动作可见,必须在可扩展根 BO 的 BDEF 投影层添加相应的 use action 语句。

  1. 右键单击包 ZRAP630_### 中的投影行为定义 ZRAP630C_ShopTP_###,选择 New Behavior Extension。

    添加 P-BDEF

  2. 填写投影行为扩展的数据。

    • Package: ZRAP630_###_EXT

    • Name: ZRAP630C_Ext_SHOPTP_###

    • Description: Behavior extension for projection bdef

    添加 P-BDEF

  3. 选择一个传输请求,然后单击 Finish。

  4. 为你的动作输入 use 语句,使代码如下所示:

    extension for projection;
    
    extend behavior for Shop
    {
    use action ZZ_ProvideFeedback;
    }
    

练习 4.5 - 添加 UI 注解

必须添加 UI 注解,动作按钮才会显示。这要在 C 视图扩展 ZRAP630C_EXT_SHOPTP_### 中完成。

为此,你需要在 UI.identification 和 UI.lineitem 注解中添加以下代码片段。

, { type: #FOR_ACTION, dataAction: 'ZZ_ProvideFeedback', label: 'Update feedback' } 

这样 ZX_ZRAP630C_SHOPTP_### 的代码现在如下所示:

  extend view entity ZRAP630C_ShopTP_### with
  {
  @EndUserText.label: 'Feedback'
  @UI.dataFieldDefault: \[{hidden: false}\]
  @UI.identification: [{hidden: false},
                       {type: #FOR_ACTION, dataAction: 'ZZ_ProvideFeedback', label: 'Update feedback' } ]
  @UI.lineItem: [{hidden: false},
                 {type: #FOR_ACTION, dataAction: 'ZZ_ProvideFeedback', label: 'Update feedback' } ]
  Shop.ZZFEEDBACKZAA as ZZFEEDBACKZAA

  }
   

现在你应当能看到一个可以输入反馈的动作按钮。

通过动作提供反馈

小结

到这里你就完成了全部练习。

^返回页首
主页 - RAP630


© 版权所有 SAP SE. 课程内容抓取自 learning.sap.com,RAP 文档抓取自 help.sap.com,仅供内部学习使用。。

利用 Sphinx 构建,使用的 主题 由 Read the Docs 开发.