修改

ABAP RESTful 应用程序编程模型 › 学习 › 业务对象 › 实体操作语言 (EML) › 使用 EML 访问业务对象的示例 › 修改

MODIFY 语句用于更改实体实例的数据。以下部分提供了可以使用此语句触发的操作示例。

有关语法的详细信息,请参阅 MODIFY ENTITY、ENTITIES(ABAP 关键字文档)。

通过 IN LOCAL MODE 实施

仅当 EML 实施在其自己的行为池中使用 RAP BO 的实例时,才能实施 IN LOCAL MODE。附加项 IN LOCAL MODE 可确保在不检查访问控制、权限控制、功能控制或预检查的情况下直接访问 BO。有关语法的详细信息,请参阅 IN LOCAL MODE(ABAP 关键字文档)和 EML 操作数。

消耗

业务对象外部使用包括场景,例如单元测试,这些场景在独立于待测试业务对象的类中实施。其他场景是跨业务对象应用程序,其中业务对象使用彼此的操作在自定义 RAP 业务对象的行为池中实施其行为或使用已发布业务对象。在这些情况下,访问控制、权限控制和功能控制实施始终在请求期间触发,无法绕过。使用已发布业务对象时,自定义 RAP BO 的行为池中只能使用 BO(映射)的已发布部分。

常规信息:CREATE 和 CREATE BY 关联

CREATE 语句允许创建实体实例。CREATE BY association 语句使用 EML 语句中指定的实体的关联来创建其子实体的实例。

有关实施合同的详细信息,请参阅实施合同:创建和实施合同:CREATE-BY-ASSOCIATION。

示例:CREATE 和 CREATE BY 关联

下面的 MODIFY 语句包括两个创建操作。第一个使用预填充的内部表 create 创建实体差旅的实例。第二个触发按关联创建操作,该操作基于创建的差旅实例创建两个预订实例。以下代码可用于单独的单元测试类,以测试参考业务对象的创建操作。

*Declare internal table using derived type
    DATA create TYPE TABLE FOR CREATE /DMO/R_Travel_D.

*Select valid flight data
    SELECT SINGLE AirlineID, ConnectionID, FlightDate FROM /DMO/I_Flight INTO @DATA(flight).

*Populate internal table for travel instance
    create = VALUE #( ( %cid                 = 'create_travel'
                        %is_draft            = if_abap_behv=>mk-off
                        CustomerID           = '1'
                        AgencyID             = '70006'
                        BeginDate            = flight-FlightDate
                        EndDate              = flight-FlightDate
                        Description          = 'Travel 1'
 ) ).

*Create a travel instance and two associated booking instances
    MODIFY ENTITIES OF /DMO/R_Travel_D
        ENTITY Travel
          CREATE FIELDS ( CustomerID AgencyID BeginDate EndDate Description ) WITH create
          CREATE BY \_Booking
          FIELDS ( CustomerID AirlineID ConnectionID FlightDate ) WITH

		  VALUE #( ( %cid_ref = 'create_travel'

					 %target = VALUE #( ( %cid         = 'create_booking_1'

                                          %is_draft    = if_abap_behv=>mk-off

                                          CustomerID   = '1'

                            			  AirlineID    = flight-AirlineID

										  ConnectionID = flight-ConnectionID

										  FlightDate   = flight-FlightDate )

										( %cid         = 'create_booking_2'

										  %is_draft    = if_abap_behv=>mk-off

										  CustomerID   = '1'

										  AirlineID    = flight-AirlineID

										  ConnectionID = flight-ConnectionID

									  	FlightDate   = flight-FlightDate )

										 ) ) )

    MAPPED DATA(mapped)
    REPORTED DATA(reported)
    FAILED DATA(failed).

*Persist transactional buffer
    COMMIT ENTITIES.

在将内部表用于创建差旅实例之前,需要从相应的 CDS 实体及其行为定义派生此内部表的类型。内部表用于的修改操作,也需要在其类型声明中进行说明。因此,声明的内部表包含执行预期修改操作所需的所有 CDS 元素和组件。

为确保使用有效的航班数据,我们现在从航班数据库的任意行中选择航空公司标识、转机标识和航班日期,并将其值保存在本地结构 flight 中。

