回滚实体
ABAP RESTful 应用程序编程模型 › 学习 › 业务对象 › 实体操作语言 (EML) › 使用 EML 访问业务对象的示例 › 回滚实体
常规信息:ROLLBACK ENTITIES
ROLLBACK ENTITIES 语句重置事务缓冲区。它用于在行为池之外回滚自上次 COMMIT ENTITIES 操作以来所做的所有更改。
有关语法的详细信息,请参阅 ROLLBACK ENTITIES(ABAP 关键字文档)。
示例:ROLLBACK ENTITIES
以下代码演示 ROLLBACK ENTITIES 语句的影响。声明并填充将用于后续 MODIFY 语句的内部表后,将使用 MODIFY 语句创建第一个实例,并使用 COMMIT ENTITIES 语句持久保存。然后,在创建第二个实例后,使用 ROLLBACK ENTITIES 语句重置事务缓冲区。以下 COMMIT ENTITIES 语句不会导致数据库发生更改,因为事务缓冲区已由 ROLLBACK ENTITIES 语句清空。执行结束时,数据库仅包含一个差旅实例。
有关 COMMIT ENTITIES 语句的详细信息,请参见 COMMIT ENTITIES。
展开以下代码示例以查看源代码
示例代码
*Declare internal tables using derived type
DATA travel1 TYPE TABLE FOR CREATE /DMO/R_Travel_D .
DATA travel2 TYPE TABLE FOR CREATE /DMO/R_Travel_D .
*Select valid flight data
SELECT SINGLE FlightDate FROM /DMO/I_Flight INTO @DATA(flight1).
*Populating the internal tables
travel1 = VALUE #( ( %cid = 'create_travel_1'
%is_draft = if_abap_behv=>mk-off
CustomerID = '1'
AgencyID = '70006'
BeginDate = flight1
EndDate = flight1 ) ).
travel2 = VALUE #( ( %cid = 'create_travel_2'
%is_draft = if_abap_behv=>mk-off
CustomerID = '2'
AgencyID = '70007'
BeginDate = flight1
EndDate = flight1 ) ).
*Create first travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D
ENTITY Travel
CREATE FIELDS ( CustomerID AgencyID BeginDate EndDate ) WITH travel1.
*Persist transactional buffer
COMMIT ENTITIES
RESPONSE OF /DMO/R_Travel_D
FAILED DATA(failed_commit1)
REPORTED DATA(reported_commit1).
*Create second travel instance
MODIFY ENTITIES OF /DMO/R_Travel_D
ENTITY Travel
CREATE FIELDS ( CustomerID AgencyID BeginDate EndDate ) WITH travel2.
*Reset transactional buffer
ROLLBACK ENTITIES.
*Persist (empty) transactional buffer
COMMIT ENTITIES
RESPONSE OF /DMO/R_Travel_D
FAILED DATA(failed_commit2)
REPORTED DATA(reported_commit2).
来源:SAP Help Portal · 2025 FPS02 (Oct 2026) · 中文为 SAP 官方机器翻译
← COMMIT ENTITIES · 通用响应参数 →