确定预订补充实体的值
ABAP RESTful 应用程序编程模型 › 开发 › 开发应用程序 › 使用独占草稿功能开发事务应用 › 使用 UUID 键值构建被管理业务对象 › 开发事务行为 › 开发确定 › 确定预订补充实体的值
对于具有草稿的托管场景,定义并实施对隐式值计算的登记补充实体的确定。
确定 setBookSupplNumber
在行为定义中定义确定,并在 BookingSupplement 的行为实施类中实施该确定。
定义
使用触发器操作 create 定义保存时确定。由于登记补充标识不得在外部更改,因此将字段 BookingSupplementID 定义为 read only。
示例代码
define behavior for /DMO/R_BookingSupplement_D alias BookingSupplement
...
{ ...
field ( readonly ) TravelUUID, BookingSupplementID;
determination setBookSupplNumber on save { create; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
确定新登记补充编号的实施与登记的计算相同。有关详细的逐步描述,请参阅确定 setBookingNumber。
展开以下代码示例以查看确定的源代码 setBookSupplNumber。
示例代码
METHOD setBookSupplNumber.
DATA:
max_bookingsupplementid TYPE /dmo/booking_supplement_id,
bookingsupplements_update TYPE TABLE FOR UPDATE /DMO/R_Travel_D\\BookingSupplement,
bookingsupplement TYPE STRUCTURE FOR READ RESULT /DMO/R_BookingSupplement_D.
"Read all bookings for the requested booking supplements
" If multiple booking supplements of the same booking are requested, the booking is returned only once.
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY BookingSupplement BY \_Booking
FIELDS ( BookingUUID )
WITH CORRESPONDING #( keys )
RESULT DATA(bookings).
" Read all booking supplements for the affected bookings
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Booking BY \_BookingSupplement
FIELDS ( BookingSupplementID )
WITH CORRESPONDING #( bookings )
LINK DATA(bookingsupplement_links)
RESULT DATA(bookingsupplements).
" Process all affected bookings.
LOOP AT bookings INTO DATA(booking).
" find max used booking supplement ID in all booking supplements of this booking
max_bookingsupplementid = '00'.
LOOP AT bookingsupplement_links INTO DATA(bookingsupplement_link) USING KEY id WHERE source-%tky = booking-%tky.
bookingsupplement = bookingsupplements[ KEY id %tky = bookingsupplement_link-target-%tky ].
IF bookingsupplement-BookingSupplementID > max_bookingsupplementid.
max_bookingsupplementid = bookingsupplement-BookingSupplementID.
ENDIF.
ENDLOOP.
"Provide a booking supplement ID for all booking supplements of this booking that have none.
LOOP AT bookingsupplement_links INTO bookingsupplement_link USING KEY id WHERE source-%tky = booking-%tky.
bookingsupplement = bookingsupplements[ KEY id %tky = bookingsupplement_link-target-%tky ].
IF bookingsupplement-BookingSupplementID IS INITIAL.
max_bookingsupplementid += 1.
APPEND VALUE #( %tky = bookingsupplement-%tky
bookingsupplementid = max_bookingsupplementid
) TO bookingsupplements_update.
ENDIF.
ENDLOOP.
ENDLOOP.
" Provide a booking supplement ID for all booking supplements that have none.
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY BookingSupplement
UPDATE FIELDS ( BookingSupplementID ) WITH bookingsupplements_update.
ENDMETHOD.
确定 calculateTotalPrice
在行为定义中定义确定,并在 BookingSupplement 的行为实施类中实施该确定。
备注
总价的实际计算通过操作
recalcPrice完成。确定仅执行操作。请参阅操作recalcTotalPrice。
定义
使用操作触发器 create 和字段触发器 CurrencyCode 和 BookSupplPrice 定义修改确定。
示例代码
define behavior for /DMO/R_BookingSupplement_D alias BookingSupplement
...
{ ...
determination calculateTotalPrice on modify { create; field BookSupplPrice, CurrencyCode; }
… }
通过快速修复,您可以直接在行为定义编辑器中生成行为池中的方法声明。
实施
更改触发器字段时执行操作 reCalcTotalPrice。这些步骤与确定 calculateTotalPrice 中的步骤完全相同。
展开以下代码示例以查看确定的源代码 calculateTotalPrice。
示例代码
METHOD calculateTotalPrice.
" Read all parent UUIDs
READ ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY BookingSupplement BY \_Travel
FIELDS ( TravelUUID )
WITH CORRESPONDING #( keys )
RESULT DATA(travels).
" Trigger Re-Calculation on Root Node
MODIFY ENTITIES OF /DMO/R_Travel_D IN LOCAL MODE
ENTITY Travel
EXECUTE reCalcTotalPrice
FROM CORRESPONDING #( travels ).
ENDMETHOD.
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译