在下一步中,使用 value 运算符用差旅实例的值填充内部表。在此,我们还使用结构 flight 中的值。由于目标业务对象支持管理的内部编号,因此不需要在内部表中指定主键值。相反,可以自由选择提供的差旅实例的内容标识。只要不存在实例的主键,就会将内容标识用作初步标识符。在示例中,它在后续“按关联创建”操作中引用。使用草稿标识 %is_draft 可以确定是要创建活动实例还是草稿实例。由于我们希望创建活动实例,因此我们将草稿标识设置为假。

MODIFY 语句由关键字 MODIFY ENTITIES OF 引入,后跟语句引用的业务对象的行为定义。

手头语句触发差旅实体的创建和按关联创建操作,因此指定了 ENTITY Travel。在此,我们使用为行为定义中的实体指定的别名。

关键字 CREATE FIELDS 后跟要填充的字段的名称。在关键字 WITH 之后,指定创建差旅实例所依据的内部表的名称。分配给内部表的派生类型可确保差旅实例的类型安全创建。最好使用此语法,因为它在尝试覆盖定义为只读的字段时提供直接反馈。此外,当改用语法 SET FIELDS WITH 时,无法为字段设置初始值。

逐个关联操作由关键字 CREATE BY \ 后跟关联名称指定。

在为关联实体指定要填充的字段后,关键字 WITH 引入了以内部表形式预期的输入参数规范。此内部表是使用包含两个登记实例的数据的值运算符构建的。由于我们已指定要修改的字段,因此不需要在 %control 结构中额外将其激活。由于要创建预订实例的差旅实例的主键尚不存在,因此使用其内容标识 create_travel 引用差旅实例。

关键字 MAPPED 后指定的结构充当响应参数。其中包含有关给定内容标识的创建操作提供的主键的信息。此响应参数的类型派生自指定的实体和 框架触发的操作。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

最后,通过 COMMIT ENTITIES 语句触发数据到数据库的持久性。有关此语句的详细信息,请参见 COMMIT ENTITIES。

自动填充 CID

对于 CREATE 和 CREATE BY ASSOCIATION 等静态操作,可以使用附加项 AUTO FILL CID 确保使用内容标识 (CID) 填充 %cid。请注意,如果要使用 %cid_ref,则不得将 AUTO FILL CID 用于参考的实例,因为 %cid_ref 无法引用自动创建的内容标识。在以下示例中,使用未指定内容标识的内部表创建差旅实例。使用 AUTO FILL CID 创建差旅实例期间会自动生成内容标识。

*Declare internal table using derived type
DATA create TYPE TABLE FOR CREATE /DMO/R_Travel_D.

*Select valid flight data
SELECT SINGLE FlightDate FROM /DMO/I_Flight INTO @DATA(flight).

*Populate internal table for travel instance, %cid does not need to be specified
create = VALUE #( (   %is_draft            = if_abap_behv=>mk-off
                      CustomerID           = '1'
                      AgencyID             = '70006'
                      BeginDate            = flight
                      EndDate              = flight
                      Description          = 'Travel 1'
                ) ).

*Create a travel instance using AUTO FILL CID
MODIFY ENTITIES OF /DMO/R_Travel_D
  ENTITY Travel
    CREATE AUTO FILL CID FIELDS ( CustomerID AgencyID BeginDate EndDate Description ) WITH create
MAPPED DATA(mapped)
REPORTED DATA(reported)
FAILED DATA(failed).

*Persist transactional buffer
COMMIT ENTITIES.

生成的内容标识和实例键值之间的映射信息存储在 MAPPED 结构中。

常规信息:UPDATE

UPDATE 语句允许编辑实体实例。

有关实施合同的详细信息,请参阅实施合同:更新。

示例:UPDATE

以下 UPDATE 语句将两个预订实例的状态设置为“已接受”。与 UI 不同,使用 EML,您可以选择修改草稿或活动实例。在这种情况下,我们希望直接更新活动实例。您可以在单独的单元测试类中使用以下代码,以测试参考业务对象的更新操作。请注意,之前需要根据现有数据替换预订 UUID 的占位符。

