确定登记实体的值

ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发确定 › 确定登记实体的值

对于具有草稿的托管场景,定义并实施对登记实体的确定,以进行隐式值计算。

确定 setBookingNumber

在行为定义中定义确定,并在“差旅”的行为实施类中实施。

定义

使用触发器操作 create 定义保存时确定。由于预订标识不得在外部更改,因此将字段 BookingID 定义为 read only。

示例代码

define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
field ( readonly ) BookingID;
determination setBookingNumber on save { create; }
… }

通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施

通过循环一次差旅的所有预订来确定新预订实例的编号,并确定最大的标识。为每个新预订实例添加 1。以下步骤将指导您完成实施。

  1. 将传入预订 keys 的所有相应差旅实例读入内部表 travels。如果请求多次预订差旅,则差旅仅返回一次。

  2. 将所有受影响差旅的所有预订读入内部表 bookings。返回链接表以接收每个差旅的相关预订。

  3. 在 travels 处循环,为最大预订标识定义一个变量,并将值设置为 '0000'(初始值)。

  4. 循环于 booking_links,其中差旅键值与受影响的差旅匹配。将预订 ID 与最大预订 ID 进行比较,以确定可用于差旅实例的最大预订 ID。

  5. 为此差旅没有的所有预订提供预订 ID。仅考虑未分配预订 ID 的预订实例。为了坚持确定幂等规则,这一点尤为重要。

    记住

    如果在相同条件下多次执行确定(等幂),则确定结果不得更改。请参阅确定规则。

    将新预订标识写入以表形式键入的新内部表中以进行更新。

  6. 使用内部更新表的条目更新预订实体。

展开以下代码示例以查看确定的源代码 setBookingNumber。

示例代码

  METHOD setBookingNumber.
    DATA:
      max_bookingid   TYPE /dmo/booking_id,
      bookings_update TYPE TABLE FOR UPDATE /DMO/R_Travel_D\\Booking,
      booking         TYPE STRUCTURE FOR READ RESULT /DMO/R_Booking_D.

    "Read all travels for the requested bookings
    " If multiple bookings of the same travel are requested, the travel is returned only once.
    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Booking BY \_Travel
        FIELDS ( TravelUUID )
        WITH CORRESPONDING #( keys )
      RESULT DATA(travels).

    " Read all bookings for all affected travels
    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Travel BY \_Booking
        FIELDS ( BookingID )
        WITH CORRESPONDING #( travels )
        LINK DATA(booking_links)
      RESULT DATA(bookings).

    " Process all affected travels.
    LOOP AT travels INTO DATA(travel).

      " find max used bookingID in all bookings of this travel
      max_bookingid = '0000'.
      LOOP AT booking_links INTO DATA(booking_link) USING KEY id WHERE source-%tky = travel-%tky.
        " Short dump occurs if link table does not match read table, which must never happen
        booking = bookings[ KEY id  %tky = booking_link-target-%tky ].
        IF booking-BookingID > max_bookingid.
          max_bookingid = booking-BookingID.
        ENDIF.
      ENDLOOP.

      "Provide a booking ID for all bookings of this travel that have none.
      LOOP AT booking_links INTO booking_link USING KEY id WHERE source-%tky = travel-%tky.
        " Short dump occurs if link table does not match read table, which must never happen
        booking = bookings[ KEY id  %tky = booking_link-target-%tky ].
        IF booking-BookingID IS INITIAL.
          max_bookingid += 1.
          APPEND VALUE #( %tky      = booking-%tky
                          BookingID = max_bookingid
                        ) TO bookings_update.
        ENDIF.
      ENDLOOP.
    ENDLOOP.

    " Provide a booking ID for all bookings that have none.
    MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY booking
        UPDATE FIELDS ( BookingID )
        WITH bookings_update.

  ENDMETHOD.

确定 setBookingDate

在行为定义中定义确定,并在预订的行为实施类中实施该确定。

定义

使用触发器操作 create 定义保存时确定。设置填充日期后,预订实例保存到数据库时,之后不应更改日期。因此,字段 BookingDate 对于外部使用者是只读的。

示例代码

define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
field ( readonly ) TravelUUID, BookingID, BookingDate;
determination setBookingDate on save { create; }
… }

通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施

设置预订日期的系统日期。以下步骤将指导您完成实施。

  1. 读取已导入 keys 到内部表的所有登记实例,并删除已具有登记日期的实例 (BookingDate)。继续仅使用还没有预订日期的实例。如果多次执行确定,则不得再次计算预订日期。为了坚持确定幂等规则,这一点尤为重要。

    记住

    如果在相同条件下多次执行确定(等幂),则确定结果不得更改。请参阅确定规则。

  2. 为每个传入预订实例将系统日期 sy-datum 分配到 BookingDate。

  3. 使用修改请求更新所有相关实例的字段 BookingDate。

展开以下代码示例以查看确定的源代码 setBookingDate。

示例代码

 METHOD setBookingDate.

    READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Booking
        FIELDS ( BookingDate )
        WITH CORRESPONDING #( keys )
      RESULT DATA(bookings).

    DELETE bookings WHERE BookingDate IS NOT INITIAL.
    CHECK bookings IS NOT INITIAL.

    LOOP AT bookings ASSIGNING FIELD-SYMBOL(<booking>).
      <booking>-BookingDate = cl_abap_context_info=>get_system_date( ).
    ENDLOOP.

    MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Booking
        UPDATE  FIELDS ( BookingDate )
        WITH CORRESPONDING #( bookings ).

  ENDMETHOD.

确定 calculateTotalPrice

在行为定义中定义确定,并在预订的行为实施类中实施该确定。

备注

总价的实际计算通过操作 recalcPrice 完成。确定仅执行操作。请参阅操作 recalcTotalPrice。

定义

使用操作触发器 create 和字段触发器 CurrencyCode 和 FlightPrice 定义修改确定。

示例代码

define behavior for /DMO/R_Booking_D alias Booking
...
{ ...
determination calculateTotalPrice on modify { create; field FlightPrice, CurrencyCode; }

… }

通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施

更改触发器字段时执行操作 reCalcTotalPrice。以下步骤将指导您完成实施。

  1. 要获取 TravelUUID,请通过关联读取差旅实例到内部表中。执行操作需要根实例的键值。

  2. 为所有受影响的差旅实例执行修改操作申请。

    备注

    由于操作 failed 不返回这些参数,因此不会在此 EML 调用中检索响应参数 reported 和 reCalcTotalPrice。假定操作不能失败,因为它仅在内部调用并由托管的业务对象提供者处理。

    由于操作未定义此参数,因此不会检索响应参数 result。

展开以下代码示例以查看确定的源代码 calculateTotalPrice。

示例代码

  METHOD calculateTotalPrice.

    " Read all parent UUIDs
  READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Booking BY \_Travel
        FIELDS ( TravelUUID  )
        WITH CORRESPONDING #(  keys  )
      RESULT DATA(travels).

    " Trigger Re-Calculation on Root Node
  MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
      ENTITY Travel
        EXECUTE reCalcTotalPrice
          FROM CORRESPONDING  #( travels ).

  ENDMETHOD.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 确定差旅实体的值 · 确定预订补充实体的值 →