获取权限

ABAP RESTful 应用程序编程模型 › 学习 › 业务对象 › 实体操作语言 (EML) › 使用 EML 访问业务对象的示例 › 获取权限

常规信息:GET PERMISSION

此语句用于检查在权限和功能控制方面,在全局和实例级别是否存在权限。可以为创建、按关联创建、更新和删除操作以及操作和字段检索有关权限的信息。以下部分涵盖针对不同权限类型的专用 EML 语句。

有关权限和功能控制的常规信息,请参阅权限控制和功能控制。

有关语法的详细信息,请参阅 GET PERMISSIONS(ABAP 关键字文档)。特别是,请参阅合同和结果信息主题。

有关权限和功能控制的实施合同的详细信息,请参阅实施合同:功能控制和实施合同:权限控制。

示例:全局权限

全局权限用于仅取决于用户的所有权限检查。您可以定义全局权限,以检查是否允许用户执行常规操作。

以下代码用于检查登录用户是否具有对参考业务对象执行“创建”操作的权限。

*Declare derived type for authorization request
DATA: request_ga TYPE STRUCTURE FOR PERMISSIONS REQUEST /DMO/R_Travel_D.

*Activate check for create operation
request_ga-%create = if_abap_behv=>mk-on.

*Perform authorization request
GET PERMISSIONS ONLY GLOBAL AUTHORIZATION ENTITY /DMO/R_Travel_D
  REQUEST request_ga
RESULT DATA(result)
FAILED DATA(failed)
REPORTED DATA(reported).

在执行实际权限请求之前,我们准备包含所请求权限的本地结构。首先,我们使用参考业务对象上许可请求的派生类型声明此本地结构。然后通过 ABAP 接口 if_abap_behv 激活结构中的创建组件。

GET PERMISSIONS 语句由关键字 GET PERMISSIONS ONLY GLOBAL AUTHORIZATION ENTITY 引入,后跟语句引用的实体。

关键字 REQUEST 后跟包含请求的操作权限的本地结构。

结果保存在名为 result 的本地结构中。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

示例:实例权限

实例权限用于除用户角色外,还取决于相关实体实例状态的所有权限检查。通过实例权限,您可以定义取决于实例字段值的权限。

以下代码用于检查是否可以对参考业务对象的给定差旅实例执行更新操作。根据业务对象的实例权限逻辑,这取决于登录用户是否具有实例国家/地区代码的更新权限。实例的国家/地区代码由与差旅实例相关联的代理实例的 CountryCode 定义。请注意,需要根据现有数据替换差旅 UUID 的占位符。

*Declare derived type for authorization request
DATA: request_ia TYPE STRUCTURE FOR PERMISSIONS REQUEST /DMO/R_Travel_D.

*Activate check for update operation
request_ia-%update = if_abap_behv=>mk-on.

*Perform authorization request
GET PERMISSIONS ONLY INSTANCE AUTHORIZATION ENTITY /DMO/R_Travel_D
  FROM  VALUE #( ( TravelUUID = '<Travel_UUID>'
                   %is_draft  = if_abap_behv=>mk-off ) )
  REQUEST request_ia
RESULT DATA(result)
FAILED   DATA(failed)
REPORTED DATA(reported).

在执行实际权限请求之前,我们准备包含所请求权限的本地结构。首先,我们使用参考业务对象上许可请求的派生类型声明此本地结构。然后通过 ABAP 接口 if_abap_behv 激活结构中的更新组件。

GET PERMISSIONS 语句由关键字 GET PERMISSIONS ONLY INSTANCE AUTHORIZATION ENTITY 引入,后跟语句引用的实体。

value 运算符指定要检查其权限的实例的键值。使用草稿标识 %is_draft 我们可以确定是要检查活动实例还是草稿实例的权限。由于我们要检查活动实例,因此我们将草稿标识设置为假。

关键字 REQUEST 后跟包含请求的操作权限的本地结构。

结果保存在名为 result 的本地结构中。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

示例:实例功能控制

您可以使用实例功能控制来定义哪些字段、操作和操作具有访问限制。这些限制可能取决于实例的状态。

以下代码用于检查在参考业务对象中为实体 BookingFee 定义的字段 Travel 的访问限制。字段的访问限制取决于 OverallStatus 字段的值。如果值为 'A'(已接受),则字段 BookingFee 为只读。否则是不受限制的。请注意,需要根据现有数据替换差旅 UUID 的占位符。

*Declare derived type for feature control request
DATA: request_ifc TYPE STRUCTURE FOR PERMISSIONS REQUEST /DMO/R_Travel_D.

*Activate check for field
request_ifc-%field-BookingFee = if_abap_behv=>mk-on.

*Perform feature control request
GET PERMISSIONS ONLY INSTANCE FEATURES ENTITY /DMO/R_Travel_D
  FROM  VALUE #( ( TravelUUID = '<Travel_UUID>'
                   %is_draft  = if_abap_behv=>mk-off ) )
  REQUEST request_ifc
RESULT DATA(result)
FAILED DATA(failed)
REPORTED DATA(reported).

在执行实际功能控制请求之前,我们准备包含请求权限的本地结构。首先,我们使用参考业务对象上许可请求的派生类型声明此本地结构。然后,我们通过 ABAP 接口 if_abap_behv 使用结构内的字段组件激活字段检查。

GET PERMISSIONS 语句由关键字 GET PERMISSIONS ONLY INSTANCE FEATURES ENTITY 引入,后跟语句引用的实体。

value 运算符指定要检查其权限的实例的键值。使用草稿标识 %is_draft 我们可以确定是要检查活动实例还是草稿实例的权限。由于我们要检查活动实例,因此我们将草稿标识设置为假。

关键字 REQUEST 后跟包含请求字段权限的本地结构。

结果保存在名为 result 的本地结构中。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

检查结果

以下屏幕截图显示了调试程序中先前实例功能控制权限请求产生的结构 result。已针对总体状态为 Accepted 的差旅实例执行权限申请。

要解释返回的权限值,请查阅元素信息中的 ABAP 接口 if_abap_behv。它包含解释返回值含义的图例。在包含功能控制常量的部分中,有一个用于字段的子部分。该子部分包含字段值 '02':read_only 的含义。

可以为上面所示的其它 get permissions 语句返回的值进行相应评估。请注意,为尚未请求的工序或字段返回的值始终为 '00'。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 修改 · 设置锁定 →