MODIFY ENTITIES OF /DMO/R_Travel_D
  ENTITY Booking
    UPDATE FIELDS ( BookingStatus )
    WITH VALUE #( ( BookingUUID   = '<Booking_UUID>'
                    %is_draft     = if_abap_behv=>mk-off
                    BookingStatus = 'A' )
                  ( BookingUUID   = '<Booking_UUID>'
                    %is_draft     = if_abap_behv=>mk-off
                    BookingStatus = 'A' ) )
FAILED DATA(failed)
REPORTED DATA(reported).

COMMIT ENTITIES.

MODIFY 语句由关键字 MODIFY ENTITIES OF 引入,后跟语句引用的业务对象的行为定义。

手头语句触发预订实体的更新操作,因此指定了 ENTITY Booking。在此,我们使用为行为定义中的实体指定的别名。

下一行表明将更新字段 BookingStatus 的值。

关键字 WITH VALUE 引入了内部表的结构,该内部表指示将使用哪些值更新哪些实例。在构造函数运算符 VALUE 中,实例首先由其预订 UUID 标识,然后分别指定预订状态字段的值。使用草稿标识 %is_draft 可以确定是要更新活动实例还是草稿实例。由于我们希望直接更新活动实例,因此将草稿标识设置为假。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

最后,通过 COMMIT ENTITIES 语句触发数据到数据库的持久性。有关此语句的详细信息,请参见 COMMIT ENTITIES。

常规信息:DELETE

DELETE 语句允许删除实体实例。

有关实施合同的详细信息,请参阅实施合同:删除。

示例:DELETE

以下语句删除实体差旅的实例。可在单独的单元测试类中使用,以测试参考业务对象的删除操作。请注意,之前需要根据现有数据替换差旅 UUID 的占位符。

MODIFY ENTITIES OF /DMO/R_Travel_D
  ENTITY TRAVEL
    DELETE FROM VALUE #( ( TravelUUID = '<Travel_UUID>'
                           %is_draft  = if_abap_behv=>mk-off ) )
FAILED DATA(failed)
REPORTED DATA(reported).

COMMIT ENTITIES.

MODIFY 语句由关键字 MODIFY ENTITIES OF 引入,后跟语句引用的业务对象的行为定义。

现有报表使用差旅实体的删除操作,因此指定了 ENTITY Travel。在此,我们使用为行为定义中的实体指定的别名。

值运算符指定要删除的 实例的键值。使用草稿标识 %is_draft 可以确定是否要删除活动实例或草稿实例。由于我们希望删除活动实例,因此我们将草稿标识设置为假。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

最后,通过 COMMIT ENTITIES 语句触发数据到数据库的持久性。有关此语句的详细信息,请参见 COMMIT ENTITIES。

基本信息:EXECUTE 操作

此语句允许执行操作。

有关实施合同的详细信息,请参阅实施合同:操作。

示例:EXECUTE 操作

以下语句触发根据更改的值重新计算总差旅价格的操作。该操作针对键值已由 READ BY association 语句确定的实例执行。在参考业务对象的行为池中,以下 EXECUTE 语句用于实体预订和预订补充的确定 calculateTotalPrice。有关更多上下文信息以及此确定的完整代码,请参阅计算总价。

  MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Travel
        EXECUTE reCalcTotalPrice
          FROM CORRESPONDING  #( travels )
RESULT DATA(result)
FAILED DATA(failed).

MODIFY 语句由关键字 MODIFY ENTITIES OF 引入,后跟语句引用的业务对象的行为定义。

由于此语句包含在所引用业务对象的行为池中,因此使用关键字 IN LOCAL MODE。它们确保不会触发权限和功能控制实施。

手头语句针对差旅实体的实例执行操作,因此指定了 ENTITY Travel。在此,我们使用在行为定义中为实体指定的别名。

关键字 EXECUTE 后跟要执行的操作的名称。

此操作仅针对相应的父差旅实例执行。因此,字段表达式 FROM 选择内部表 travels 已由上述 READ BY association 语句填充了所需的差旅 UUID。

