COMMIT ENTITIES

ABAP RESTful 应用程序编程模型 › 学习 › 业务对象 › 实体操作语言 (EML) › 使用 EML 访问业务对象的示例 › COMMIT ENTITIES

COMMIT ENTITIES

常规信息:COMMIT ENTITIES

COMMIT ENTITIES 语句会触发保存序列,从而将数据从事务缓冲区保存到数据库。COMMIT ENTITIES 语句为在 LUW 内更改的所有业务对象触发从事务缓冲区到数据库的数据持久性。需要显式指定 COMMIT ENTITIES,以便在行为池外触发修改操作以终止 LUW。对于来自行为池中的修改请求,COMMIT ENTITIES,随后由框架触发保存序列。

有关语法的详细信息,请参阅 COMMIT ENTITIES(ABAP 关键字文档)。

示例:COMMIT ENTITIES

以下示例代码显示一个 MODIFY CREATE 语句,后跟 COMMIT ENTITIES 语句,该语句在参考业务对象上执行。

"Declare internal table using derived type
DATA create TYPE TABLE FOR CREATE /DMO/R_Travel_D.

"Select valid flight data
SELECT SINGLE FlightDate FROM /DMO/I_Flight INTO @DATA(flight).

"Populate internal table for travel instance
create = VALUE #( ( %cid                 = 'create_travel'
                    %is_draft            = if_abap_behv=>mk-off
                    CustomerID           = '1'
                    AgencyID             = '70006'
                    BeginDate            = flight
                    EndDate              = flight
                    Description          = 'Travel 1'
 ) ).

"Create travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D
  ENTITY Travel
     CREATE FIELDS ( CustomerID AgencyID BeginDate EndDate Description ) WITH create
   MAPPED DATA(mapped_modify)
   REPORTED DATA(reported_modify)
   FAILED DATA(failed_modify).

"Persist travel instance
COMMIT ENTITIES
  RESPONSE OF /DMO/R_Travel_D
   FAILED DATA(failed_commit)
   REPORTED DATA(reported_commit).

创建的差旅实例将持久保存并在数据库中可见 /DMO/A_TRAVEL_D。

已持久化的差旅实例

模拟模式

基本信息:模拟模式

如果 COMMIT ENTITIES 语句与附加项 IN SIMULATION MODE 一起使用,则执行保存序列而不实际保存任何数据。这意味着在模拟模式下,将执行方法 finalize、check_before_save 和 cleanup_finalize,但不执行方法 adjust_numbers、save 和 cleanup。由于确定和验证由方法 finalize 和 check_before_save 执行,因此如果已执行不含模拟模式的 COMMIT ENTITIES 语句,则模拟模式可用于检查是否可以保留最终数据。

示例:模拟模式

以下示例代码显示在模拟模式下执行的 MODIFY CREATE 语句,后跟 COMMIT ENTITIES 语句,这些语句在参考业务对象上执行。模拟模式中的 COMMIT ENTITIES 语句检查是否可以保留创建的差旅实例。

"Declare internal table using derived type
DATA create TYPE TABLE FOR CREATE /DMO/R_Travel_D.

"Select valid flight data
SELECT SINGLE FlightDate FROM /DMO/I_Flight INTO @DATA(flight).

"Populate internal table for create operation
create = VALUE #( ( %cid       = 'create_travel'
                    %is_draft  = if_abap_behv=>mk-off
                    CustomerID = '1'
                    AgencyID   = '70006'
                    BeginDate  = flight
                    EndDate    = flight ) ).

"Create travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D
  ENTITY Travel
    CREATE FIELDS ( CustomerID AgencyID BeginDate ) WITH create
   FAILED DATA(failed_modify)
   REPORTED DATA(reported_modify).

"Check whether saving is possible
COMMIT ENTITIES IN SIMULATION MODE
  RESPONSE OF /DMO/R_Travel_D
   FAILED DATA(failed_commit)
   REPORTED DATA(reported_commit).

为了确定实例是否可以持久化,可以检查 REPORTED 语句的响应参数 FAILED 和 COMMIT ENTITIES。如果不一致,则通过验证填充这些参数。

差旅实例的失败键

FAILED 参数在其差旅表中包含已创建差旅实例的条目,这意味着无法保留此实例。为了确定提交操作失败的原因,可以检查响应参数 REPORTED。

报告的消息

%MSG 组件包含对相应消息的引用。在变量标签中双击 %MSG 组件后,其文本将显示在 ABAP 异常视图中。

消息文本

失败的键值和消息已由验证 validateDates 返回,防止在日期不一致的情况下持久保存实例数据。在此示例中,缺少结束日期,因为尚未在 MODIFY 语句的 FIELDS 表达式中指定相应字段。将字段 EndDate 添加到 FIELDS 表达式后,实例数据一致,可以使用 COMMIT ENTITIES 语句进行保留。

"Declare internal table using derived type
DATA create TYPE TABLE FOR CREATE /DMO/R_Travel_D.

"Select valid flight data
SELECT SINGLE FlightDate FROM /DMO/I_Flight INTO @DATA(flight).

"Populate internal table for create operation
create = VALUE #( ( %cid       = 'create_travel'
                    %is_draft  = if_abap_behv=>mk-off
                    CustomerID = '1'
                    AgencyID   = '70006'
                    BeginDate  = flight
                    EndDate    = flight ) ).

"Create travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D
  ENTITY Travel
   CREATE FIELDS ( CustomerID AgencyID BeginDate EndDate ) WITH create
    FAILED DATA(failed_modify)
    REPORTED DATA(reported_modify).

"Persist travel instance
COMMIT ENTITIES.

来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译

← 设置锁定 · 回滚实体 →