确定差旅实体的值
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发确定 › 确定差旅实体的值
对于具有草稿的托管场景,定义并实施对差旅实体的确定,以进行隐式值计算。
确定 setTravelNumber
在行为定义中定义确定,并在“差旅”的行为实施类中实施。
定义
使用触发器操作 create 定义修改确定。由于不得在外部更改差旅标识,因此将字段 TravelID 定义为 readonly。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( readonly ) TravelID;
determination setTravelNumber on save { create; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。

实施
通过选择数据库中的最高可用编号并添加 1,确定新差旅实例的编号。以下步骤将指导您完成实施。
将所有已导入 keys 的差旅实例读取到内部表中,并删除已具有差旅编号的实例 (TravelID)。继续仅使用尚不具有差旅编号的实例。如果多次执行确定,则不得再次计算差旅编号。为了坚持确定幂等规则,这一点尤为重要。
记住
如果在相同条件下多次执行确定(等幂),则确定结果不得更改。请参阅确定规则。
从数据库表
/DMO/A_TRAVEL_D中选择最大差旅编号。使用修改请求更新所有相关实例的字段
TravelID并通过将 1 添加到之前的最大差旅值来分配新的TravelID。在请求的已报告 表中写入消息。备注
由于仅在保存时执行确定,因此确保将持久化表中的最大数量增加 1 将返回唯一结果。
展开以下代码示例以查看确定的源代码 setTravelNumber。
示例代码
METHOD setTravelNumber.
"Ensure idempotence
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( TravelID )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
DELETE travels WHERE TravelID IS NOT INITIAL.
CHECK travels IS NOT INITIAL.
"Get max travelID
SELECT SINGLE FROM /DMO/A_TRAVEL_D FIELDS MAX( travel_id ) INTO @DATA(max_travelid).
"update involved instances
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( TravelID )
WITH VALUE #( FOR travel IN travels INDEX INTO i (
%tky = travel-%tky
TravelID = max_travelid + i ) ).
ENDMETHOD.
确定 setStatusToOpen
在行为定义中定义确定,并在“差旅”的行为实施类中实施。
定义
使用触发器操作 create 定义修改确定。差旅的总体状态仅通过操作 rejectTravel 和 acceptTravel 更改,请参阅接受和拒绝差旅。因此,该字段对于外部使用者为只读。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( readonly ) TravelID; OverallStatus;
determination setStatusToOpen on modify { create; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
创建新实例时,将状态设置为打开。以下步骤将指导您完成实施。
将所有具有已导入键值的差旅实例读取到内部表中,并删除状态字段 (OverallStatus) 中已具有条目的实例。继续仅处理尚不具有状态的实例。如果在使用者设置状态值后执行确定,则不得将状态设置为未处理。
对于 OverallStatus 中具有初始值的实例,通过为已导入的 OverallStatus 的所有实例执行修改请求,使用 open 更新字段 keys。常量 open 之前在本地类型的私有部分中定义。在修改请求的报告表中写入消息。
备注
在此确定中,幂等性不是问题。即使多次执行确定且实例的状态为未处理,确定结果也不会随着修改请求执行而更改。
展开以下代码示例以查看确定的源代码 setStatusToOpen。
示例代码
METHOD setStatusToOpen.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
FIELDS ( OverallStatus )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
"If Status is already set, do nothing
DELETE travels WHERE OverallStatus IS NOT INITIAL.
CHECK travels IS NOT INITIAL.
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
UPDATE FIELDS ( OverallStatus )
WITH VALUE #( FOR travel IN travels ( %tky = travel-%tky
OverallStatus = travel_status-open ) ).
ENDMETHOD.
确定 calculateTotalPrice
在行为定义中定义确定,并在“差旅”的行为实施类中实施。
备注
总价的实际计算通过操作
recalcTotalPrice完成。确定仅执行操作。请参阅操作recalcTotalPrice。
定义
使用操作触发器 create 和字段触发器 BookingFee 和 CurrencyCode 定义修改确定,并将字段 TotalPrice 定义为 read only,因为不得在外部定义值。
示例代码
define behavior for /DMO/R_Travel_D alias Travel
...
{ ...
field ( readonly ) TravelID; OverallStatus; TotalPrice;
determination calculateTotalPrice on modify { create; field BookingFee, CurrencyCode; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
更改触发器字段时执行操作 recalcPrice。以下步骤将指导您完成实施。
为导入了
keys的所有实例执行操作执行修改请求。在修改请求的报告表中写入消息。
展开以下代码示例以查看确定的源代码 calculateTotalPrice。
示例代码
METHOD calculateTotalPrice.
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
EXECUTE reCalcTotalPrice
FROM CORRESPONDING #( keys ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译