在关键字 RESULT 之后声明的表包含 操作返回的结果。由于触发的操作没有结果,因此在这种情况下会填充 RESULT。

有关响应参数 FAILED 和 REPORTED 的信息,请参阅通用响应参数。

常规信息:AUGMENTING

使用 AUGMENTING 语句,您可以在将请求传递到基本业务对象之前,通过增强请求的修改操作在投影层上添加数据或修改传入修改请求。

有关语法的详细信息,请参阅 MODIFY AUGMENTING ENTITY(ABAP 关键字文档)。

示例:AUGMENTING

以下方法支持维护实体 Supplement 包含非规范化字段 Description。此字段在关联的子实体 SupplementText 中定义。如果没有此增强方法,补充实体的传入修改请求将无法考虑描述字段,因为它派生自其他实体。在这种情况下,AUGMENTING 语句用于通过按关联创建操作增强传入创建请求。这可确保传入创建请求不仅会导致创建补充实例,还会创建包含已更改描述字段的相应补充文本实例。下面显示的代码示例中不考虑传入更新请求的增强。有关此增强场景的详细信息,请参阅编辑语言相关字段。

METHOD augment.
...

"Handle create requests including SupplementDescription
    LOOP AT entities_create INTO DATA(supplement_create).
      "Count Table index for uniquely identifiably %cid on creating supplementtext
      APPEND sy-tabix TO relates_create.

      "Direct the Supplement Create to the corresponding SupplementText Create-By-Association using the current language
      APPEND VALUE #( %cid_ref           = supplement_create-%cid
                      %is_draft          = supplement_create-%is_draft
                      %key-supplementid  = supplement_create-%key-SupplementID
                      %target            = VALUE #( ( %cid              = |CREATETEXTCID{ sy-tabix }|
                                                      %is_draft         = supplement_create-%is_draft
                                                      %key-supplementid = supplement_create-SupplementID
                                                      languagecode      = sy-langu
                                                      description       = supplement_create-SupplementDescription
                                                      %control          = VALUE #( supplementid = if_abap_behv=>mk-on
                                                                                   languagecode = if_abap_behv=>mk-on
                                                                                   description  = supplement_create-%control-SupplementDescription )
                                                   ) )
                     ) TO suppltext_for_new_suppl.
    ENDLOOP.

*Augment Create by a Create by Association
MODIFY AUGMENTING ENTITIES OF /DMO/I_Supplement
      ENTITY Supplement
        CREATE BY \_SupplementText
        FROM suppltext_for_new_suppl
        RELATING TO entities_create BY relates_create.

...
ENDMETHOD.

增强方法接收要通过导入参数表 entities_create 创建的补充实例。对于其中每个实例,当前表索引将附加到内部表 relates_create,随后的 AUGMENTING 语句将使用该索引。此外,后续按关联创建操作所需的实例数据存储在内部表 suppltext_for_new_suppl 中。因此,此表的每一行都包含使用组件 cid_ref 参考的补充实例的数据,以及要创建的相关补充文本实例的数据。下表用于以下 AUGMENTING 语句。

AUGMENTING 语句由关键字 MODIFY AUGMENTING ENTITIES OF 引入,后跟语句引用的业务对象的行为定义。由于 AUGMENTING 语句只能参考基本业务对象的实体,因此指定业务对象 /dmo/i_supplement。

手头语句使用补充实体的 create-by-association 运算,因此指定了 ENTITY Supplement。在此,我们使用为行为定义中的实体指定的别名。

逐个关联操作由关键字 CREATE BY \ 后跟关联名称指定。

使用准备的内部表 suppltext_for_new_suppl 执行操作。

基本业务对象可能会返回增强请求的 FAILED 和 REPORTED 结构中的条目。为了将这些响应与原始请求相关联,如果增强请求包含新实例,AUGMENTING 语句将提供附加项 RELATING TO 允许将增强实例与原始实例相关联。运行时使用此信息将新实例的 FAILED 键值转换回相关原始实例的键值。如果增强实例(在本例中为补充文本实例)失败,则相关原始实例(在本例中为补充实例)将包含在整个请求的 FAILED 响应中。

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 读取 · 获取权限 →